[gentoo-commits] repo/gentoo:master commit in: net-misc/gnome-remote-desktop/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d3fc4998cef8eb63cf5e356fe5d49efc2f84fec1
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Sat Oct 22 22:35:22 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Oct 25 15:25:04 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d3fc4998

net-misc/gnome-remote-desktop: Version bump to 43.1

Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/27908
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/gnome-remote-desktop/Manifest             |  1 +
 .../gnome-remote-desktop-43.1.ebuild               | 73 ++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/net-misc/gnome-remote-desktop/Manifest b/net-misc/gnome-remote-desktop/Manifest
index dca8ac52ef7e..678fe8a73e66 100644
--- a/net-misc/gnome-remote-desktop/Manifest
+++ b/net-misc/gnome-remote-desktop/Manifest
@@ -1 +1,2 @@
 DIST gnome-remote-desktop-43.0.tar.xz 195212 BLAKE2B ccfb43075ce6e36de4bcf3f92265e6596b78831393e3d6b079ef71ae729a9d48fdf177673b4b7e67db8c92a0d397461c60727780f18ff78c671eac6a01229ab4 SHA512 d774d85ef15b02f6c668806e8d7b036c3063decbec81a8cf253aaa01e13a49d802f4338e677744867e2e1ab3dc02ed30c8d8edbca2a9c428b783d5a4cdd8d110
+DIST gnome-remote-desktop-43.1.tar.xz 195740 BLAKE2B b73f0e72f72c45169deb1018dd19cbac779effc2bafc53b8db21cb72c48f5871ef64e3a085509aa859550b4fb54713506e2b6410e211eba7ee8850649af7c39f SHA512 5e0164092da0fdb4877c8a1b40f1df609315390468522efaaad8f30f5c8e29111b021c1a7f3b8ce25627dfbe7937a4876d6673a816d81fdc191d30d4553a0596

diff --git a/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.1.ebuild b/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.1.ebuild
new file mode 100644
index 000000000000..90f943fab5e7
--- /dev/null
+++ b/net-misc/gnome-remote-desktop/gnome-remote-desktop-43.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="Remote desktop daemon for GNOME using pipewire"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-remote-desktop"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="aac doc +rdp systemd +vnc"
+REQUIRED_USE="|| ( rdp vnc ) aac? ( rdp )"
+RESTRICT="test" # Tests run xvfb-run directly
+
+DEPEND="
+	x11-libs/cairo
+	x11-libs/libdrm
+	>=media-libs/libepoxy-1.4
+	>=dev-libs/glib-2.68:2
+	x11-libs/libnotify
+	app-crypt/libsecret
+	>=media-video/pipewire-0.3.49:=
+	app-crypt/tpm2-tss:=
+	rdp? (
+		>=media-libs/nv-codec-headers-11.1.5.0
+		>=net-misc/freerdp-2.8.0:=[server]
+		>=sys-fs/fuse-3.9.1:3
+		>=x11-libs/libxkbcommon-1.0.0
+
+		aac? (
+			media-libs/fdk-aac:=
+		)
+	)
+	vnc? (
+		net-libs/libvncserver
+	)
+"
+RDEPEND="${DEPEND}
+	x11-wm/mutter[screencast]
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	virtual/pkgconfig
+	doc? (
+		app-text/asciidoc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc man)
+		$(meson_use aac fdk_aac)
+		$(meson_use rdp)
+		$(meson_use vnc)
+		$(meson_use systemd)
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}