[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     4f3f4dba9608b629c0c879a3dc59093dfefed928
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Aug  3 16:16:39 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Aug  3 16:23:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4f3f4dba

dev-python/django: Bump to 4.0.7

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |   2 +
 dev-python/django/django-4.0.7.ebuild | 110 ++++++++++++++++++++++++++++++++++
 2 files changed, 112 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 2820539c0d36..6f783159de2d 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -2,3 +2,5 @@ DIST Django-3.2.14.checksum.txt 2552 BLAKE2B 8949b6bbc05160539ba26e4a9a2b774e450
 DIST Django-3.2.14.tar.gz 9814965 BLAKE2B d2081621598ca9743b056b752775d8fe87748e7e0ad4e252f9bb0d50bbdd942cf5908aafc7757668a5dd041aafecd94f63b38441e4dbb8e1810babde1aaec436 SHA512 daa18a0a64870789af4627b1cd345fef66d4b227d71cbd9b4766332728c37e3fb17472924c290851f8bc2111efe90c5e22eebf9b6f7a26e77bdc8edaa8e42e16
 DIST Django-4.0.6.checksum.txt 2543 BLAKE2B 4d38a86dc468f1cf9553557073fa6d5aad6875739c5cd3e50dd79954254dc25a0345b32fc771f4db3d566858c58b48d4f0fba434903eae0e0709666627b5e38c SHA512 b701e13371bdc00b61e7ff7f5a2b2d39a9d703616ce79640700e53a252f8aefd8bbf5560b082420bd4ff921110a44ac6a353c61db664b0ee899905d5cf65de59
 DIST Django-4.0.6.tar.gz 10389543 BLAKE2B c458b2b2a782d95771df00ed529d4b0ef0f42720f19258d32ea955e90806b61aabf03a5eb39a7a36c5d220af32dd35e78244db4d17a3f074601952905fd5e0fa SHA512 1050511bd9345519d8382a58e4e6ccc39cd41a6777c9575540dcc655f11dd36316cfc2431f94da9ac4a0fa6e41640a9131c8d49df4188a2ffc26f7ff56d40a6a
+DIST Django-4.0.7.checksum.txt 2551 BLAKE2B 6fa44707d33af485d3c55096dcc650b4e2384421c57c30cedee9f9577488783836a3ad8261dceaf5c718c1a5fcbe5852b081596525b22639c310c9aa6e86c639 SHA512 4b2453be8090c2a9d48bbe34f6e5dd55859b9debc3a116519c69da39d04ecca202e6da62ae9114790a9da8c55cfcfe176a972bb25576305a8e23736e2e063e3e
+DIST Django-4.0.7.tar.gz 10407810 BLAKE2B 77c994d042ace329699aa33e14098cbcd4f24fa4db880dd78ed87828b02c25298a1c1664511547de53eb80ebade7bdfb16412a615027e512ded437ae7de79b54 SHA512 51574ab7423a3948318a5985f74bd781269bf1c95dc77838c11e8f9d5e9233f0a3be5dfa4798d523473b9f1fd3196d4c10284e3a28d9543084b2a63179167731

diff --git a/dev-python/django/django-4.0.7.ebuild b/dev-python/django/django-4.0.7.ebuild
new file mode 100644
index 000000000000..16e1a7824c10
--- /dev/null
+++ b/dev-python/django/django-4.0.7.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+	"${FILESDIR}"/django-4.0.5-py311.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}