[gentoo-commits] repo/gentoo:master commit in: sys-firmware/edk2-ovmf-bin/

["John Helmert III" <ajak@gentoo.org>]

commit:     3bb54ffa0e7e41b2bfba21d8b7dc77db2c30a1fe
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  7 01:04:51 2022 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Tue Sep  6 22:38:54 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3bb54ffa

sys-firmware/edk2-ovmf-bin: new package, add 202202

The source package only supports building on amd64, so add the keywords
from the last edk2-ovmf with USE=binary to this package.

Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 sys-firmware/edk2-ovmf-bin/Manifest                |  1 +
 .../edk2-ovmf-bin/edk2-ovmf-bin-202202.ebuild      | 69 ++++++++++++++++++++++
 sys-firmware/edk2-ovmf-bin/metadata.xml            |  8 +++
 3 files changed, 78 insertions(+)

diff --git a/sys-firmware/edk2-ovmf-bin/Manifest b/sys-firmware/edk2-ovmf-bin/Manifest
new file mode 100644
index 000000000000..3acdd51ad6e6
--- /dev/null
+++ b/sys-firmware/edk2-ovmf-bin/Manifest
@@ -0,0 +1 @@
+DIST edk2-ovmf-202202-1.xpak 2672386 BLAKE2B 75c15d4379610ab2af85b78166e350d52f4f1bc1fff5b2eb693ad0d7b1f6648e65d8ae3e2c5467f93f1557ad3b4fa664ab2d76ff10794667de22c2ea8cca6b2d SHA512 06783b89c96bada0fd025ff39eaee501a027abcb03c0bdcf3ff497d52be22927ab03013d90f145ee94a8662cfffe4f8c154dcd06db1bb1acef8a85ae43de14a3

diff --git a/sys-firmware/edk2-ovmf-bin/edk2-ovmf-bin-202202.ebuild b/sys-firmware/edk2-ovmf-bin/edk2-ovmf-bin-202202.ebuild
new file mode 100644
index 000000000000..7b35ffe6dc9e
--- /dev/null
+++ b/sys-firmware/edk2-ovmf-bin/edk2-ovmf-bin-202202.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit readme.gentoo-r1
+
+BINPKG="${P/-bin/}-1"
+
+DESCRIPTION="UEFI firmware for 64-bit x86 virtual machines"
+HOMEPAGE="https://github.com/tianocore/edk2"
+SRC_URI="https://dev.gentoo.org/~ajak/distfiles/${BINPKG}.xpak"
+S="${WORKDIR}"
+
+# TODO: the binary 202105 package currently lacks the preseeded
+#       OVMF_VARS.secboot.fd file (that we typically get from fedora)
+
+LICENSE="BSD-2 MIT"
+SLOT="0"
+#KEYWORDS="~amd64 ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="!sys-firmware/edk2-ovmf"
+
+DISABLE_AUTOFORMATTING=true
+DOC_CONTENTS="This package contains the tianocore edk2 UEFI firmware for 64-bit x86
+virtual machines. The firmware is located under
+	/usr/share/edk2-ovmf/OVMF_CODE.fd
+	/usr/share/edk2-ovmf/OVMF_VARS.fd
+	/usr/share/edk2-ovmf/OVMF_CODE.secboot.fd
+
+If USE=binary is enabled, we also install an OVMF variables file (coming from
+fedora) that contains secureboot default keys
+
+	/usr/share/edk2-ovmf/OVMF_VARS.secboot.fd
+
+If you have compiled this package by hand, you need to either populate all
+necessary EFI variables by hand by booting
+	/usr/share/edk2-ovmf/UefiShell.(iso|img)
+or creating OVMF_VARS.secboot.fd by hand:
+	https://github.com/puiterwijk/qemu-ovmf-secureboot
+
+The firmware does not support csm (due to no free csm implementation
+available). If you need a firmware with csm support you have to download
+one for yourself. Firmware blobs are commonly labeled
+	OVMF{,_CODE,_VARS}-with-csm.fd
+
+In order to use the firmware you can run qemu the following way
+
+	$ qemu-system-x86_64 \
+		-drive file=/usr/share/edk2-ovmf/OVMF.fd,if=pflash,format=raw,unit=0,readonly=on \
+		..."
+
+src_unpack() {
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.xpak") || die "unpacking binpkg failed"
+}
+
+src_install() {
+	mv "usr/share/doc/${P/-bin/}" "usr/share/doc/${PF}" || die
+
+	# Don't want to try to install the readme from the source package
+	rm "usr/share/doc/${PF}/README.gentoo.bz2"
+	mv usr "${ED}" || die
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}

diff --git a/sys-firmware/edk2-ovmf-bin/metadata.xml b/sys-firmware/edk2-ovmf-bin/metadata.xml
new file mode 100644
index 000000000000..cfac6f8ac4ff
--- /dev/null
+++ b/sys-firmware/edk2-ovmf-bin/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>virtualization@gentoo.org</email>
+		<name>Gentoo Virtualization Project</name>
+	</maintainer>
+</pkgmetadata>