[gentoo-commits] repo/gentoo:master commit in: games-action/minetest/

["Marek Szuba" <marecki@gentoo.org>]

commit:     7b34fcd9b3a3ff6ec14c07dbf609cccbcc46ad96
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 26 00:47:33 2022 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Mon Sep 26 01:01:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7b34fcd9

games-action/minetest: drop 5.6.0-r1

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 games-action/minetest/Manifest                 |   1 -
 games-action/minetest/minetest-5.6.0-r1.ebuild | 144 -------------------------
 2 files changed, 145 deletions(-)

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index d0e808804a78..2032f7e2d163 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -1,2 +1 @@
-DIST minetest-5.6.0.tar.gz 9922682 BLAKE2B 10787b9bbc397d3d214b22640a830fc429bd8292541e0b71b50d05d483f87469cedf03fcf7a898bd83486c55911439a9804eab2bca58cd464a69adaa76b4f820 SHA512 e87c4036f17a61d3e623b2f48e3611ba1bc0177b5d58330fe6e64a74075c78ab7cd5eb7b855097ce98819112a54857324237f7d3b81ec504a1f608444e74a630
 DIST minetest-5.6.1.tar.gz 9924663 BLAKE2B 509b8073a4e82ecff008f692ebdd7a8f35ff5222ba1095937d24870404cca848b80891887837e03d86c117568f9bbee1f92fb958640e06107230673e79d7f813 SHA512 15d2ce3b1150f077ff933a04f0ba8e02c71ee60a0edb636d1511d4e90244a34a14d7e5c4b47bee4de96cd179249a5a6963d7a092084f46c0fa54c9ff431a5265

diff --git a/games-action/minetest/minetest-5.6.0-r1.ebuild b/games-action/minetest/minetest-5.6.0-r1.ebuild
deleted file mode 100644
index 6d626a4d0046..000000000000
--- a/games-action/minetest/minetest-5.6.0-r1.ebuild
+++ /dev/null
@@ -1,144 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_BUILD_TYPE="Release"
-LUA_COMPAT=( lua5-1 luajit )
-
-inherit cmake flag-o-matic lua-single systemd xdg
-
-DESCRIPTION="A free open-source voxel game engine with easy modding and game creation"
-HOMEPAGE="https://www.minetest.net"
-SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~riscv"
-IUSE="+client +curl doc leveldb ncurses nls postgres prometheus redis +server +sound spatial test"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}
-	|| ( client server )"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="${LUA_DEPS}
-	$(lua_gen_impl_dep 'deprecated' lua5-1)
-	app-arch/zstd
-	dev-db/sqlite:3
-	dev-libs/gmp:0=
-	dev-libs/jsoncpp:=
-	sys-libs/zlib
-	client? (
-		>=dev-games/irrlicht-mt-1.9.0.7
-		media-libs/freetype:2
-		media-libs/libpng:0=
-		media-libs/libjpeg-turbo
-		virtual/opengl
-		x11-libs/libX11
-		x11-libs/libXxf86vm
-		sound? (
-			media-libs/libvorbis
-			media-libs/openal
-		)
-	)
-	curl? ( net-misc/curl )
-	leveldb? ( dev-libs/leveldb:= )
-	ncurses? ( sys-libs/ncurses:0= )
-	nls? ( virtual/libintl )
-	postgres? ( >=dev-db/postgresql-9.5:= )
-	prometheus? ( dev-cpp/prometheus-cpp )
-	redis? ( dev-libs/hiredis:= )
-	server? (
-		acct-group/minetest
-		acct-user/minetest
-		>=dev-games/irrlicht-mt-headers-1.9.0.7
-	)
-	spatial? ( sci-libs/libspatialindex:= )"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	doc? (
-		app-doc/doxygen
-		media-gfx/graphviz
-	)
-	nls? ( sys-devel/gettext )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-5.4.1-system_puc_lua.patch
-	"${FILESDIR}"/${PN}-5.6.0-no_upstream_optflags.patch
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# remove bundled libraries other than bitop
-	rm -rf lib/{gmp,jsoncpp,lua} || die
-
-	# To avoid TEXTRELs on riscv
-	append-flags -fPIC
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_CLIENT=$(usex client)
-		-DBUILD_SERVER=$(usex server)
-		-DBUILD_UNITTESTS=$(usex test)
-		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
-		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
-		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
-		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
-		-DCUSTOM_MANDIR="${EPREFIX}/usr/share/man"
-		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
-		-DENABLE_CURL=$(usex curl)
-		-DENABLE_CURSES=$(usex ncurses)
-		-DENABLE_GETTEXT=$(usex nls)
-		-DENABLE_GLES=no
-		-DENABLE_LEVELDB=$(usex leveldb)
-		-DENABLE_LUAJIT=$(usex lua_single_target_luajit)
-		-DENABLE_POSTGRESQL=$(usex postgres)
-		-DENABLE_PROMETHEUS=$(usex prometheus)
-		-DENABLE_REDIS=$(usex redis)
-		-DENABLE_SPATIAL=$(usex spatial)
-		-DENABLE_SOUND=$(usex sound)
-		-DENABLE_SYSTEM_GMP=1
-		-DENABLE_SYSTEM_JSONCPP=1
-		-DRUN_IN_PLACE=0
-	)
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-
-	if use doc; then
-		cmake_src_compile doc
-		HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
-	fi
-}
-
-src_install() {
-	cmake_src_install
-
-	if use server; then
-		keepdir /etc/minetest
-		fowners root:minetest /etc/minetest
-		fperms 2750 /etc/minetest
-
-		keepdir /var/log/minetest
-		fowners minetest:minetest /var/log/minetest
-
-		newconfd "${FILESDIR}"/minetestserver.confd minetest-server
-		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
-
-		systemd_newunit "${FILESDIR}"/minetestserver_default.service minetest-server.service
-		systemd_newunit "${FILESDIR}"/minetestserver_template.service minetest-server@.service
-
-		insinto /etc/logrotate.d
-		newins "${FILESDIR}"/minetestserver.logrotate minetest-server
-	fi
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-}