[gentoo-commits] repo/proj/guru:dev commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac.paragon@gmail.com>]

commit:     ec1e1447e1422427a209c28ab761c1dcab53ab96
Author:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
AuthorDate: Fri Aug 12 14:08:47 2022 +0000
Commit:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
CommitDate: Fri Aug 12 14:08:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=ec1e1447

app-misc/fastfetch: add 1.6.2

Signed-off-by: Viorel Munteanu <ceamac.paragon <AT> gmail.com>

 app-misc/fastfetch/Manifest               |  1 +
 app-misc/fastfetch/fastfetch-1.6.2.ebuild | 96 +++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index b8f5d2d9a..d850c6a21 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
 DIST fastfetch-1.6.0.tar.gz 349123 BLAKE2B 9d41c640134d6277a4f844e60654f55870f59b7117f7d3fa4424da777f4e139570e12d97e5781806fdc6d9860b134d7740441983461c205b3b5bd1e07d62079a SHA512 38d027923b5dabea3f85077307767e0ddab6a2685a3ad055fb58abe736d9edc580a4a75811f03ee7904223c67bc31dc84f3da9f4a1aa43a0ccd775c33b3ad941
 DIST fastfetch-1.6.1.tar.gz 349168 BLAKE2B 21076a879e921898766d70566f21cbf9d3f05a6dfc8b2b32be8908f32e0b130c01aca43b1c61ea5fb909757eca116e8bdb604f65d695a7b40b40f18607452597 SHA512 f0a5609cf8d3b57331617396f1c9656ac41dbcb58f485cc6a035dcc02813d7888d7ba42ee953d7f6bc1dd5c3a1ca702f6d1a8582ad5c6b8a4d085f1d40ac3c85
+DIST fastfetch-1.6.2.tar.gz 349994 BLAKE2B 1df9e50d86e3e0912b78894c889b46d4c626b649efec98a1abdf800a31c149077b876b234f79451a34d58ce91a824b1c892175481c03545de0e0e65ff81dd21e SHA512 5e00e307805bcbf21d6b29d14f812588453f30d0bd9484970a29a41c1c1a2eafc8de2a7e85e897fc1573e6e28394638ba6a92cb5f96edb266a37ee3843e42dda

diff --git a/app-misc/fastfetch/fastfetch-1.6.2.ebuild b/app-misc/fastfetch/fastfetch-1.6.2.ebuild
new file mode 100644
index 000000000..31e8aeeb4
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.6.2.ebuild
@@ -0,0 +1,96 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? (
+		media-gfx/chafa
+		media-gfx/imagemagick:=
+	)
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+pkg_setup() {
+	if use chafa && ! use imagemagick; then
+		elog "USE chafa depends on imagemagick, but that is currently disabled.  Enabling imagemagick"
+	fi
+
+	if use imagemagick || use chafa; then
+		export fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	else
+		export fastfetch_enable_imagemagick7=no
+	fi
+
+	if use imagemagick || use chafa; then
+		export fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	else
+		export fastfetch_enable_imagemagick6=no
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+	)
+
+	cmake_src_configure
+}