[gentoo-commits] repo/gentoo:master commit in: dev-util/colm/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     4442e3e66d8459aeaaaa33afaa263a5a9c2b9c55
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 28 21:40:42 2022 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri Oct 28 22:47:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4442e3e6

dev-util/colm: Drop .la files and fix sed delimiter for CFLAGS

Closes: https://bugs.gentoo.org/840966
Closes: https://bugs.gentoo.org/840969
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 dev-util/colm/colm-0.14.7-r2.ebuild | 67 +++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)

diff --git a/dev-util/colm/colm-0.14.7-r2.ebuild b/dev-util/colm/colm-0.14.7-r2.ebuild
new file mode 100644
index 000000000000..23a2f43b338a
--- /dev/null
+++ b/dev-util/colm/colm-0.14.7-r2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="COmputer Language Manipulation"
+HOMEPAGE="https://www.colm.net/open-source/colm/"
+SRC_URI="https://www.colm.net/files/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		|| ( app-text/asciidoc dev-ruby/asciidoctor )
+		dev-python/pygments
+	)
+"
+# libfsm moved from ragel -> colm, bug #766108
+RDEPEND="!<dev-util/ragel-7.0.3"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.14.7-drop-julia-check.patch
+	"${FILESDIR}"/${PN}-0.14.7-disable-static-lib.patch
+	"${FILESDIR}"/${PN}-0.14.7-solaris.patch
+)
+
+src_prepare() {
+	default
+
+	# bug #733426
+	sed -i -e 's/(\[ASCIIDOC\], \[asciidoc\], \[asciidoc\]/S([ASCIIDOC], [asciidoc asciidoctor]/' configure.ac || die
+
+	# bug #766069
+	sed -i -e "s|gcc|$(tc-getCC) ${CFLAGS}|" src/main.cc || die
+	sed -i -e "s|gcc|$(tc-getCC)|" test/colm.d/gentests.sh || die
+	sed -i -e "s|g++|$(tc-getCXX)|" test/colm.d/gentests.sh || die
+
+	# fix linkage on Darwin from colm itself during build
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		sed -i -e 's/libcolm\.so/libcolm.dylib/' src/main.cc || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable doc manual)
+}
+
+src_test() {
+	# Build tests
+	default
+
+	# Run them
+	cd test || die
+	./runtests || die
+}
+
+src_install() {
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}