[gentoo-commits] repo/gentoo:master commit in: www-client/opera-beta/

["Sam James" <sam@gentoo.org>]

commit:     160760c9efea9fde13de8898d585568a2bb375a0
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Sep  1 03:39:44 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Sep  1 03:39:44 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=160760c9

www-client/opera-beta: remove old

Signed-off-by: Sam James <sam <AT> gentoo.org>

 www-client/opera-beta/Manifest                     |   1 -
 .../opera-beta/opera-beta-90.0.4480.37.ebuild      | 158 ---------------------
 2 files changed, 159 deletions(-)

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 645895b943b4..e730794cdb3e 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,4 +1,3 @@
-DIST opera-beta_90.0.4480.37_amd64.deb 87760936 BLAKE2B 893e91922235c24601f9e071f688179baefc7d646aa39714edfe33b44a3d5d44b9095ea1cbf886c9ff54cb692d78f9faa61d7f1ae47be1e938415d6696d3e6a8 SHA512 d3a956881dcaa99e14befa95b1e9c2a07fc6ec3c0937ff2d74b6e1523e6566c14c5e3c308478f58307e91bb343c11f40ab4c0f64b45a93e9f973e270d47e0677
 DIST opera-beta_90.0.4480.41_amd64.deb 87713760 BLAKE2B 593769d761aa180917729fe794db2c0a6bf1044c7e163b0eba64a80e0afb091f6ceefb9358371062db40137f85c04448cc0deb7b72b1a10fb35ab7aa4b13c521 SHA512 81d7e84424f040af6d85f3bdfb3f0456a92895f2a7e510cfa68dcda7323a608e0fa065004c542de49d6d9a933b81c9140d48c83128b44a7e0602f5d669a4b4c9
 DIST opera-beta_91.0.4516.3_amd64.deb 88063968 BLAKE2B 36bb20ff01d6d5a9a442fca497974fa8f43ffb6cd011e873acbc1ca6d1c4642d971ecfe949a6c905e78c48e47d20e0de29afafc5dc02ab6948bfd7ff60726b94 SHA512 cfaa8be684bf2fc003bd8ed6d05c377554581b47273bc6dcecbf3bda18a2b72d9e26aa201a58ab2e3545c32f8d9f7c7ee1f7b5bb6aa5c9fa4aac86b92f48b0bf
 DIST opera-beta_91.0.4516.6_amd64.deb 88110388 BLAKE2B 9e032b21cd19161178441942f5a525507b3ac61abcc5b6409fd0d4b5d6d9ff08399e2461684fdeb922ebb52c99a974a031ea4365a0f78396c2f48075eb8973d9 SHA512 937bc3fb40db72f53824c06f1e4884bd42a022c594d64bc87975535f68b7d5e63e1ea8fb31e5d090021a85bfe3a15b14698217f8d5631dde615b02229dcb472d

diff --git a/www-client/opera-beta/opera-beta-90.0.4480.37.ebuild b/www-client/opera-beta/opera-beta-90.0.4480.37.ebuild
deleted file mode 100644
index bf2f16f337f7..000000000000
--- a/www-client/opera-beta/opera-beta-90.0.4480.37.ebuild
+++ /dev/null
@@ -1,158 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-CHROMIUM_LANGS="
-	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
-	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
-	zh-CN zh-TW
-"
-
-# These are intended for ebuild maintainer use to force RPM if DEB is not available.
-: ${OPERA_FORCE_RPM=no}
-
-inherit chromium-2 pax-utils xdg
-
-if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-	inherit rpm
-	OPERA_ARCHIVE_EXT="rpm"
-else
-	inherit unpacker
-	OPERA_ARCHIVE_EXT="deb"
-fi
-
-DESCRIPTION="A fast and secure web browser"
-HOMEPAGE="https://www.opera.com/"
-LICENSE="OPERA-2018"
-SLOT="0"
-
-SRC_URI_BASE=(
-	"https://download1.operacdn.com/pub/${PN}"
-	"https://download2.operacdn.com/pub/${PN}"
-	"https://download3.operacdn.com/pub/${PN}"
-	"https://download4.operacdn.com/pub/${PN}"
-)
-
-if [[ ${PN} == opera ]]; then
-	MY_PN=${PN}-stable
-	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
-else
-	MY_PN=${PN}
-fi
-
-KEYWORDS="-* ~amd64"
-
-FFMPEG_VERSION="104.0.5083.0"
-
-SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
-	proprietary-codecs? (
-		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
-	)"
-
-IUSE="+proprietary-codecs suid"
-RESTRICT="bindist mirror strip"
-
-RDEPEND="
-	app-accessibility/at-spi2-atk:2
-	app-accessibility/at-spi2-core:2
-	dev-libs/atk
-	dev-libs/expat
-	dev-libs/glib:2
-	dev-libs/nspr
-	dev-libs/nss
-	gnome-base/gsettings-desktop-schemas
-	media-libs/alsa-lib
-	media-libs/mesa[gbm(+)]
-	net-misc/curl
-	net-print/cups
-	sys-apps/dbus
-	sys-libs/glibc
-	x11-libs/cairo
-	x11-libs/gdk-pixbuf
-	x11-libs/gtk+:3
-	x11-libs/libdrm
-	x11-libs/libxcb
-	x11-libs/libxkbcommon
-	x11-libs/libxshmfence
-	x11-libs/libX11
-	x11-libs/libXcomposite
-	x11-libs/libXdamage
-	x11-libs/libXext
-	x11-libs/libXfixes
-	x11-libs/libXrandr
-	x11-libs/pango
-"
-
-QA_PREBUILT="*"
-S=${WORKDIR}
-OPERA_HOME="opt/opera${PN#opera}"
-
-pkg_pretend() {
-	# Protect against people using autounmask overzealously
-	use amd64 || die "opera only works on amd64"
-}
-
-pkg_setup() {
-	chromium_suid_sandbox_check_kernel_config
-}
-
-src_unpack() {
-	:
-}
-
-src_install() {
-	dodir /
-	cd "${ED}" || die
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rpm_src_unpack "${A[0]}"
-	else
-		unpacker
-	fi
-
-	# move to /opt, bug #573052
-	mkdir -p "${OPERA_HOME%${PN}}"
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
-	else
-		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
-	fi
-	rm -r "usr/lib" || die
-
-	# disable auto update
-	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
-
-	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
-		rm "${OPERA_HOME}/setup_repo.sh" || die
-	else
-		rm -r "usr/share/lintian" || die
-
-		# fix docs
-		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
-		gzip -d usr/share/doc/${PF}/changelog.gz || die
-	fi
-
-	# fix desktop file
-	sed -i \
-		-e 's|^TargetEnvironment|X-&|g' \
-		usr/share/applications/${PN}.desktop || die
-
-	# remove unused language packs
-	pushd "${OPERA_HOME}/localization" > /dev/null || die
-	chromium_remove_language_paks
-	popd > /dev/null || die
-
-	# setup opera symlink
-	rm "usr/bin/${PN}" || die
-	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
-
-	# install proprietary codecs
-	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
-	if use proprietary-codecs; then
-		mv lib_extra "${OPERA_HOME}"
-	fi
-
-	# pax mark opera, bug #562038
-	pax-mark m "${OPERA_HOME}/opera"
-	# enable suid sandbox if requested
-	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
-}