[gentoo-commits] repo/gentoo:master commit in: dev-python/trio/, profiles/features/wd40/

[gentoo-commits] repo/gentoo:master commit in: dev-python/trio/, profiles/features/wd40/

[Andrew Ammerlaan]

commit:     ee23fb4365bb824ce2363b72d2b816e43562ea72
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 28 11:45:10 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Wed Sep 28 11:45:10 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee23fb43

dev-python/trio: add 0.22.0

Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 dev-python/trio/Manifest            |  1 +
 dev-python/trio/trio-0.22.0.ebuild  | 68 +++++++++++++++++++++++++++++++++++++
 profiles/features/wd40/package.mask |  1 +
 3 files changed, 70 insertions(+)

diff --git a/dev-python/trio/Manifest b/dev-python/trio/Manifest
index e0e21672d738..719ae9d2c64e 100644
--- a/dev-python/trio/Manifest
+++ b/dev-python/trio/Manifest
@@ -1 +1,2 @@
 DIST trio-0.21.0.gh.tar.gz 491228 BLAKE2B e5f65d3aa9e4bc0c449e3986048d63fe3001a2eee96dbe5d8c088e0fce786b1d50861b47170baa7cced097938b16c92f0efd51518404a5e0ea6a17a48d656823 SHA512 383b11f264ddf4c78eb75829472826ebacf32d063790e8d4681d5df2f21c4f9287884db1752fd19976b674643adf7299816d4404e3032193ef90f522ad9cfa79
+DIST trio-0.22.0.gh.tar.gz 517482 BLAKE2B ab1fcb22d8f0ed9c8de831a9384b55ab433811863974cb767cb0ea4eb3a0df7372b5ea2c2d4c2af3ca1d3c8c3144d5546ad8cc68276b17ecb3d20ea1858ba9e0 SHA512 45b813d6cc65f8d49f70cb0ea7f33593fed0cc5989c60ba449f0b38c4759604aa7360cd016758fd364438b92516be549edf1efd583c7f5ee2de8813334f182bc

diff --git a/dev-python/trio/trio-0.22.0.ebuild b/dev-python/trio/trio-0.22.0.ebuild
new file mode 100644
index 000000000000..0762903a78dd
--- /dev/null
+++ b/dev-python/trio/trio-0.22.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for async concurrency and I/O"
+HOMEPAGE="
+	https://github.com/python-trio/trio/
+	https://pypi.org/project/trio/
+"
+SRC_URI="
+	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/async_generator-1.9[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/exceptiongroup-1.0.0_rc9[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/outcome[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	dev-python/sortedcontainers[${PYTHON_USEDEP}]
+"
+# NB: we're ignoring tests that require pyopenssl
+BDEPEND="
+	test? (
+		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/immutables \
+	dev-python/sphinxcontrib-trio \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these tests require internet access
+		trio/tests/test_ssl.py
+		trio/tests/test_highlevel_ssl_helpers.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# Times out on slower arches (ia64 in this case)
+		# https://github.com/python-trio/trio/issues/1753
+		trio/tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
+
+		# incompatible ipython version?
+		trio/_core/tests/test_multierror.py::test_ipython_exc_handler
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m "not redistributors_should_skip"
+}

diff --git a/profiles/features/wd40/package.mask b/profiles/features/wd40/package.mask
index 9e34df407953..73cf842b502d 100644
--- a/profiles/features/wd40/package.mask
+++ b/profiles/features/wd40/package.mask
@@ -50,6 +50,7 @@ dev-python/spur
 dev-python/sshtunnel
 dev-python/tempest
 dev-python/trustme
+>=dev-python/trio-0.22.0
 dev-python/twine
 dev-python/watchfiles
 dev-ros/roswtf