[gentoo-commits] repo/gentoo:master commit in: net-misc/owncloud-client/

["Bernard Cafarelli" <voyageur@gentoo.org>]

commit:     40614322562091f5305448bd88af20c8fd76c4dd
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 13 21:49:21 2022 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Sun Nov 13 22:39:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=40614322

net-misc/owncloud-client: add 2.11.1.8946

Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/owncloud-client/Manifest                  |  1 +
 .../owncloud-client-2.11.1.8946.ebuild             | 67 ++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index dea42b6bbff6..0160ebd98ff1 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
 DIST ownCloud-2.11.1.8438.tar.xz 5655380 BLAKE2B da34adafabfc8c2b0bbfdff99a81b56f2d2639b5168b2165a847a6d5a4efe4e86578984c0f0c20564d0978aab18bb1a62330539bdd137f608a5cfc3ff8d84cf0 SHA512 fe38471f62e7233a7ba04f7fd2c7c7231957e6927c39d0bcf3f6f77fd6cbb1223618bbf6a8cc5fa15de10a35c7f07f2f5df0e49acbc2af5fe9333cda2eb41c92
+DIST ownCloud-2.11.1.8946.tar.xz 5654496 BLAKE2B 6b5b82730460071ae590b35d653824f4e56d506d87929c5d4ebb31eef921d0cb0141a44d7f0c996b8d1afffa5874d3e4dda75feaba740e652df2939633475fcd SHA512 b44f72e22c539a731901d9c146f00edbf0a4dabb992d6cde06be1b50506d5bc4a8aa861c6ea0207eed72aaea8c8af8651ce07f9e9154e6e44ccdecdd27e35b75

diff --git a/net-misc/owncloud-client/owncloud-client-2.11.1.8946.ebuild b/net-misc/owncloud-client/owncloud-client-2.11.1.8946.ebuild
new file mode 100644
index 000000000000..ef87f857f8d3
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.11.1.8946.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+MY_PN="ownCloud"
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/${MY_PN}/stable/${PV}/source/${MY_PN}-${PV}.tar.xz"
+S=${WORKDIR}/${MY_PN}-${PV}
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dolphin gnome-keyring nautilus test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[gnome-keyring?,qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )"
+
+DEPEND="${RDEPEND}
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules"
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DBUILD_SHELL_INTEGRATION_DOLPHIN=$(usex dolphin)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}