[gentoo-commits] repo/gentoo:master commit in: games-action/minetest/

["Marek Szuba" <marecki@gentoo.org>]

commit:     61f18f0ba8608ba7fe49666415a37f5041e87a8f
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 16 18:04:49 2022 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Tue Aug 16 18:05:53 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61f18f0b

games-action/minetest: drop 5.5.1

That's the last version vulnerable to CVE-2022-35978 gone.

Bug: https://bugs.gentoo.org/865401
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 games-action/minetest/Manifest              |   1 -
 games-action/minetest/minetest-5.5.1.ebuild | 142 ----------------------------
 2 files changed, 143 deletions(-)

diff --git a/games-action/minetest/Manifest b/games-action/minetest/Manifest
index 79e9c57cb43f..c35862e90e11 100644
--- a/games-action/minetest/Manifest
+++ b/games-action/minetest/Manifest
@@ -1,2 +1 @@
-DIST minetest-5.5.1.tar.gz 9559568 BLAKE2B 76f8da1844c0b87f93ae6227aa224a4afbef2ffed604bd0375cf63a243f9792dceb197512af1bfebced32decf9ecb32bd2698dab48f998397624793d17b493be SHA512 d430c665f9634d34e3c2341300ea294204687ab8fce8f5a895cde38be277cac02d83777924524950f22027ee0d4a43a21a1dace8b1fe467e40bb7d30095de570
 DIST minetest-5.6.0.tar.gz 9922682 BLAKE2B 10787b9bbc397d3d214b22640a830fc429bd8292541e0b71b50d05d483f87469cedf03fcf7a898bd83486c55911439a9804eab2bca58cd464a69adaa76b4f820 SHA512 e87c4036f17a61d3e623b2f48e3611ba1bc0177b5d58330fe6e64a74075c78ab7cd5eb7b855097ce98819112a54857324237f7d3b81ec504a1f608444e74a630

diff --git a/games-action/minetest/minetest-5.5.1.ebuild b/games-action/minetest/minetest-5.5.1.ebuild
deleted file mode 100644
index 0dd8837ab379..000000000000
--- a/games-action/minetest/minetest-5.5.1.ebuild
+++ /dev/null
@@ -1,142 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-1 luajit )
-
-inherit cmake flag-o-matic lua-single systemd xdg
-
-DESCRIPTION="A free open-source voxel game engine with easy modding and game creation"
-HOMEPAGE="https://www.minetest.net"
-SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-2.1+ CC-BY-SA-3.0 OFL-1.1 Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~riscv"
-IUSE="+client +curl doc leveldb ncurses nls postgres prometheus redis +server +sound spatial test"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}
-	|| ( client server )"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="${LUA_DEPS}
-	$(lua_gen_impl_dep 'deprecated' lua5-1)
-	app-arch/zstd
-	dev-db/sqlite:3
-	dev-libs/gmp:0=
-	dev-libs/jsoncpp:=
-	sys-libs/zlib
-	client? (
-		>=dev-games/irrlicht-mt-1.9.0.4
-		media-libs/freetype:2
-		media-libs/libpng:0=
-		media-libs/libjpeg-turbo
-		virtual/opengl
-		x11-libs/libX11
-		x11-libs/libXxf86vm
-		sound? (
-			media-libs/libvorbis
-			media-libs/openal
-		)
-	)
-	curl? ( net-misc/curl )
-	leveldb? ( dev-libs/leveldb:= )
-	ncurses? ( sys-libs/ncurses:0= )
-	nls? ( virtual/libintl )
-	postgres? ( >=dev-db/postgresql-9.5:= )
-	prometheus? ( dev-cpp/prometheus-cpp )
-	redis? ( dev-libs/hiredis:= )
-	server? (
-		acct-group/minetest
-		acct-user/minetest
-		>=dev-games/irrlicht-mt-headers-1.9.0.4
-	)
-	spatial? ( sci-libs/libspatialindex:= )"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	doc? (
-		app-doc/doxygen
-		media-gfx/graphviz
-	)
-	nls? ( sys-devel/gettext )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-5.4.1-system_puc_lua.patch
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	# remove bundled libraries other than bitop
-	rm -rf lib/{gmp,jsoncpp,lua} || die
-
-	# To avoid TEXTRELs on riscv
-	append-flags -fPIC
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_CLIENT=$(usex client)
-		-DBUILD_SERVER=$(usex server)
-		-DBUILD_UNITTESTS=$(usex test)
-		-DCUSTOM_BINDIR="${EPREFIX}/usr/bin"
-		-DCUSTOM_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
-		-DCUSTOM_EXAMPLE_CONF_DIR="${EPREFIX}/usr/share/doc/${PF}"
-		-DCUSTOM_LOCALEDIR="${EPREFIX}/usr/share/${PN}/locale"
-		-DCUSTOM_MANDIR="${EPREFIX}/usr/share/man"
-		-DCUSTOM_SHAREDIR="${EPREFIX}/usr/share/${PN}"
-		-DENABLE_CURL=$(usex curl)
-		-DENABLE_CURSES=$(usex ncurses)
-		-DENABLE_GETTEXT=$(usex nls)
-		-DENABLE_GLES=no
-		-DENABLE_LEVELDB=$(usex leveldb)
-		-DENABLE_LUAJIT=$(usex lua_single_target_luajit)
-		-DENABLE_POSTGRESQL=$(usex postgres)
-		-DENABLE_PROMETHEUS=$(usex prometheus)
-		-DENABLE_REDIS=$(usex redis)
-		-DENABLE_SPATIAL=$(usex spatial)
-		-DENABLE_SOUND=$(usex sound)
-		-DENABLE_SYSTEM_GMP=1
-		-DENABLE_SYSTEM_JSONCPP=1
-		-DRUN_IN_PLACE=0
-	)
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-
-	if use doc; then
-		cmake_src_compile doc
-		HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
-	fi
-}
-
-src_install() {
-	cmake_src_install
-
-	if use server; then
-		keepdir /etc/minetest
-		fowners root:minetest /etc/minetest
-		fperms 2750 /etc/minetest
-
-		keepdir /var/log/minetest
-		fowners minetest:minetest /var/log/minetest
-
-		newconfd "${FILESDIR}"/minetestserver.confd minetest-server
-		newinitd "${FILESDIR}"/minetestserver.initd minetest-server
-
-		systemd_newunit "${FILESDIR}"/minetestserver_default.service minetest-server.service
-		systemd_newunit "${FILESDIR}"/minetestserver_template.service minetest-server@.service
-
-		insinto /etc/logrotate.d
-		newins "${FILESDIR}"/minetestserver.logrotate minetest-server
-	fi
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-}