[gentoo-commits] repo/gentoo:master commit in: dev-python/pbr/

["Michał Górny" <mgorny@gentoo.org>]

commit:     8b47e7e321c124e36415f19abf7eceaf42f0509b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 21 05:19:14 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 21 07:48:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b47e7e3

dev-python/pbr: Bump to 5.11.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pbr/Manifest          |  1 +
 dev-python/pbr/pbr-5.11.0.ebuild | 73 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/dev-python/pbr/Manifest b/dev-python/pbr/Manifest
index 5ad0f418ca6d..312483417e10 100644
--- a/dev-python/pbr/Manifest
+++ b/dev-python/pbr/Manifest
@@ -1 +1,2 @@
 DIST pbr-5.10.0.tar.gz 127122 BLAKE2B 45a254629c2d1e73ce500edb5ba05f165dfaa9987bd62500490cdcceed11708878bc82441f218cf2f5a38b50301a2bcd0aabd0a5e5810346586d8d6463162ba9 SHA512 a5f4393407a17f4de5977483f3c7fa651780b9b9069a0a1898a5b511742262dfb06f891cfcb632c5b64ecfd041188095ceb880c6e71c99c81f0eace59e4e1976
+DIST pbr-5.11.0.tar.gz 127505 BLAKE2B 201fcd04ded1f909f4792886ddf79a5a764318645ff6b6245543cde2940d502ab711820cb6e999894a339df933e43e6a8394bd8ec1e978d930710a3085b131fd SHA512 bdb442e8ef7bda90a65c5fb7f0696041808278fcc643eb0c15d5401b7da7d64cd3566018b1046145f55bc5683791ee182bec92461801004b02a35b8bf4c5abf0

diff --git a/dev-python/pbr/pbr-5.11.0.ebuild b/dev-python/pbr/pbr-5.11.0.ebuild
new file mode 100644
index 000000000000..1e521c028037
--- /dev/null
+++ b/dev-python/pbr/pbr-5.11.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{8..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="
+	https://opendev.org/openstack/pbr/
+	https://github.com/openstack/pbr/
+	https://pypi.org/project/pbr/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/setuptools-60.5.0[${PYTHON_USEDEP}]
+"
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and https://bugs.gentoo.org/show_bug.cgi?id=561038
+# docutils is needed for sphinx exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848
+# stestr is run as external tool
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+			>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+			>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+			>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+			>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20.0.3[${PYTHON_USEDEP}]
+			dev-vcs/git
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# TODO: investigate
+	sed -e 's:test_console_script_develop:_&:' \
+		-e 's:test_console_script_install:_&:' \
+		-e 's:test_setup_py_keywords:_&:' \
+		-i pbr/tests/test_core.py || die
+	# network
+	rm pbr/tests/test_wsgi.py || die
+	# installs random packages via pip from the Internet
+	sed -e 's:test_requirement_parsing:_&:' \
+		-e 's:test_pep_517_support:_&:' \
+		-i pbr/tests/test_packaging.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Testing on ${EPYTHON} is not supported at the moment"
+		return
+	fi
+
+	eunittest -b
+}