[gentoo-commits] repo/gentoo:master commit in: dev-util/rr/

["Luca Barbato" <lu_zero@gentoo.org>]

commit:     519f92d8849d49ed7a6bd58e6f9e01bc1ca71d90
Author:     Luca Barbato <lu_zero <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 14 08:01:22 2022 +0000
Commit:     Luca Barbato <lu_zero <AT> gentoo <DOT> org>
CommitDate: Sun Aug 14 08:04:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=519f92d8

dev-util/rr: add 5.6.0

Signed-off-by: Luca Barbato <lu_zero <AT> gentoo.org>

 dev-util/rr/Manifest        |  1 +
 dev-util/rr/rr-5.6.0.ebuild | 68 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/dev-util/rr/Manifest b/dev-util/rr/Manifest
index 58904e361e41..fc0bd80be157 100644
--- a/dev-util/rr/Manifest
+++ b/dev-util/rr/Manifest
@@ -1 +1,2 @@
 DIST mozilla-rr-5.5.0.tar.gz 1477110 BLAKE2B d37162ef68b20f1ce7878c338f480e6e1ba1850e37d2c6728705b3ab8791897bfc238c950fd5f318dc2ba0be0df04571888092418b227e396c2c524121ad8345 SHA512 4101de8ccf46533e5fc8e72f99bff39253a40543510d9bc9a611ed0909efcd45a050244994a9ebc878d1c6d0af548ec7e2879d1e737f6455db732f75175ab497
+DIST mozilla-rr-5.6.0.tar.gz 1579320 BLAKE2B 14ea99c4486c72db844b5cad3f0c300d7bf5d49449e7080ed0484f89022be6d9b7f81b3808b65f59028a5256a6b3f6508729d5b7e8f3f45d8353ceb7ae2a577a SHA512 4b5ef65b6c6a4b62fc72949b4541aaf608f6133ea0b6c2e529a8eed725e6a0b5186f20ed60b210821e6929410e1f21723840eacfdc85bf12c87703e7ebf5f9a7

diff --git a/dev-util/rr/rr-5.6.0.ebuild b/dev-util/rr/rr-5.6.0.ebuild
new file mode 100644
index 000000000000..71b981ee54e2
--- /dev/null
+++ b/dev-util/rr/rr-5.6.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+CMAKE_BUILD_TYPE=Release
+
+inherit cmake linux-info python-single-r1
+
+DESCRIPTION="Record and Replay Framework"
+HOMEPAGE="https://rr-project.org/"
+SRC_URI="https://github.com/rr-debugger/${PN}/archive/${PV}.tar.gz -> mozilla-${P}.tar.gz"
+
+LICENSE="MIT BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="multilib test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	sys-libs/zlib:=
+	dev-libs/capnproto:=
+	${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	sys-devel/gdb[xml]"
+# Add all the deps needed only at build/test time.
+DEPEND+="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pexpect[${PYTHON_USEDEP}]
+		')
+		sys-devel/gdb[xml]
+	)"
+
+RESTRICT="test" # toolchain and kernel version dependent
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="SECCOMP"
+		linux-info_pkg_setup
+	fi
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -i 's:-Werror::' CMakeLists.txt || die #609192
+}
+
+src_test() {
+	if has usersandbox ${FEATURES} ; then
+		ewarn "Test suite fails under FEATURES=usersandbox (bug #632394). Skipping."
+		return 0
+	fi
+
+	cmake_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+		-Ddisable32bit=$(usex !multilib) #636786
+	)
+
+	cmake_src_configure
+}