[gentoo-commits] repo/gentoo:master commit in: dev-util/intel-graphics-system-controller/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     557b96ab49f15d2042f2fdb3fece88e2eae476b9
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  5 20:25:28 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Oct  5 20:35:25 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=557b96ab

dev-util/intel-graphics-system-controller: add 0.8.4

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-util/intel-graphics-system-controller/Manifest |  1 +
 .../intel-graphics-system-controller-0.8.4.ebuild  | 50 ++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/dev-util/intel-graphics-system-controller/Manifest b/dev-util/intel-graphics-system-controller/Manifest
index c394b28a708c..abce9906d06b 100644
--- a/dev-util/intel-graphics-system-controller/Manifest
+++ b/dev-util/intel-graphics-system-controller/Manifest
@@ -1 +1,2 @@
 DIST intel-graphics-system-controller-0.8.0.tar.gz 166364 BLAKE2B 86a1aeb328554a7260c57bb4513dc236e34aa758b53d4d743562639326d22963742fe1ceca89df648187dfe8e7233c5306977241bb9d37e765d21f52d0073873 SHA512 a2fd38717cd1d02270c97eda20fe4294c634a0520293cdd396b93d474eed2ec903ed565a2d15d5e2671424000bb21c3f04b9812a4c050aa68383a75dee0281ef
+DIST intel-graphics-system-controller-0.8.4.tar.gz 173733 BLAKE2B c51f21bd2093d44c12ce10b4e5990a4428294093c6a8ccd90b01be30d918ac0898ea57b68ad004f4f477a7049e5060521c7fb1547d09f6e30cae8eab41090a69 SHA512 948c2043765c7a5b5dd9c350474725871601a76d292fd34c57c81b492945107ba2519b6a3f113cefed158adb7ac61164e85284be4683d1f48870650fdba969ad

diff --git a/dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.8.4.ebuild b/dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.8.4.ebuild
new file mode 100644
index 000000000000..b874403f416f
--- /dev/null
+++ b/dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.8.4.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="igsc"
+MY_P="${MY_PN}-${PV}"
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="Intel graphics system controller firmware update library"
+HOMEPAGE="https://github.com/intel/igsc"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/V${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="+cli doc"
+
+RDEPEND="dev-libs/metee:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		app-doc/doxygen
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CLI="$(usex cli)"
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_PERF="OFF"
+		-DENABLE_WERROR="OFF"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DENABLE_TESTS="OFF"
+	)
+
+	cmake_src_configure
+}