[gentoo-commits] repo/gentoo:master commit in: media-libs/osl/

["Sam James" <sam@gentoo.org>]

commit:     53e1973f60c92620705b4f6717e39b63536f23a8
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Nov  3 05:54:44 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Nov  3 06:14:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=53e1973f

media-libs/osl: add 1.12.7.0

Closes: https://bugs.gentoo.org/873958
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/osl/Manifest            |   1 +
 media-libs/osl/osl-1.12.7.0.ebuild | 109 +++++++++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/media-libs/osl/Manifest b/media-libs/osl/Manifest
index 145ea4407354..33091b219dcf 100644
--- a/media-libs/osl/Manifest
+++ b/media-libs/osl/Manifest
@@ -1,2 +1,3 @@
 DIST osl-1.11.17.0.tar.gz 13888749 BLAKE2B 284489a2dc580bade93894c43c22d99d88e249329e10922c9c6dde7fc0eed3f741e279cc5fc043ce513ea59ddcea4a3576e34c6fd2294aadc727bdc8d422ed26 SHA512 14cb25b10f4644551b906344a289e2a4c421f4c85beaa120bb1a1e532c9be3ec235622516c4700fb23d258c5dcd1ece18b84491b0973b3162098843a9059b1d2
 DIST osl-1.12.6.2.tar.gz 20247666 BLAKE2B 68905b7dc1a055a7ded26f0a6661ba9db8ddc473fef9ec1de4dab37d0473ce22d123feb33416a44d7b57a80281a64c978540e83f200ac2199a9e49142e00749a SHA512 16e35842735b2dfba7d44a310a918ea8a54798f5ff873ec04bb33b9801612aaf0993ca44b9591fb0b797accb0451137edf6424e1b2a511a011b65f385663d828
+DIST osl-1.12.7.0.tar.gz 20250356 BLAKE2B a9398243546b1bfc1e3f9602f6112a72a8e7cb6ace54e93d0e5f30d943474e82c3317596597d6a09e0f2cf04b1b21f05c31a2357e3d667d710cd2aa340f5fd63 SHA512 ec0391dfc95140fee4fa8332991cdcb0978dafc436f3e07d0293e2baa2014b8765e6b60631ae5a8bbd6e16dbcf37f04c076d7d6b2d8bfa58b78471f0d92c433f

diff --git a/media-libs/osl/osl-1.12.7.0.ebuild b/media-libs/osl/osl-1.12.7.0.ebuild
new file mode 100644
index 000000000000..3aa13e612394
--- /dev/null
+++ b/media-libs/osl/osl-1.12.7.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+# Check this on updates
+LLVM_MAX_SLOT=15
+
+inherit cmake llvm toolchain-funcs python-single-r1
+
+DESCRIPTION="Advanced shading language for production GI renderers"
+HOMEPAGE="http://opensource.imageworks.com/?p=osl"
+# If a development release, please don't keyword!
+SRC_URI="https://github.com/imageworks/OpenShadingLanguage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/OpenShadingLanguage-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+X86_CPU_FEATURES=(
+	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="doc partio qt5 test ${CPU_FEATURES[@]%:*} python"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/pugixml
+	>=media-libs/openexr-3:0=
+	>=media-libs/openimageio-2.3.12.0:=
+	<sys-devel/clang-$((${LLVM_MAX_SLOT} + 1)):=
+	sys-libs/zlib:=
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	partio? ( media-libs/partio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+
+llvm_check_deps() {
+	has_version -r "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	llvm_pkg_setup
+
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local gcc="$(tc-getCC)"
+	local mycmakeargs=(
+		# Still needed?
+		# See https://github.com/AcademySoftwareFoundation/OpenShadingLanguage/pull/1454
+		#-DCMAKE_CXX_STANDARD=14
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DINSTALL_DOCS=$(usex doc)
+		-DUSE_CCACHE=OFF
+		-DLLVM_STATIC=OFF
+		-DOSL_BUILD_TESTS=$(usex test)
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_PARTIO=$(usex partio)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_PYTHON=$(usex python)
+		-DPYTHON_VERSION="${EPYTHON/python}"
+		-DUSE_SIMD="$(IFS=","; echo "${mysimd[*]}")"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# TODO: investigate failures
+	local myctestargs=(
+		-E "(osl-imageio|osl-imageio.opt|render-background|render-bumptest|render-mx-furnace-burley-diffuse|render-mx-furnace-sheen|render-mx-burley-diffuse|render-mx-conductor|render-mx-generalized-schlick|render-mx-generalized-schlick-glass|render-microfacet|render-oren-nayar|render-uv|render-veachmis|render-ward|color|color.opt|example-deformer)"
+	)
+
+	cmake_src_test
+}