[gentoo-commits] repo/gentoo:master commit in: app-crypt/gcr/

["Matt Turner" <mattst88@gentoo.org>]

commit:     e212c9ea8ffbc9ac96b5febc0f6ef00f018ac859
Author:     Guillermo Joandet <gjoandet <AT> gmail <DOT> com>
AuthorDate: Wed Oct 12 22:19:16 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Thu Oct 13 00:26:55 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e212c9ea

app-crypt/gcr: Version bump to 4.0.0

Closes: https://github.com/gentoo/gentoo/pull/27760
Signed-off-by: Guillermo Joandet <gjoandet <AT> gmail.com>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-crypt/gcr/Manifest         |  1 +
 app-crypt/gcr/gcr-4.0.0.ebuild | 93 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index efe2493b734d..b9f08f384360 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1,3 +1,4 @@
 DIST gcr-3.41.0.tar.xz 1039744 BLAKE2B c646a04168310051d5b582a9d2f7ab9da89eef095e856e56b8d730600debead051ad8bb40eddb7457b1be2be3e092227dd886f647258a9c6a81d4bab728245f7 SHA512 455acc40ed77feeb35f9845b00229f468b322b7eda0b1b5abb0153f0a6ba29f3d0364df22225143f4caf130254a1258b3c7f934370e5142f2f64e1c3084b6f6e
 DIST gcr-3.41.1.tar.xz 1030368 BLAKE2B 9d254b7f2ad864c45200e58b685db97c1ffbc83d29ba8cbda94d30ec565aa3dc5a2535305dc63b3264131b68ec9e48f37ac30d5ba08d0ce156f3b6091cd62dc1 SHA512 dd70d41636ede863d05824b26823a8f572902f7a9b6f09b0c70586ef0d4c046864e6956130b9231850a515a9fbfcd56faf20354c1cf8f697f005827c048a2325
 DIST gcr-3.92.0.tar.xz 719608 BLAKE2B 770946582ada19d4282b0adfe77c4eabf08439430b89397a16829259162a940df44a5abf7e2dddd6e13c075449c7b4e5529dd95b781f67b4437246bca8989100 SHA512 bd566c8846e1ee99f82eefd9f7fbc5959c09bf383fef9c7bdc82b6c2c9c7634faaddcf6d91b0eca10b69a99e8f954272c3decf0594864351a48a5473e2bb5db3
+DIST gcr-4.0.0.tar.xz 715600 BLAKE2B 8f656cea44bc9c2ab710d33db61f26b7c7f1df73a59430945aa3c9e4acad503d7d93f916f90e2c4efb0e1379eabd9616e974a76c3d3564657b16cd46dd5954c6 SHA512 5d036710c9ae58016467e63b60ab18e461ec1db1740880dccf555dd8c555b382b1ceac3e3ee6fda22dce395e93ba8ecf0578d6c815d08c2790e618f7ca5bfd50

diff --git a/app-crypt/gcr/gcr-4.0.0.ebuild b/app-crypt/gcr/gcr-4.0.0.ebuild
new file mode 100644
index 000000000000..6ac349e0b8c4
--- /dev/null
+++ b/app-crypt/gcr/gcr-4.0.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="4/gcr4.4-gck2.2" # subslot = soname and soversion of libgcr and libgck
+
+IUSE="gtk gtk-doc +introspection systemd test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+DEPEND="
+	>=dev-libs/glib-2.68.0:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=app-crypt/p11-kit-0.19.0
+	>=app-crypt/libsecret-0.20
+	systemd? ( sys-apps/systemd:= )
+	gtk? ( gui-libs/gtk:4[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+	!<app-crypt/gcr-3.41.1-r1
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk gtk4)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		-Dssh_agent=true
+		$(meson_feature systemd)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/{gck-2,gcr-4} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}