[gentoo-commits] repo/gentoo:master commit in: sys-cluster/resource-agents/

["Sam James" <sam@gentoo.org>]

commit:     1e682e0638a3e1e30f8153cffbcee7dd16b56034
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 18 02:06:10 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Nov 18 02:11:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1e682e06

sys-cluster/resource-agents: add 4.11.0

Closes: https://bugs.gentoo.org/720420
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-cluster/resource-agents/Manifest               |  1 +
 .../resource-agents/resource-agents-4.11.0.ebuild  | 69 ++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/sys-cluster/resource-agents/Manifest b/sys-cluster/resource-agents/Manifest
index ed88231ec603..23a37c5b965b 100644
--- a/sys-cluster/resource-agents/Manifest
+++ b/sys-cluster/resource-agents/Manifest
@@ -1 +1,2 @@
+DIST resource-agents-4.11.0.tar.gz 860940 BLAKE2B 8009d6936c59bd014710db2478e3d001c59eca8c9e76f5847cc7568c08951f784696a65ff0cf62970a7d193ce7e205ddfc1116993dc0ea07496a647833d32829 SHA512 3baf66b39a26323787a5089dccd369a0e4fc8ac60a3061c8fbe461d5e60cdee6330eaa7840c32d536473688f1bdeea47b77e1ba9bb199012495a31d2d75662c2
 DIST resource-agents-4.6.1.tar.gz 799688 BLAKE2B a276dbd17d6b91926f2a040d847e2ca499fe36cf30a0413d2bdffccd3bd8cbe7022ab29244524d5f7f6b91c7513a56b40de5f4bb425e65d4f83710445da91231 SHA512 ccd4a86b5a4da636248badfb81808fa4c96f08dbce9dc8d9322b594cb6028f74b33fd9cacdbee65f49ca05f7dca04671e247f64b767df5cd0b7d19539f52ad5e

diff --git a/sys-cluster/resource-agents/resource-agents-4.11.0.ebuild b/sys-cluster/resource-agents/resource-agents-4.11.0.ebuild
new file mode 100644
index 000000000000..d5c32f56840b
--- /dev/null
+++ b/sys-cluster/resource-agents/resource-agents-4.11.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${P/resource-}"
+inherit autotools
+
+DESCRIPTION="Resources pack for Heartbeat / Pacemaker"
+HOMEPAGE="http://www.linux-ha.org/wiki/Resource_Agents"
+SRC_URI="https://github.com/ClusterLabs/resource-agents/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="doc libnet rgmanager systemd"
+
+RDEPEND="
+	sys-apps/iproute2
+	>=sys-cluster/cluster-glue-1.0.12-r1
+	libnet? ( net-libs/libnet:1.1 )
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		dev-libs/libxslt
+		app-text/docbook-xsl-stylesheets
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/4.6.1-configure.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# --with-ocf-root needs to be /usr/lib, see bug #720420
+	econf \
+		--disable-fatal-warnings \
+		--localstatedir=/var \
+		--with-ocf-root=/usr/lib/ocf \
+		--with-rsctmpdir=/run/resource-agents \
+		$(use_enable doc) \
+		$(use_enable libnet)
+}
+
+src_install() {
+	default
+
+	rm -rf "${ED}/usr/lib/ocf/resource.d/redhat" || die
+	rm -rf "${ED}"/etc/init.d/ || die
+	rm -rf "${ED}"{,/var}/run || die
+
+	use rgmanager || rm -rf "${ED}"/usr/share/cluster/ "${ED}"/var/
+}
+
+pkg_postinst() {
+	elog "To use Resource Agents installed in ${EROOT}/usr/lib/ocf/resource.d"
+	elog "you have to emerge required runtime dependencies manually."
+	elog ""
+	elog "Description and dependencies of all Agents can be found on"
+	elog "http://www.linux-ha.org/wiki/Resource_Agents"
+	elog "or in the documentation of this package."
+}