[gentoo-commits] repo/gentoo:master commit in: gui-apps/mako/

["John Helmert III" <ajak@gentoo.org>]

commit:     4e4773b156dee91fd662dab42a1bdda0a6044d17
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 24 19:36:24 2022 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Mon Aug 15 02:40:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4e4773b1

gui-apps/mako: install systemd user unit and completions

Closes: https://github.com/gentoo/gentoo/pull/26572
Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 gui-apps/mako/mako-1.7.1-r1.ebuild | 71 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

diff --git a/gui-apps/mako/mako-1.7.1-r1.ebuild b/gui-apps/mako/mako-1.7.1-r1.ebuild
new file mode 100644
index 000000000000..6ffde2623461
--- /dev/null
+++ b/gui-apps/mako/mako-1.7.1-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson systemd
+
+DESCRIPTION="A lightweight notification daemon for Wayland. Works on Sway"
+HOMEPAGE="https://github.com/emersion/mako"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/emersion/${PN}.git"
+else
+	SRC_URI="https://github.com/emersion/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="elogind +icons systemd"
+
+DEPEND="
+	dev-libs/wayland
+	dev-util/wayland-scanner
+	x11-libs/pango
+	x11-libs/cairo
+	|| (
+		systemd? ( sys-apps/systemd )
+		elogind? ( sys-auth/elogind )
+		sys-libs/basu
+	)
+	sys-apps/dbus
+	icons? (
+		x11-libs/gtk+:3
+		x11-libs/gdk-pixbuf
+	)
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-libs/wayland-protocols-1.21
+"
+BDEPEND="
+	virtual/pkgconfig
+	app-text/scdoc
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dicons=$(usex icons enabled disabled)
+		-Dzsh-completions=true
+		-Dfish-completions=true
+		-Dbash-completions=true
+	)
+
+	if use systemd ; then
+		emesonargs+=( -Dsd-bus-provider=libsystemd )
+	elif use elogind ; then
+		emesonargs+=( -Dsd-bus-provider=libelogind )
+	else
+		emesonargs+=( -Dsd-bus-provider=basu )
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	systemd_douserunit contrib/systemd/mako.service
+}