[gentoo-commits] repo/gentoo:master commit in: app-arch/cpio/

["Sam James" <sam@gentoo.org>]

commit:     cddeeeb867340fae38dda81d3cb2fd794c1a3c60
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 19 12:15:20 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Oct 30 09:54:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cddeeeb8

app-arch/cpio: Install as gcpio, make cpio a symlink

Closes: https://bugs.gentoo.org/877645
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
Closes: https://github.com/gentoo/gentoo/pull/27846
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-arch/cpio/cpio-2.13-r3.ebuild | 50 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/app-arch/cpio/cpio-2.13-r3.ebuild b/app-arch/cpio/cpio-2.13-r3.ebuild
new file mode 100644
index 000000000000..c2b24b09a8a5
--- /dev/null
+++ b/app-arch/cpio/cpio-2.13-r3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="A file archival tool which can also read and write tar files"
+HOMEPAGE="https://www.gnu.org/software/cpio/cpio.html"
+SRC_URI="mirror://gnu/cpio/${P}.tar.bz2"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}-CVE-2021-38185.patch.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="nls"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.12-non-gnu-compilers.patch #275295
+	"${WORKDIR}"/${P}-CVE-2021-38185.patch
+	"${FILESDIR}"/${PN}-2.13-sysmacros-glibc-2.26.patch
+	"${FILESDIR}"/${PN}-2.13-fix-no-absolute-filenames-revert-CVE-2015-1197-handling.patch
+)
+
+src_prepare() {
+	default
+
+	# Drop after 2.13 (only here for CVE patch)
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable nls)
+		--bindir="${EPREFIX}"/bin
+		--with-rmt="${EPREFIX}"/usr/sbin/rmt
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# install as gcpio for better compatibility with non-GNU userland
+	# and make cpio as a symlink
+	mv "${ED}"/bin/{,g}cpio || die
+	dosym gcpio /bin/cpio
+	mv "${ED}"/usr/share/man/man1/{,g}cpio.1 || die
+	dosym gcpio.1 /usr/share/man/man1/cpio.1
+}