[gentoo-commits] repo/gentoo:master commit in: dev-libs/appstream-glib/

["Matt Turner" <mattst88@gentoo.org>]

commit:     2beb9f4faf6507be9feba346ffaf6664916b5685
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 10 19:39:03 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Aug 10 19:46:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2beb9f4f

dev-libs/appstream-glib: Version bump to 0.8.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/appstream-glib/Manifest                   |  1 +
 .../appstream-glib/appstream-glib-0.8.1.ebuild     | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-libs/appstream-glib/Manifest b/dev-libs/appstream-glib/Manifest
index 7423b9b1b360..fe6450739af5 100644
--- a/dev-libs/appstream-glib/Manifest
+++ b/dev-libs/appstream-glib/Manifest
@@ -1,2 +1,3 @@
 DIST appstream-glib-0.7.18.tar.xz 2309276 BLAKE2B 67f414ae45866cab314ed2b307f2045a2035c262810696246f5bdea2a0bac88d98b561f72a8e87608f90407ad6d577d720213461ecef09d277e919b5330c0bc2 SHA512 2a202eb25d823d524128a8ab164025b6579e069f8b62373cf5447d049a0e3764fca5bf1464296101a45870d1426b094493fc8ead07a6a4bcb514c0f1a91e8ff2
 DIST appstream-glib-0.8.0.tar.xz 2315988 BLAKE2B b0858a2dccc70c3eee32262bd83a73ad739d72ca049b23387fea012c68d8dcbaec28aeaa31f81b05dee12c60a5426bdbcf1f22f5a8edbb441c663882c47b1a22 SHA512 13aeb37b8e890691a14d20ed0a86a14ae7125a6e08e60adcefe58ce2f861cebf7f49a01d9d1c137205b923f3162b307fc2671d476b7aaa9eae5fc5234ea4c1da
+DIST appstream-glib-0.8.1.tar.xz 2320596 BLAKE2B de8d68c541cd6700fff0bc22a71d59510ccf584ac1380e2aed3e5aa122825cb3087d65b42ac1dc35acbd4b171382d9560545cdeaffa9d6bda721784444bf7a36 SHA512 32462a32ea25c945abb8d9084af1c84850f264b3a2136c6f54444e0168acf0d74ee450f8cbf483a504e417dc29b85a2e9bbc0a5bb8a217296eccacaa02db5ef5

diff --git a/dev-libs/appstream-glib/appstream-glib-0.8.1.ebuild b/dev-libs/appstream-glib/appstream-glib-0.8.1.ebuild
new file mode 100644
index 000000000000..be7926bb8630
--- /dev/null
+++ b/dev-libs/appstream-glib/appstream-glib-0.8.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg meson
+
+DESCRIPTION="Provides GObjects and helper methods to read and write AppStream metadata"
+HOMEPAGE="https://people.freedesktop.org/~hughsient/appstream-glib/ https://github.com/hughsie/appstream-glib"
+SRC_URI="https://people.freedesktop.org/~hughsient/${PN}/releases/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/8" # soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="gtk-doc fonts +introspection stemmer"
+
+RDEPEND="
+	>=dev-libs/glib-2.58.0:2
+	sys-apps/util-linux
+	app-arch/libarchive:=
+	>=net-misc/curl-7.56.0
+	>=dev-libs/json-glib-1.1.2
+	>=x11-libs/gdk-pixbuf-2.31.5:2[introspection?]
+
+	fonts? (
+		x11-libs/gtk+:3
+		>=media-libs/freetype-2.4:2
+	)
+	>=media-libs/fontconfig-2.11:1.0
+	dev-libs/libyaml
+	stemmer? ( dev-libs/snowball-stemmer:= )
+	x11-libs/pango
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	dev-util/gperf
+
+	dev-libs/libxml2:2
+	app-text/docbook-xml-dtd:4.2
+	dev-libs/libxslt
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.9
+		app-text/docbook-xml-dtd:4.3
+	)
+	>=sys-devel/gettext-0.19.8
+"
+
+src_configure() {
+	local emesonargs=(
+		-Ddep11=true
+		-Dbuilder=true
+		-Drpm=false
+		-Dalpm=false
+		$(meson_use fonts)
+		$(meson_use stemmer)
+		-Dman=true
+		$(meson_use gtk-doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}