From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1451634-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 40A84158020
for <garchives@archives.gentoo.org>; Sun, 30 Oct 2022 15:51:48 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 834C0E0916;
Sun, 30 Oct 2022 15:51:47 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 67430E08A0
for <gentoo-commits@lists.gentoo.org>; Sun, 30 Oct 2022 15:51:47 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8219E340D23
for <gentoo-commits@lists.gentoo.org>; Sun, 30 Oct 2022 15:51:46 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id C65215E8
for <gentoo-commits@lists.gentoo.org>; Sun, 30 Oct 2022 15:51:44 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1667145017.2f8c0176b502f6150bec2e9d3523dd59b6223bf8.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-apps/sed/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sys-apps/sed/sed-4.8-r1.ebuild
X-VCS-Directories: sys-apps/sed/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: 2f8c0176b502f6150bec2e9d3523dd59b6223bf8
X-VCS-Branch: master
Date: Sun, 30 Oct 2022 15:51:44 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 1b4a3202-d664-4e10-88df-1f64ea98243e
X-Archives-Hash: 44bcb0512e39c4dec1e77c4767534fa0
commit: 2f8c0176b502f6150bec2e9d3523dd59b6223bf8
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 30 12:25:03 2022 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Oct 30 15:50:17 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2f8c0176
sys-apps/sed: Install as gsed for better BSD compat.
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
Signed-off-by: Sam James <sam <AT> gentoo.org>
sys-apps/sed/sed-4.8-r1.ebuild | 60 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
diff --git a/sys-apps/sed/sed-4.8-r1.ebuild b/sys-apps/sed/sed-4.8-r1.ebuild
new file mode 100644
index 000000000000..6cea28c227be
--- /dev/null
+++ b/sys-apps/sed/sed-4.8-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/sed.asc
+inherit flag-o-matic verify-sig
+
+DESCRIPTION="Super-useful stream editor"
+HOMEPAGE="http://sed.sourceforge.net/"
+SRC_URI="mirror://gnu/sed/${P}.tar.xz"
+SRC_URI+=" verify-sig? ( mirror://gnu/sed/${P}.tar.xz.sig )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="acl nls selinux static"
+
+RDEPEND="
+ !static? (
+ acl? ( virtual/acl )
+ nls? ( virtual/libintl )
+ selinux? ( sys-libs/libselinux )
+ )
+"
+DEPEND="${RDEPEND}
+ static? (
+ acl? ( virtual/acl[static-libs(+)] )
+ nls? ( virtual/libintl[static-libs(+)] )
+ selinux? ( sys-libs/libselinux[static-libs(+)] )
+ )
+"
+BDEPEND="nls? ( sys-devel/gettext )
+ verify-sig? ( sec-keys/openpgp-keys-sed )"
+
+PATCHES=(
+ "${FILESDIR}/${P}-avoid-noreturn-diagnostic.patch"
+)
+
+src_configure() {
+ use static && append-ldflags -static
+
+ local myconf=(
+ --exec-prefix="${EPREFIX}"
+ $(use_enable acl)
+ $(use_enable nls)
+ $(use_with selinux)
+ # rename to gsed for better BSD compatibility
+ --program-prefix=g
+ )
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ # symlink to the standard name
+ dosym gsed /bin/sed
+ dosym gsed.1 /usr/share/man/man1/sed.1
+}