[gentoo-commits] repo/gentoo:master commit in: net-irc/ngircd/

["Sam James" <sam@gentoo.org>]

commit:     4cbd0d999c01c8eea326f13e05abc4649e69e68a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Oct  4 07:17:00 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Oct  4 09:08:58 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4cbd0d99

net-irc/ngircd: drop 26.1-r4

Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-irc/ngircd/ngircd-26.1-r4.ebuild | 114 -----------------------------------
 1 file changed, 114 deletions(-)

diff --git a/net-irc/ngircd/ngircd-26.1-r4.ebuild b/net-irc/ngircd/ngircd-26.1-r4.ebuild
deleted file mode 100644
index 383cb5fad69a..000000000000
--- a/net-irc/ngircd/ngircd-26.1-r4.ebuild
+++ /dev/null
@@ -1,114 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/alexbarton.asc"
-inherit tmpfiles verify-sig
-
-DESCRIPTION="An IRC server written from scratch"
-HOMEPAGE="https://ngircd.barton.de/"
-SRC_URI="https://arthur.barton.de/pub/${PN}/${P}.tar.xz"
-SRC_URI+=" verify-sig? ( https://arthur.barton.de/pub/${PN}/${P}.tar.xz.sig )"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 x86 ~x64-macos"
-IUSE="debug gnutls ident irc-plus +ipv6 pam +ssl strict-rfc tcpd test zlib"
-
-# Flaky test needs investigation (bug 719256)
-RESTRICT="test"
-
-RDEPEND="
-	acct-user/ngircd
-	irc-plus? ( virtual/libiconv )
-	ident? ( net-libs/libident )
-	pam? ( sys-libs/pam )
-	ssl? (
-		gnutls? ( net-libs/gnutls:= )
-		!gnutls? (
-			dev-libs/openssl:0=
-		)
-	)
-	tcpd? ( sys-apps/tcp-wrappers )
-	zlib? ( sys-libs/zlib )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	test? (
-		dev-tcltk/expect
-		net-misc/netkit-telnetd
-	)
-	verify-sig? ( sec-keys/openpgp-keys-alexbarton )
-"
-
-src_prepare() {
-	default
-
-	if ! use prefix ; then
-		sed -i \
-			-e "/;ServerUID = /s/65534/ngircd/" \
-			-e "/;ServerGID = /s/65534/ngircd/" \
-			doc/sample-ngircd.conf.tmpl || die
-	fi
-
-	# make pidfiles work out-of-the-box
-	sed -i \
-		-e "/;PidFile = /s/;//" \
-		-e "/;ServerUID = /s/;//" \
-		-e "/;ServerGID = /s/;//" \
-		doc/sample-ngircd.conf.tmpl || die
-
-	# Note that if we need to use automake, we need a certain version (for now):
-	# https://github.com/ngircd/ngircd/issues/261
-	# WANT_AUTOMAKE=1.11
-	# eautomake
-}
-
-src_configure() {
-	local myeconf=(
-		--sysconfdir="${EPREFIX}"/etc/${PN}
-		$(use_enable debug sniffer)
-		$(use_enable debug)
-		$(use_enable irc-plus ircplus)
-		$(use_enable ipv6)
-		$(use_enable strict-rfc)
-		$(use_with irc-plus iconv)
-		$(use_with ident)
-		$(use_with pam)
-		$(use_with tcpd tcp-wrappers)
-		$(use_with zlib)
-	)
-
-	if use ssl ; then
-		if use gnutls ; then
-			myeconf+=(
-				$( use_with gnutls )
-			)
-		else
-			myeconf+=(
-				$( use_with !gnutls openssl )
-			)
-		fi
-	fi
-
-	econf "${myeconf[@]}"
-}
-
-src_install() {
-	default
-
-	fowners ngircd:ngircd /etc/ngircd/ngircd.conf
-	newinitd "${FILESDIR}"/ngircd.init-r2.d ngircd
-	newconfd "${FILESDIR}"/ngircd.conf.d ngircd
-	dotmpfiles "${FILESDIR}"/ngircd.conf
-}
-
-pkg_postinst() {
-	if [[ -z ${REPLACING_VERSIONS} ]] && use pam ; then
-		elog "ngircd will use PAMIsOptionalPAM by default, please change this option."
-		elog "You may not be able to login until you change this."
-	fi
-
-	tmpfiles_process ngircd.conf
-}