[gentoo-commits] repo/gentoo:master commit in: app-misc/dvtm/

["Sam James" <sam@gentoo.org>]

commit:     053e6acf541a65c0dd708f9b23a8b7ff322f3613
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Thu Oct  6 15:11:49 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Oct  7 11:28:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=053e6acf

app-misc/dvtm: update EAPI 6 -> 8

Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Closes: https://github.com/gentoo/gentoo/pull/27663
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-misc/dvtm/dvtm-0.15-r6.ebuild | 62 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-misc/dvtm/dvtm-0.15-r6.ebuild b/app-misc/dvtm/dvtm-0.15-r6.ebuild
new file mode 100644
index 000000000000..85425583c5af
--- /dev/null
+++ b/app-misc/dvtm/dvtm-0.15-r6.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="Dynamic virtual terminal manager"
+HOMEPAGE="https://www.brain-dump.org/projects/dvtm/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="
+		https://github.com/martanne/dvtm
+		https://git.sr.ht/~martanne/dvtm
+		https://repo.or.cz/dvtm.git
+	"
+else
+	SRC_URI="https://www.brain-dump.org/projects/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND=">=sys-libs/ncurses-6.1:=[unicode(+)]"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.15-gentoo.patch
+	"${FILESDIR}"/${PN}-0.15-stop-installing-terminfo.patch
+)
+
+src_prepare() {
+	default
+
+	restore_config config.h
+}
+
+src_compile() {
+	tc-export PKG_CONFIG
+	emake CC="$(tc-getCC)" ${PN}
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" STRIP=true install
+
+	insinto /usr/share/${PN}
+	newins config.h ${PF}.config.h
+
+	dodoc README.md
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	elog "This ebuild has support for user defined configs"
+	elog "Please read this ebuild for more details and re-emerge as needed"
+	elog "if you want to add or remove functionality for ${PN}"
+}