[gentoo-commits] repo/gentoo:master commit in: games-simulation/openrct2/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     fab603ab3f1cd2424400e0d4e0c618213eb18406
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  5 20:31:17 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Oct  5 20:35:28 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fab603ab

games-simulation/openrct2: add 0.4.2

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 games-simulation/openrct2/Manifest              |   1 +
 games-simulation/openrct2/openrct2-0.4.2.ebuild | 167 ++++++++++++++++++++++++
 2 files changed, 168 insertions(+)

diff --git a/games-simulation/openrct2/Manifest b/games-simulation/openrct2/Manifest
index 251e73fe62fd..160a1ae4e3af 100644
--- a/games-simulation/openrct2/Manifest
+++ b/games-simulation/openrct2/Manifest
@@ -1,4 +1,5 @@
 DIST openrct2-0.4.1.tar.gz 14307739 BLAKE2B d50dd896128898725eb7bd347341dc23a5ef4e8c83d3334625f5484dc5d4214a6ba19981997291de3edb80baaf498e9b4fd83b460a2fd4fdc2100c080d3d0bb6 SHA512 795e94b025ebe8ce4386e59723e2442e950810652a1c95caa1e21a88bef5417c2cce18c93418788e75cd8e980ffda0dc73838693fbe2be108a4e269da9159f06
+DIST openrct2-0.4.2.tar.gz 16476190 BLAKE2B b1626c8cf8ec4100adb11e346515b68e6d7f5104bb95f756a04f170f0258b84a8ae84235c0defec5d994d1eb6c377feeadde1380d892a714f94469bd0cc5d689 SHA512 b047c4cfa4eb5e6257a9836bc85a1aab66504591c7a8f698b893290132d43d7e187a077d29b9f6fb712bfc62b9fcd063a70e7b5d36e2fc7dd61f3af0aff0163f
 DIST openrct2-objects-1.3.2.zip 3954437 BLAKE2B 21d79e35a3bad343a4f96e152f8b5f04820fc927557f0526e639f7c04ca1fac61804db02be57261deb01d65c81f67783ba9ed8e0230a90b2626fa2b63ed82857 SHA512 88b292961d728c1ad31dd9f68ba9a1201a59126887030b7b4a8d9fdbed758c1b9bd4f29fb924ddd3cf7b4c5fb7c95f576a00fabdef5a8403e287edeb1c740ff1
 DIST openrct2-objects-1.3.5.zip 4431827 BLAKE2B 238e1f97aae2b4958001b368b0cb7b86ed4a6999f9e45144a2d0e78d890df6f3d0edf49fe7a4e51766dc7ff1c26a6c814c6c5ad5836c46ced35efe34f8cab682 SHA512 7200a04b5f6e0f689859207554afc91fd53d9a3899eb88bc650c6883b18ffa7e6d1420a1efea0ab2e2926e10afeb352484ad04df425531ad3efc00dc6cb2acb1
 DIST openrct2-replays-0.0.67.zip 1479146 BLAKE2B 78e2872013e20ce389dd24d70aeeeb2fe3822dbc3bb6059308ad0f2014d0550fe26f85b7dbce7ed8373235e688e5a8e2817b16231a751871d22301d9e3d1ecf7 SHA512 41745238b61128777ae4fee1ecb7e9284d84d9b420d653b5371d1349bd00473a98beeaa41688903081390ad38b693cd5e54d230bfc2c255beabbef93ec326f69

diff --git a/games-simulation/openrct2/openrct2-0.4.2.ebuild b/games-simulation/openrct2/openrct2-0.4.2.ebuild
new file mode 100644
index 000000000000..744df62f60d7
--- /dev/null
+++ b/games-simulation/openrct2/openrct2-0.4.2.ebuild
@@ -0,0 +1,167 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake readme.gentoo-r1 xdg-utils
+
+MY_PN="OpenRCT2"
+MY_PN_OBJ="objects"
+MY_PN_RPL="replays"
+MY_PN_TS="title-sequences"
+MY_PV_OBJ="1.3.5"
+MY_PV_RPL="0.0.69"
+MY_PV_TS="0.4.0"
+
+DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
+HOMEPAGE="https://openrct2.org/"
+SRC_URI="
+	https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
+	https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
+	test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
+"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="dedicated +flac +opengl scripting test +truetype +vorbis"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	dev-libs/jansson:=
+	dev-libs/libzip:=
+	media-libs/libpng:=
+	net-misc/curl[ssl]
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2
+		media-libs/speexdsp
+		flac? ( media-libs/flac:= )
+		opengl? ( virtual/opengl )
+		vorbis? ( media-libs/libvorbis )
+	)
+	dev-libs/openssl:0=
+	scripting? ( dev-lang/duktape:= )
+	truetype? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+	)
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	dedicated? (
+		acct-group/openrct2
+		acct-user/openrct2
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	dev-cpp/nlohmann_json
+	test? ( dev-cpp/gtest )
+"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.4.0-include-additional-paths.patch"
+	"${FILESDIR}/${PN}-0.4.1-gtest-1.10.patch"
+)
+
+src_unpack() {
+	unpack "${P}".tar.gz
+
+	mkdir -p "${S}"/data/sequence || die
+	cd "${S}"/data/sequence || die
+	unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip
+
+	mkdir -p "${S}"/data/object || die
+	cd "${S}"/data/object || die
+	unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip
+
+	if use test; then
+		mkdir -p "${S}"/testdata/replays || die
+		cd "${S}"/testdata/replays || die
+		unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Don't treat warnings as errors.
+	sed -e 's/-Werror//' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	# Note: There is currently no support for Disord-RPC and Google Benchmark,
+	# as both packages do not exist in Gentoo, so support for them has been disabled.
+	local mycmakeargs=(
+		-DDISABLE_DISCORD_RPC=ON
+		$(usex !dedicated "-DDISABLE_FLAC=$(usex !flac)" "")
+		-DDISABLE_GOOGLE_BENCHMARK=ON
+		-DDISABLE_GUI=$(usex dedicated)
+		-DDISABLE_HTTP=OFF
+		-DDISABLE_IPO=ON
+		-DDISABLE_NETWORK=OFF
+		$(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
+		-DDISABLE_TTF=$(usex !truetype)
+		$(usex !dedicated "-DDISABLE_VORBIS=$(usex !vorbis)" "")
+		-DDOWNLOAD_OBJECTS=OFF
+		-DDOWNLOAD_REPLAYS=OFF
+		-DDOWNLOAD_TITLE_SEQUENCES=OFF
+		-DENABLE_SCRIPTING=$(usex scripting)
+		-DOPENRCT2_USE_CCACHE=OFF
+		-DPORTABLE=OFF
+		-DSTATIC=OFF
+		-DWITH_TESTS=$(usex test)
+		-DUSE_MMAP=ON
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Since the tests need the OpenRCT2 data,
+	# we need to symlink them into the build directory,
+	# otherwise some tests will fail, as they don't find the OpenRCT2 data.
+	# It is currently not possible to override that path.
+	# See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
+	ln -s "${S}"/data "${BUILD_DIR}" || die
+
+	cmake_src_test
+}
+
+src_install() {
+	use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )
+
+	cmake_src_install
+
+	if use dedicated; then
+		newinitd "${FILESDIR}"/openrct2.initd openrct2
+		newconfd "${FILESDIR}"/openrct2.confd openrct2
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}