[gentoo-commits] repo/gentoo:master commit in: app-emulation/86Box/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     b448138a90716e7547e97fba9dfbb83e954ea750
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  1 18:17:26 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon Aug  1 18:22:05 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b448138a

app-emulation/86Box: add 3.7

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 app-emulation/86Box/86Box-3.7.ebuild | 74 ++++++++++++++++++++++++++++++++++++
 app-emulation/86Box/Manifest         |  1 +
 2 files changed, 75 insertions(+)

diff --git a/app-emulation/86Box/86Box-3.7.ebuild b/app-emulation/86Box/86Box-3.7.ebuild
new file mode 100644
index 000000000000..ab0476394bfd
--- /dev/null
+++ b/app-emulation/86Box/86Box-3.7.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Emulator of x86-based machines based on PCem"
+HOMEPAGE="https://github.com/86Box/86Box"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="dinput +dynarec experimental +fluidsynth +munt new-dynarec +openal +qt5 +threads"
+
+DEPEND="
+	app-emulation/faudio
+	dev-libs/libevdev
+	media-libs/freetype:2=
+	media-libs/libpng:=
+	media-libs/libsdl2
+	media-libs/openal
+	media-libs/rtmidi
+	net-libs/libslirp
+	sys-libs/zlib
+	qt5? ( x11-libs/libXi )
+"
+
+RDEPEND="
+	${DEPEND}
+	fluidsynth? ( media-sound/fluidsynth )
+	munt? ( media-libs/munt-mt32emu )
+	openal? ( media-libs/openal )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtopengl:5
+		dev-qt/qttranslations:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+src_configure() {
+	# LTO needs to be filtered
+	# See https://bugs.gentoo.org/854507
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	local mycmakeargs=(
+		-DCPPTHREADS="$(usex threads)"
+		-DDEV_BRANCH="$(usex experimental)"
+		-DDINPUT="$(usex dinput)"
+		-DDYNAREC="$(usex dynarec)"
+		-DFLUIDSYNTH="$(usex fluidsynth)"
+		-DMINITRACE="OFF"
+		-DMUNT="$(usex munt)"
+		-DNEW_DYNAREC="$(usex new-dynarec)"
+		-DOPENAL="$(usex openal)"
+		-DPREFER_STATIC="OFF"
+		-DQT="$(usex qt5)"
+		-DRELEASE="ON"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	elog "In order to use 86Box, you will need some roms for various emulated systems."
+	elog "See https://github.com/86Box/roms for more information."
+}

diff --git a/app-emulation/86Box/Manifest b/app-emulation/86Box/Manifest
index 3f1f5d425f9b..8a04c380ed2e 100644
--- a/app-emulation/86Box/Manifest
+++ b/app-emulation/86Box/Manifest
@@ -1 +1,2 @@
 DIST 86Box-3.6.tar.gz 5158884 BLAKE2B 7483b39ac377dba0f65680d40c88944bec5a77b64abeb859da586e6fecf2706f0803bbd18f443e4b6bdb3cfb03e50f3bdc264a586f629d3db62c5c965eb76ed5 SHA512 08f281f70afce47f8e483c0b16dc99b3704beb89c8ad007a6d1814f8cd3716d5bedc4ca4444cbd61c79960e89152b24cfa34c53d51a10f99c811ca3d3290225d
+DIST 86Box-3.7.tar.gz 4452842 BLAKE2B 90efc4f6c9f1f59e875d91f09b0fc97a435d93f4dd3db6cd6ad9405760f3f57c15803d8fc6974a5886230a57644f09a079258fbc34a05597c8a5ff78ffbffd90 SHA512 fde59f957387b907f62dac26ef903727d47576c2c82036e877fe6508b4d9c8bee843789f23ed6d963f12e3a502391b55077841b80faac036ed7071608caff4c9