[gentoo-commits] repo/gentoo:master commit in: x11-misc/redshift/

["Piotr Karbowski" <slashbeast@gentoo.org>]

commit:     c9f7fa07018697549d1ea0b1951efa367d64200a
Author:     Piotr Karbowski <slashbeast <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 19 08:54:47 2022 +0000
Commit:     Piotr Karbowski <slashbeast <AT> gentoo <DOT> org>
CommitDate: Wed Oct 19 08:55:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c9f7fa07

x11-misc/redshift: 1.12-r7: release tarball; py3.11.

Closes: https://bugs.gentoo.org/877507
Signed-off-by: Piotr Karbowski <slashbeast <AT> gentoo.org>

 x11-misc/redshift/Manifest                |  1 +
 x11-misc/redshift/redshift-1.12-r7.ebuild | 85 +++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/x11-misc/redshift/Manifest b/x11-misc/redshift/Manifest
index e4397643934b..d091a9428eab 100644
--- a/x11-misc/redshift/Manifest
+++ b/x11-misc/redshift/Manifest
@@ -1 +1,2 @@
 DIST redshift-1.12.tar.gz 659019 BLAKE2B 09339a57fee192e3428ba4387cbea498f2f9f97eb75a418588cdda3289cfa7b7fada4cb299e983e9e6d2ffe3822c8235082e67bdfa542716b6dee9fc853a8dc1 SHA512 6763f6964b577fc146191af1c67a283a60df5bbdd3a74bfc94f66d5f9f3bef8835a479c6ec8a648b650b83a0e245928884a0f628606ace8c3f58d8319d35036f
+DIST redshift-1.12.tar.xz 486072 BLAKE2B b7ce74ae134a8f6954ff978e99670f24c447b23ab5e8d69a62109806bfe38c5e1b41e5f65cd6b182298aaf3e0b9187a2c70ea3148fd4ccba8b9c17697024944d SHA512 225e222e5f2c55be4571094ccaf02a92e162dfc35fd0fe504084e21e358b888a72f9992f9f9edaf1d496eb673af74a0d825ae5cf6ef7f0f1ab51d32419722c32

diff --git a/x11-misc/redshift/redshift-1.12-r7.ebuild b/x11-misc/redshift/redshift-1.12-r7.ebuild
new file mode 100644
index 000000000000..3fd13868f5ba
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.12-r7.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit flag-o-matic systemd xdg-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="appindicator geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_configure() {
+	use gtk && python_setup
+
+	# Fix compile for Clang (bug #732438)
+	append-cflags -fPIE
+
+	econf \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--enable-apparmor \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+
+		python_foreach_impl python_optimize
+
+		# https://bugs.gentoo.org/784281
+		mv "${D}"/usr/share/{appdata,metainfo}/ || die
+	fi
+}
+
+pkg_postinst() {
+	use gtk && xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && xdg_icon_cache_update
+}