[gentoo-commits] repo/gentoo:master commit in: dev-python/indexed_gzip/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     38937972dd8ccf257a9cb9e426e17a5c0090b7be
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 15 20:34:41 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Sep 15 20:34:41 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=38937972

dev-python/indexed_gzip: add 1.7.0

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/indexed_gzip/indexed_gzip-1.7.0.ebuild | 58 +++++++++++++++++++++++
 1 file changed, 58 insertions(+)

diff --git a/dev-python/indexed_gzip/indexed_gzip-1.7.0.ebuild b/dev-python/indexed_gzip/indexed_gzip-1.7.0.ebuild
new file mode 100644
index 000000000000..11a55ef5459b
--- /dev/null
+++ b/dev-python/indexed_gzip/indexed_gzip-1.7.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Fast random access of gzip files in Python"
+HOMEPAGE="
+	https://pypi.org/project/indexed-gzip/
+	https://github.com/pauldmccarthy/indexed_gzip/
+"
+SRC_URI="
+	https://github.com/pauldmccarthy/indexed_gzip/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	sys-libs/zlib:=
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip custom "clean" command that doesn't support "-a"
+	# https://bugs.gentoo.org/838955
+	# TODO: this can be removed once distutils-r1 stops using clean
+	sed -e '/cmdclass/d' -i setup.py || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	if use test; then
+		export INDEXED_GZIP_TESTING=1
+	fi
+	distutils-r1_src_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)/indexed_gzip/tests" || die
+	epytest
+}