[gentoo-commits] repo/gentoo:master commit in: gui-libs/libpanel/

["Matt Turner" <mattst88@gentoo.org>]

commit:     bb91a913d17a1354d6c9fa451078811a81ebc1a7
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Wed Nov  2 18:49:05 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Nov  2 19:06:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bb91a913

gui-libs/libpanel: Version bump to 1.0.2

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/28113
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gui-libs/libpanel/Manifest              |  1 +
 gui-libs/libpanel/libpanel-1.0.2.ebuild | 55 +++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/gui-libs/libpanel/Manifest b/gui-libs/libpanel/Manifest
index 2ce87bf17d5e..b4595b2d929a 100644
--- a/gui-libs/libpanel/Manifest
+++ b/gui-libs/libpanel/Manifest
@@ -1 +1,2 @@
 DIST libpanel-1.0.1.tar.xz 100852 BLAKE2B a55ac6c7c441f5c487553052dca66dd4c1efe1cc010c7202c3400df1d3fc3cfc8f886afdd796981cf14800ad34e49b8efbd274f2f97bce19600b8935a2f1f595 SHA512 5592b01e3a8c532d40e2190d1b2c332d8a104946c0813156119be98d433cd946ad839308b166ebdc399b853809e2fde90be8ea3acced053c2f11b86807163627
+DIST libpanel-1.0.2.tar.xz 101032 BLAKE2B 965140df480b4d6aad1fb008b54ce4c46e78c50136c1bbe200430e97b1f9f2f399bedb8d8695ddfdaef80fdb544be181f3e1a97bd6a4ad7bcacc2a091e00448e SHA512 3c13d7842ba1f1dc1a4bbea3e47517fffe20205c6145812659c203d065523310f1a9b991d7a70454c1333332b25b3eb52835122df14b2993a395fd2aa6046dca

diff --git a/gui-libs/libpanel/libpanel-1.0.2.ebuild b/gui-libs/libpanel/libpanel-1.0.2.ebuild
new file mode 100644
index 000000000000..9faf973952bc
--- /dev/null
+++ b/gui-libs/libpanel/libpanel-1.0.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala xdg
+
+DESCRIPTION="A dock/panel library for GTK 4"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libpanel"
+
+LICENSE="LGPL-3+"
+SLOT="1"
+KEYWORDS="~amd64"
+
+IUSE="examples gtk-doc +introspection +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.6:4[introspection?]
+	>=gui-libs/libadwaita-1.0:1
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use examples install-examples)
+		$(meson_feature introspection)
+		$(meson_feature gtk-doc docs)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use gtk-doc; then
+		mkdir "${ED}"/usr/share/gtk-doc || die
+		mv "${ED}"/usr/share/doc/panel-1.0 "${ED}"/usr/share/gtk-doc/ || die
+	fi
+}