[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgusb/

["Matt Turner" <mattst88@gentoo.org>]

commit:     0d828ab76ae41b05944911b4b0bbb8fe463d6fa5
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Mon Oct  3 02:46:16 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Mon Oct  3 02:52:21 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0d828ab7

dev-libs/libgusb: Version bump to 0.4.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libgusb/Manifest             |  1 +
 dev-libs/libgusb/libgusb-0.4.1.ebuild | 72 +++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/dev-libs/libgusb/Manifest b/dev-libs/libgusb/Manifest
index 652ea0353b83..12cf0ebe277f 100644
--- a/dev-libs/libgusb/Manifest
+++ b/dev-libs/libgusb/Manifest
@@ -1,2 +1,3 @@
 DIST libgusb-0.3.10.tar.xz 42972 BLAKE2B 4c49aa15cbbbb56d5ee5b896adb3e34b45332cd846933fd3aa86a645e7d897418d0e7a30d9972980e6527f1e60fc6e579f5df119708a12b3e504ff695c94d922 SHA512 66bd7c292cb9df2799b02acd48dc4b07794e7339ea1bd6473ea512dfec1b8e7e58abbd40f16a2a4805240cc8df4aec050335edb4f4178ad12ac5275438b8ae59
 DIST libgusb-0.4.0.tar.xz 49844 BLAKE2B 9f2b552d8f224b4c8209f8adaec9d9131adf6ea938a25dca2ce2e6a8b4f154e3d9d6c75dc5bb1d42c6f00b2727136156c76f6291156f2c364aaa3343990ac3bd SHA512 80aa3dea90a7a49d1108cddf066232dcb3c3a41bbbec5e598fbb1f5a554997b2fbc3ad95e514813ffb575a018585deef6ec16ba4533eefb3c1a086e1cc4534ce
+DIST libgusb-0.4.1.tar.xz 50384 BLAKE2B e6613758bb24710ce8326e12a6fb6a8708135c0c826a7b8f87fa95df5dba04bf5155c2daf42713d5f74478ca457f795c2f553acbdef1a8b1df0019f7832b019f SHA512 de0a74d75b00699e6b113c0ec334f7385e892317b2814047f7990fed361d78d6acdb2148ded9e602cf3537ff87e8c10017da2315923db4cb3f5c29f75418e9b8

diff --git a/dev-libs/libgusb/libgusb-0.4.1.ebuild b/dev-libs/libgusb/libgusb-0.4.1.ebuild
new file mode 100644
index 000000000000..ae1b186b47a5
--- /dev/null
+++ b/dev-libs/libgusb/libgusb-0.4.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="GObject wrapper for libusb"
+HOMEPAGE="https://github.com/hughsie/libgusb"
+SRC_URI="https://people.freedesktop.org/~hughsient/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2[${MULTILIB_USEDEP}]
+	virtual/libusb:1[udev,${MULTILIB_USEDEP}]
+	>=dev-libs/json-glib-1.1.1[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	sys-apps/hwdata
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-util/umockdev-0.17.7[${MULTILIB_USEDEP}] )"
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/setuptools[${PYTHON_USEDEP}]')
+	gtk-doc? ( dev-util/gi-docgen )
+	vala? ( $(vala_depend) )
+	virtual/pkgconfig
+"
+
+python_check_deps() {
+	python_has_version "dev-python/setuptools[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_library=shared
+		$(meson_use test tests)
+		$(meson_native_use_bool vala vapi)
+		-Dusb_ids="${EPREFIX}"/usr/share/hwdata/usb.ids
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_bool introspection)
+		$(meson_feature test umockdev)
+
+	)
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/ || die
+		mv "${ED}"/usr/share/{doc,gtk-doc}/libgusb || die
+	fi
+}