[gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/

["Matt Turner" <mattst88@gentoo.org>]

commit:     8849c84255353b759d99be4fbe31d3525e323d10
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Oct  1 16:56:48 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Oct  1 17:16:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8849c842

gnome-extra/evolution-data-server: Drop old versions

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/evolution-data-server/Manifest         |   1 -
 .../evolution-data-server-3.44.3-r1.ebuild         | 159 ---------------------
 2 files changed, 160 deletions(-)

diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index e8d4fd13d43c..ab7b26eaf5a3 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1,3 +1,2 @@
-DIST evolution-data-server-3.44.3.tar.xz 4783696 BLAKE2B 1ce3336b3e35d011737cb171112c29589b3a172fbc6d2964259b2bfeb8796a53c8c34665277d8cd6db0cff11905425ddd19da52baf6f473948b3879f6506c831 SHA512 b03b1c52a93a3f4fa5eece998eea075086e232953e8485f0b551bd7bfebbbf935288052d55cfaf3ff57b121b14f64db2ac8ce41d54d27aab39e683c4d3b54cac
 DIST evolution-data-server-3.44.4.tar.xz 4784388 BLAKE2B dd5b7094af9c66b710d61de282ff7e223fd87524f0135b7fc2c962d7829a8ed25a90a5fa73d155b692e28d9d18807f8c8731efbfb32613e2e1a020008739beae SHA512 385137f1e412b5c5bcd496d493da4657f8bb6e72519f6e62ab1a683c729082ea0ddcf7b5dae8c0cdf37cb279a1cf59ffb6dd61009c693001d03a0d54264e979a
 DIST evolution-data-server-3.46.0.tar.xz 4817048 BLAKE2B 5c07137659132fca4e2e42d616d3b7e26317f44009de1c9582105a65036884c5b1f7521ac325e2a74a6493362a38b6761d78dabd00b9e64b51a352bcd1d225af SHA512 3aef4ef51e5be2c5e392a2b2781283bb75d8e7d08a3a0daae6be488d14e998779b992095d12889d2d6afe5c732394090f99fa9a866e8825eecdcde2bf6b24ec1

diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.44.3-r1.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.44.3-r1.ebuild
deleted file mode 100644
index fddb566738a1..000000000000
--- a/gnome-extra/evolution-data-server/evolution-data-server-3.44.3-r1.ebuild
+++ /dev/null
@@ -1,159 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake db-use flag-o-matic gnome2 vala virtualx
-
-DESCRIPTION="Evolution groupware backend"
-HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
-
-# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
-LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
-SLOT="0/63-26-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
-
-IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ipv6 ldap kerberos oauth vala +weather"
-REQUIRED_USE="vala? ( introspection )"
-
-KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
-
-# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
-# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
-# glib-2.70 for build-time optional GPowerProfileMonitor
-# <libgweather-4.2.0 because of libsoup:3 transition
-gdata_depend=">=dev-libs/libgdata-0.17.7:="
-RDEPEND="
-	>=app-crypt/gcr-3.4:=
-	>=app-crypt/libsecret-0.5[crypt]
-	>=dev-db/sqlite-3.7.17
-	>=dev-libs/glib-2.70:2
-	>=dev-libs/libical-3.0.8:=[glib,introspection?]
-	>=dev-libs/libxml2-2
-	>=dev-libs/nspr-4.4
-	>=dev-libs/nss-3.9
-	>=net-libs/libsoup-2.58:2.4
-
-	dev-libs/icu:=
-	sys-libs/zlib:=
-	virtual/libiconv
-
-	berkdb? ( >=sys-libs/db-4:= )
-	gtk? (
-		>=app-crypt/gcr-3.4[gtk]
-		>=x11-libs/gtk+-3.16:3
-		>=media-libs/libcanberra-0.25[gtk3]
-	)
-	oauth? (
-		>=dev-libs/json-glib-1.0.4
-		>=net-libs/webkit-gtk-2.28.0:4
-		${gdata_depend}
-	)
-	gnome-online-accounts? (
-		>=net-libs/gnome-online-accounts-3.8:=
-		${gdata_depend} )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
-	kerberos? ( virtual/krb5:= )
-	ldap? ( >=net-nds/openldap-2:= )
-	weather? (
-		>=dev-libs/libgweather-3.91.0:4=
-		<dev-libs/libgweather-4.2.0:4=
-	)
-"
-DEPEND="${RDEPEND}
-	vala? ( $(vala_depend)
-		net-libs/libsoup:2.4[vala]
-		dev-libs/libical[vala]
-		oauth? ( dev-libs/libgdata[vala] )
-		gnome-online-accounts? ( dev-libs/libgdata[vala] )
-	)
-"
-BDEPEND="
-	dev-util/gdbus-codegen
-	dev-util/glib-utils
-	dev-util/gperf
-	gtk-doc? ( >=dev-util/gtk-doc-1.14
-		app-text/docbook-xml-dtd:4.1.2 )
-	>=dev-util/intltool-0.35.5
-	>=sys-devel/gettext-0.18.3
-	virtual/pkgconfig
-"
-
-# Some tests fail due to missing locales.
-# Also, dbus tests are flaky, bugs #397975 #501834
-# It looks like a nightmare to disable those for now.
-RESTRICT="test !test? ( test )"
-
-# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
-src_prepare() {
-	use vala && vala_setup
-	cmake_src_prepare
-	gnome2_src_prepare
-
-	eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
-
-	# Make CMakeLists versioned vala enabled
-	sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
-		-e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
-		-i "${S}"/CMakeLists.txt || die
-}
-
-src_configure() {
-	# /usr/include/db.h is always db-1 on FreeBSD
-	# so include the right dir in CPPFLAGS
-	use berkdb && append-cppflags "-I$(db_includedir)"
-
-	local google_enable
-	if use oauth || use gnome-online-accounts; then
-		google_enable="ON"
-	else
-		google_enable="OFF"
-	fi
-
-	# phonenumber does not exist in tree
-	local mycmakeargs=(
-		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
-		-DENABLE_GTK_DOC=$(usex gtk-doc)
-		-DWITH_PRIVATE_DOCS=$(usex gtk-doc)
-		-DENABLE_SCHEMAS_COMPILE=OFF
-		-DENABLE_INTROSPECTION=$(usex introspection)
-		-DWITH_KRB5=$(usex kerberos)
-		-DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
-		-DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
-		-DWITH_OPENLDAP=$(usex ldap)
-		-DWITH_PHONENUMBER=OFF
-		-DENABLE_SMIME=ON
-		-DENABLE_GTK=$(usex gtk)
-		-DENABLE_CANBERRA=$(usex gtk)
-		-DENABLE_OAUTH2=$(usex oauth)
-		-DENABLE_EXAMPLES=OFF
-		-DENABLE_GOA=$(usex gnome-online-accounts)
-		-DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
-		# ENABLE_BACKTRACES requires libdwarf ?
-		-DENABLE_IPV6=$(usex ipv6)
-		-DENABLE_WEATHER=$(usex weather)
-		-DWITH_GWEATHER4=ON
-		-DENABLE_GOOGLE=${google_enable}
-		-DENABLE_LARGEFILE=ON
-		-DENABLE_VALA_BINDINGS=$(usex vala)
-	)
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-}
-
-src_test() {
-	virtx cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	if use ldap; then
-		insinto /etc/openldap/schema
-		doins "${FILESDIR}"/calentry.schema
-		dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
-	fi
-}