[gentoo-commits] repo/gentoo:master commit in: media-gfx/simple-scan/

["Matt Turner" <mattst88@gentoo.org>]

commit:     d6672c05e54a501e1f89ae5efa3a4e8c8204f632
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 24 15:12:30 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Sep 24 15:33:43 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d6672c05

media-gfx/simple-scan: Version bump to 42.5

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/simple-scan/Manifest                |  1 +
 media-gfx/simple-scan/simple-scan-42.5.ebuild | 73 +++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/media-gfx/simple-scan/Manifest b/media-gfx/simple-scan/Manifest
index 24e51e762427..dfc58b126bc2 100644
--- a/media-gfx/simple-scan/Manifest
+++ b/media-gfx/simple-scan/Manifest
@@ -1 +1,2 @@
 DIST simple-scan-42.1.tar.xz 1100296 BLAKE2B 86d22abb8e3f72f19ab856d8e3578f57f71bc8e34ee5bb6e3809f160bc733b7f5753b947cbd12714829b29662087cdb601687cdd9ca1b1cbba41e543ce033ed2 SHA512 c4919ade08a30ee185eb4c62f59777fc360aa35c009f033ee9a9d10e23104fc0c44016509551e3d8de2948a3657c6c4d6c2fbbd955c4c09c6698d6733a55cfce
+DIST simple-scan-42.5.tar.xz 1193500 BLAKE2B ba6299e351e12a996b55a2c0c213290ea8b1faa490e7b6950ef961ca9c6f65522370064afe655f305fbfcd8dd225b0d22def10fbe3d358584c71933030e72003 SHA512 d479d11fb735e4f63eeb1917d00befe71c1c2128dd425f57f8069c0ae7132053c7259c11139be3c59a9ad1e27367f08174a8dc2632255d105705a36b3871a7f4

diff --git a/media-gfx/simple-scan/simple-scan-42.5.ebuild b/media-gfx/simple-scan/simple-scan-42.5.ebuild
new file mode 100644
index 000000000000..7ecc2967a664
--- /dev/null
+++ b/media-gfx/simple-scan/simple-scan-42.5.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Simple document scanning utility"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/simple-scan"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="colord webp"
+
+DEPEND="
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.24:3
+	>=gui-libs/libhandy-1.6.0:1=
+	>=sys-libs/zlib-1.2.3.1:=
+	x11-libs/cairo:=
+	x11-libs/gdk-pixbuf:2
+	>=dev-libs/libgusb-0.2.7
+	colord? ( >=x11-misc/colord-0.1.24:=[udev(+)] )
+	webp? ( media-libs/libwebp )
+	>=media-gfx/sane-backends-1.0.20:=
+
+	media-libs/libjpeg-turbo:0=
+"
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gui-libs/libhandy:1[vala]
+	dev-libs/libgusb[vala]
+	colord? ( x11-misc/colord[vala] )
+"
+
+PATCHES=(
+	# Add control for optional dependencies
+	"${FILESDIR}"/40.0-add-control-optional-deps.patch
+)
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord)
+		-Dpackagekit=false
+		$(meson_use webp)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}