[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     018a6c653aa92a50befed074f1ab43bb3fdf58b7
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  5 05:38:35 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Oct  5 05:53:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=018a6c65

dev-python/django: add 4.1.2

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/django/Manifest            |   2 +
 dev-python/django/django-4.1.2.ebuild | 103 ++++++++++++++++++++++++++++++++++
 2 files changed, 105 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 636d6be66611..8bfd890d0470 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -4,5 +4,7 @@ DIST Django-4.0.7.checksum.txt 2551 BLAKE2B 6fa44707d33af485d3c55096dcc650b4e238
 DIST Django-4.0.7.tar.gz 10407810 BLAKE2B 77c994d042ace329699aa33e14098cbcd4f24fa4db880dd78ed87828b02c25298a1c1664511547de53eb80ebade7bdfb16412a615027e512ded437ae7de79b54 SHA512 51574ab7423a3948318a5985f74bd781269bf1c95dc77838c11e8f9d5e9233f0a3be5dfa4798d523473b9f1fd3196d4c10284e3a28d9543084b2a63179167731
 DIST Django-4.1.1.checksum.txt 2548 BLAKE2B aee8b104cf680645aabef0f2a18c029414435093b40eaf8f61dfecda3745b364a64e340136cc35c416708b150074d7fa18d65ab9619ed7e477d94dbfcb3d769c SHA512 62c542e4f6574ef82563ba8b5389d1408506cc4f48eb3781109d00ddaeb92f93d28536e913c120171bdbe979834baf4c28a14bc934b0540a75d1a5b7dba97d5e
 DIST Django-4.1.1.tar.gz 10474304 BLAKE2B 5349e095824db2aadfd8962932916ec2d01fa5f25287cc3b2184d921b9dd6c8d1e52a4648dc8f4cd87da03a261a0406fe7ef521667513a734bd1dae0754ed18f SHA512 49d0003b1a582cb27163df4bb30eda21d4e3bb101eb5ca0dab3ec1d5b4d99b6481b2edb4fd0e89ba8a06d0266d24ca70c92cd51b9e4c4eab818d68098e8ef4d8
+DIST Django-4.1.2.checksum.txt 2552 BLAKE2B 3786a5824ce981fa66e4173b4fe985ccca4084c3bf2a67cce05d527768c54afec69efb2cd79578fff3dfdcf6dcf26536208dc1ae203348e0648a1d2b27373469 SHA512 01bd342832d626efc03f0704b2e7a8287830cf8ccde53b0d8b9d20c10eb10b6d799611e143196f121b43967e72e08a2db032fec81638c3d58e541ccbd598bb1e
+DIST Django-4.1.2.tar.gz 10509111 BLAKE2B a6786e214967a3a789fd42218e3422f6985efa8e0f4be807d6afb1dd293ef37a201850af1728e72ae0bf429da3aac41dbfa95926f426e9bfe4b3f7f77a6e2934 SHA512 734d782777269b714f6648509d010649e7df2790e438ab2439ba1c4fc1cc9d37626b77ea9d60806c215ab666feb4555b1360ebcdc8cb16e85da8c950b262bbd7
 DIST Django-4.1.checksum.txt 2533 BLAKE2B 263c3719c572347cb5d2087b960a47f0e6ac409a94499cd5ee8ec619c3388d29354c10813d4b3d2a0d6bd73ca52f562a6ae89a3d9340d5ea478a80cc30284467 SHA512 96d0a66c40261530d65bdde34ba1fc2e650690821b0f52900d60ab85162debc64e33e089f90e2b106235fc47581a54dc6432968534837c1a71a887b40fdd4f36
 DIST Django-4.1.tar.gz 10484595 BLAKE2B 29a833330862abcf69bf082af6df08986443d34abfe821bd307fba6ddd73dd00be7ae8d3e809fe97db0b22f9062daa760cbe01da8d773e1528f583938959f775 SHA512 f0f7e627b3c474c886cb2476f900222d2623e1ed1da1ac6b23ac618ff49e330edc2efd47b275cb02b8bcb254126bf3c926462c616bb0abee1cd433715f5184da

diff --git a/dev-python/django/django-4.1.2.ebuild b/dev-python/django/django-4.1.2.ebuild
new file mode 100644
index 000000000000..5a30981b4f33
--- /dev/null
+++ b/dev-python/django/django-4.1.2.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.5.2[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}