[gentoo-commits] repo/gentoo:master commit in: dev-libs/gmime/

["Matt Turner" <mattst88@gentoo.org>]

commit:     0b61827a3f6f2ba071faac255e434e2b73e1e104
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 20 13:53:23 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Aug 20 13:59:06 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0b61827a

dev-libs/gmime: Version bump to 3.2.13

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/gmime/Manifest            |  1 +
 dev-libs/gmime/gmime-3.2.13.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/dev-libs/gmime/Manifest b/dev-libs/gmime/Manifest
index f1118397150d..340d9ad89faa 100644
--- a/dev-libs/gmime/Manifest
+++ b/dev-libs/gmime/Manifest
@@ -1,2 +1,3 @@
 DIST gmime-2.6.23.tar.xz 5216588 BLAKE2B e173a7dbd418663ebbc55b856359bf9286c3791827f9b7f89da48dd7c3609e77312546f9489c08d34a7dcaeb78659789809d5fafc1323cbae9b9f1c4a316c659 SHA512 2ff6718b7a555cd5b34848399f29c7d0aa5a15e1f3cb46e9258c499e874191ee00f41b737386805d3000bad34367d174a25c45d38ba90cba7902400e733afa14
 DIST gmime-3.2.12.tar.xz 2233844 BLAKE2B 863a0634586a478faf32a201051639c33c214d0acb2b7852ba82a3be1f923ad44f3d04390bd9b62991ebaa17da19b6f74f4ce334ff8272563750587793256164 SHA512 2b2529d36bac4501cc79f9b8127a9f0898fce9ce91dbf8a6c72037d120a2fbccbb97b91b00b81fed15bae4232c59700efacf1c94910a06c66340e67815df5afb
+DIST gmime-3.2.13.tar.xz 2231624 BLAKE2B c1b4af7ea911c6e2cdea01700d76d218028f7a7f3fc0443b15f915658f945b0fd784928eaa572b0a4b1cd2ea6f7b2812de75f066e3dd2bef23ebd4075a393ee9 SHA512 cfbf5d9e8d6cafcb340b6e470acaf7ae0a96581d39119a751b22fcf3ede089cc24accbd26a79ec2a4b7901ce66d7092765e8c388bbfa2138606dbb4b3f81f4d3

diff --git a/dev-libs/gmime/gmime-3.2.13.ebuild b/dev-libs/gmime/gmime-3.2.13.ebuild
new file mode 100644
index 000000000000..ef0aa8daabc8
--- /dev/null
+++ b/dev-libs/gmime/gmime-3.2.13.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic gnome2 vala
+
+DESCRIPTION="Library for creating and parsing MIME messages"
+HOMEPAGE="https://github.com/jstedfast/gmime http://spruce.sourceforge.net/gmime/"
+SRC_URI="https://github.com/jstedfast/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+SLOT="3.0"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
+IUSE="crypt doc idn test +vala"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.68.0:2
+	sys-libs/zlib
+	crypt? ( >=app-crypt/gpgme-1.8.0:= )
+	idn? ( net-dns/libidn2:= )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0:=
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/libiconv
+"
+BDEPEND="
+	>=dev-util/gtk-doc-am-1.8
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+"
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_setup
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-solaris* ]]; then
+		# bug #???, why not use --with-libiconv
+		append-libs iconv
+	fi
+
+	gnome2_src_configure \
+		--enable-largefile \
+		$(use_enable crypt crypto) \
+		$(use_enable vala) \
+		$(use_with idn libidn) \
+		$(usex doc "" DB2HTML=)
+}
+
+src_compile() {
+	gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc -r docs/tutorial/html/
+	fi
+}