[gentoo-commits] repo/gentoo:master commit in: dev-python/pywavelets/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     d890d988b904cf1a09bf415b1e40661e72514c47
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 15 17:53:46 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Thu Sep 15 19:55:51 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d890d988

dev-python/pywavelets: add 1.4.0

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/pywavelets/Manifest                |  1 +
 dev-python/pywavelets/pywavelets-1.4.0.ebuild | 49 +++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/pywavelets/Manifest b/dev-python/pywavelets/Manifest
index 00e0bde62919..e2d9cbd6d67b 100644
--- a/dev-python/pywavelets/Manifest
+++ b/dev-python/pywavelets/Manifest
@@ -1 +1,2 @@
 DIST PyWavelets-1.3.0.tar.gz 4585209 BLAKE2B 0835fe2ea375eb6036862f137569f77c9723203c581695688f73704e9f21e7dd4034e535b67bcf2b6e2819d2ebc69e6336b8d1ea16702412ce637f914a830b3c SHA512 57eaf4bd5d92f40658208a14c75f58dd7a523f702e209a1383b01e2f5a6d62b15d498126151819060bd2931aea6e280fd5c2dea1e22c21953c16a60d9f184c6f
+DIST PyWavelets-1.4.0.tar.gz 4589435 BLAKE2B 7a8711e3b1312de9fc8bba9d79212f63aa8d21b5e9ba5b1330553dad2dc96b8e4d19d550eee2e162bd92ca0f9b44d7f6784083446964c058095d941fd17a9f27 SHA512 e8b0400457fd336b86a01466b6ca2b998960bbefee06febc252b4588df8d3fe7ea364938a50ba1affc6b041f281afb249449c2d860e4d8d437bef608e0818ad0

diff --git a/dev-python/pywavelets/pywavelets-1.4.0.ebuild b/dev-python/pywavelets/pywavelets-1.4.0.ebuild
new file mode 100644
index 000000000000..fe8c19594c61
--- /dev/null
+++ b/dev-python/pywavelets/pywavelets-1.4.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+MY_PN="${PN/pyw/PyW}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Discrete Wavelet Transforms in Python"
+HOMEPAGE="
+	https://pywavelets.readthedocs.io/en/latest/
+	https://github.com/PyWavelets/pywt/
+"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.17.3[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc/source \
+	dev-python/numpydoc
+
+python_test() {
+	epytest "${BUILD_DIR}/lib"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docinto examples
+		dodoc -r demo
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}