[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

["Sam James" <sam@gentoo.org>]

commit:     f91c33c2f6527daca331b0cbe4eac778458b63ce
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 25 04:32:31 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Sep 25 04:32:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f91c33c2

dev-util/diffoscope: add 222

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-222.ebuild | 109 ++++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 85a6b8c52131..4ba2aa825a09 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,2 +1,3 @@
 DIST diffoscope-219.tar.gz 2711533 BLAKE2B 1b244a36ca2622244fb1f11f8fc895680bd1d77b544421e5e2c3662294fdf8e7efe3b67e370a83089c180f3c8563562847cc8b09bec85426e1b05f340575b724 SHA512 615b82cbd2b1a8bcdfae4274c051e4be52fb8ea90c5e56b041dd1d8c520c759d09cd4c080b31154257828316f7b4c0ac79cf0b1e09d762271ce01ffde353ee7a
 DIST diffoscope-221.tar.gz 3145331 BLAKE2B 76369a7719f9a256ca61cc097bc439c5ef267370b78b5e25c466f351fc262b6a9a18f2f82d88ae86fd382a11900c4350ff79c6217c53df42ad56706ee58fa42b SHA512 145390374378f699f7689af0e35897bc9d75cd805722f0db66e689135186eb43def17ec5aac4adf8f7e0045cbddec8a31dc5c8b68eb4e7b0d3bd1f0661f26416
+DIST diffoscope-222.tar.gz 3145249 BLAKE2B ae91a16b4c21754d4c677922fed0a2f6102ba1ee370eac42a4008fcd0898adc7b1e86a900476f08eae8705353f05837daf4fcc4026d5beb27ab982b72a0e12d7 SHA512 b4f2e17fbb755517d922dfcbc0ae57544a89600338bed7d98d59ab024ddc13bcedcddfa6ee808530e163b3f6c3cf627b159b9d0a011765d03a9268839226590f

diff --git a/dev-util/diffoscope/diffoscope-222.ebuild b/dev-util/diffoscope/diffoscope-222.ebuild
new file mode 100644
index 000000000000..bd5c0dd544f8
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-222.ebuild
@@ -0,0 +1,109 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="ncurses"
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/tlsh[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+EPYTEST_DESELECT=(
+	# Test seems to use different tarball
+	tests/test_presenters.py::test_text_proper_indentation
+
+	# Needs triage
+	tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+	tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+	# img2txt based failures, bug #797688
+	tests/comparators/test_ico_image.py::test_diff
+	tests/comparators/test_ico_image.py::test_diff_meta
+	tests/comparators/test_ico_image.py::test_diff_meta2
+	tests/comparators/test_ico_image.py::test_has_visuals
+	tests/comparators/test_jpeg_image.py::test_diff
+	tests/comparators/test_jpeg_image.py::test_compare_non_existing
+	tests/comparators/test_jpeg_image.py::test_diff_meta
+	tests/comparators/test_jpeg_image.py::test_has_visuals
+
+	# docx2txt based falures, bug #797688
+	tests/comparators/test_docx.py::test_diff
+
+	# Formatting
+	tests/test_source.py::test_code_is_black_clean
+)
+
+distutils_enable_tests pytest