From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1456929-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (2048 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 3ADA5158020
	for <garchives@archives.gentoo.org>; Tue, 15 Nov 2022 22:58:22 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 6E126E0AF4;
	Tue, 15 Nov 2022 22:58:21 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 4B900E0AF4
	for <gentoo-commits@lists.gentoo.org>; Tue, 15 Nov 2022 22:58:21 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
	 key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 4BAC8340EAD
	for <gentoo-commits@lists.gentoo.org>; Tue, 15 Nov 2022 22:58:20 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id AEC96599
	for <gentoo-commits@lists.gentoo.org>; Tue, 15 Nov 2022 22:58:18 +0000 (UTC)
From: "Eray Aslan" <eras@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Eray Aslan" <eras@gentoo.org>
Message-ID: <1668553065.d2b3d0f516d485cd8a9040f5d68f0943d810cdad.eras@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-crypt/heimdal/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-crypt/heimdal/Manifest app-crypt/heimdal/heimdal-7.7.1.ebuild
X-VCS-Directories: app-crypt/heimdal/
X-VCS-Committer: eras
X-VCS-Committer-Name: Eray Aslan
X-VCS-Revision: d2b3d0f516d485cd8a9040f5d68f0943d810cdad
X-VCS-Branch: master
Date: Tue, 15 Nov 2022 22:58:18 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 7de9d200-bb7f-42c9-8a14-a2e56cc4b47a
X-Archives-Hash: 0e0d12bcb02162128672e10380f220c2

commit:     d2b3d0f516d485cd8a9040f5d68f0943d810cdad
Author:     Eray Aslan <eras <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 15 22:57:45 2022 +0000
Commit:     Eray Aslan <eras <AT> gentoo <DOT> org>
CommitDate: Tue Nov 15 22:57:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d2b3d0f5

app-crypt/heimdal: add 7.7.1

Bug: https://bugs.gentoo.org/881429
Signed-off-by: Eray Aslan <eras <AT> gentoo.org>

 app-crypt/heimdal/Manifest             |   1 +
 app-crypt/heimdal/heimdal-7.7.1.ebuild | 186 +++++++++++++++++++++++++++++++++
 2 files changed, 187 insertions(+)

diff --git a/app-crypt/heimdal/Manifest b/app-crypt/heimdal/Manifest
index 7402ad50fecf..7394a567ab21 100644
--- a/app-crypt/heimdal/Manifest
+++ b/app-crypt/heimdal/Manifest
@@ -1 +1,2 @@
 DIST heimdal-7.7.0.tar.gz 10189293 BLAKE2B db9cdd1861dc9214a7f76b3d8b9656cfc0bad11cb6eadffa4fa29ea7f9aabd4c3d1b628c510644ec9abe1b3bf27a413ccf8cd590d602c4a4ac54ba3deb4cedc4 SHA512 6660939b5a36ce36310721a08a089fb671d1e3d2e8ac74ea4775bfa5f8f772d32de805551456200fe96cc486c092c44beb84f5dd877008bc305490ee971bbf99
+DIST heimdal-7.7.1.tar.gz 10009851 BLAKE2B 2d2b6cef4aea1dfab97106cc6be5f3f68736c93f153b650ba349ee32be2a415de8a550c462c6d0978628ac18403838145198e07b4710ebe21570878e2b44f595 SHA512 c77def1d32301caa8675297152a534919459a65bd1c5353cdc8795c07aa7a94fd319b697b98e02233ef25eaeedb36420edd139c1e22d68d54bb991343a11a369

diff --git a/app-crypt/heimdal/heimdal-7.7.1.ebuild b/app-crypt/heimdal/heimdal-7.7.1.ebuild
new file mode 100644
index 000000000000..5012d8dddef3
--- /dev/null
+++ b/app-crypt/heimdal/heimdal-7.7.1.ebuild
@@ -0,0 +1,186 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+VIRTUALX_REQUIRED="manual"
+
+inherit autotools db-use multilib-minimal python-any-r1 virtualx flag-o-matic
+
+MY_P="${P}"
+DESCRIPTION="Kerberos 5 implementation from KTH"
+HOMEPAGE="http://www.h5l.org/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="afs +berkdb caps gdbm hdb-ldap +lmdb otp selinux ssl static-libs test X"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	virtual/libcrypt:=[${MULTILIB_USEDEP}]
+	ssl? (
+		>=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
+	)
+	berkdb? ( >=sys-libs/db-4.8.30-r1:*[${MULTILIB_USEDEP}] )
+	gdbm? ( >=sys-libs/gdbm-1.10-r1:=[${MULTILIB_USEDEP}] )
+	lmdb? ( dev-db/lmdb:= )
+	caps? ( sys-libs/libcap-ng )
+	>=dev-db/sqlite-3.8.2[${MULTILIB_USEDEP}]
+	>=sys-fs/e2fsprogs-1.46.4-r51[${MULTILIB_USEDEP}]
+	sys-libs/ncurses:0=
+	>=sys-libs/readline-6.2_p5-r1:0=[${MULTILIB_USEDEP}]
+	afs? ( net-fs/openafs )
+	hdb-ldap? ( >=net-nds/openldap-2.3.0:= )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXau
+		x11-libs/libXt
+	)
+	!!app-crypt/mit-krb5
+	!!app-crypt/mit-krb5-appl"
+
+DEPEND="${CDEPEND}
+	${PYTHON_DEPS}
+	dev-perl/JSON
+	virtual/pkgconfig
+	sys-apps/texinfo
+	>=sys-devel/autoconf-2.62
+	test? ( X? ( ${VIRTUALX_DEPEND} ) )"
+
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-kerberos )"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/krb5-types.h
+	/usr/include/cms_asn1.h
+	/usr/include/digest_asn1.h
+	/usr/include/hdb_asn1.h
+	/usr/include/krb5_asn1.h
+	/usr/include/pkcs12_asn1.h
+	/usr/include/pkinit_asn1.h
+	/usr/include/rfc2459_asn1.h
+)
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/krb5-config
+)
+
+PATCHES=(
+	"${FILESDIR}/heimdal_disable-check-iprop.patch"
+	"${FILESDIR}/heimdal_tinfo.patch"
+	"${FILESDIR}/heimdal_build-headers-before-use.patch"
+	"${FILESDIR}/heimdal_fix-db60.patch"
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# QA
+	append-flags -fno-strict-aliasing
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-kcm
+		--disable-osfc2
+		--enable-shared
+		--with-libintl="${EPREFIX}"/usr
+		--with-readline="${EPREFIX}"/usr
+		--with-sqlite3="${EPREFIX}"/usr
+		--libexecdir="${EPREFIX}"/usr/sbin
+		--enable-pthread-support
+		--enable-kx509
+		--enable-pk-init
+		--with-ipv6
+		$(use_enable afs afs-support)
+		$(use_enable gdbm ndbm-db)
+		$(use_enable lmdb mdb-db)
+		$(use_enable otp)
+		$(use_enable static-libs static)
+		$(multilib_native_use_with caps capng)
+		$(multilib_native_use_with hdb-ldap openldap "${EPREFIX}"/usr)
+		$(use_with ssl openssl "${EPREFIX}"/usr)
+		$(multilib_native_use_with X x)
+	)
+	if use berkdb; then
+		myeconfargs+=(
+			--with-berkeley-db
+			--with-berkeley-db-include="$(db_includedir)"
+		)
+	else
+		myeconfargs+=(
+			--without-berkeley-db
+		)
+	fi
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+	if multilib_is_native_abi; then
+		emake
+	else
+		emake -C include
+		emake -C lib
+		emake -C kdc
+		emake -C tools
+		emake -C tests/plugin
+	fi
+}
+
+multilib_src_test() {
+	multilib_is_native_abi && emake -j1 check
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi; then
+		INSTALL_CATPAGES="no" emake DESTDIR="${D}" install
+	else
+		emake -C include DESTDIR="${D}" install
+		emake -C lib DESTDIR="${D}" install
+		emake -C kdc DESTDIR="${D}" install
+		emake -C tools DESTDIR="${D}" install
+		emake -C tests/plugin DESTDIR="${D}" install
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc ChangeLog* README NEWS TODO
+
+	# client rename
+	mv "${ED}"/usr/share/man/man1/{,k}su.1
+	mv "${ED}"/usr/bin/{,k}su
+
+	newinitd "${FILESDIR}"/heimdal-kdc.initd-r2 heimdal-kdc
+	newinitd "${FILESDIR}"/heimdal-kadmind.initd-r2 heimdal-kadmind
+	newinitd "${FILESDIR}"/heimdal-kpasswdd.initd-r2 heimdal-kpasswdd
+	newinitd "${FILESDIR}"/heimdal-kcm.initd-r1 heimdal-kcm
+
+	newconfd "${FILESDIR}"/heimdal-kdc.confd heimdal-kdc
+	newconfd "${FILESDIR}"/heimdal-kadmind.confd heimdal-kadmind
+	newconfd "${FILESDIR}"/heimdal-kpasswdd.confd heimdal-kpasswdd
+	newconfd "${FILESDIR}"/heimdal-kcm.confd heimdal-kcm
+
+	insinto /etc
+	newins "${S}"/krb5.conf krb5.conf.example
+
+	if use hdb-ldap; then
+		insinto /etc/openldap/schema
+		doins "${S}/lib/hdb/hdb.schema"
+	fi
+
+	if ! use static-libs ; then
+		find "${ED}" -name "*.la" -delete || die
+	fi
+
+	# default database dir
+	keepdir /var/heimdal
+}