[gentoo-commits] repo/gentoo:master commit in: net-im/synapse/files/, net-im/synapse/

["Sam James" <sam@gentoo.org>]

commit:     e715058e518723fe8a9000539578483d8bbab060
Author:     Petr Vaněk <arkamar <AT> atlas <DOT> cz>
AuthorDate: Wed Jul 20 13:31:39 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 29 03:14:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e715058e

net-im/synapse: add 1.63.1

Closes: https://bugs.gentoo.org/857996
Closes: https://bugs.gentoo.org/857999
Signed-off-by: Petr Vaněk <arkamar <AT> atlas.cz>
Closes: https://github.com/gentoo/gentoo/pull/26486
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-im/synapse/Manifest              |   1 +
 net-im/synapse/files/synapse.service |  22 ++++++++
 net-im/synapse/synapse-1.63.1.ebuild | 104 +++++++++++++++++++++++++++++++++++
 3 files changed, 127 insertions(+)

diff --git a/net-im/synapse/Manifest b/net-im/synapse/Manifest
index 811838f92ce3..1d9637aa7670 100644
--- a/net-im/synapse/Manifest
+++ b/net-im/synapse/Manifest
@@ -1 +1,2 @@
 DIST synapse-1.62.0.gh.tar.gz 7841903 BLAKE2B f3002798a3fccd1b7fc4a1a302d12dd0940727ce8e89bcab0fdda04d498dbc9e469d21e7815db75b3593fcdfa01557e6828a39e874e946ce1b43d51cfe459ee6 SHA512 2bf9264f08fab29e8707317b69c52a4234bb25443c342ba43a27e06c506bcca1a9bdb211a99802abbca551e4f4288f68775d4629493b39d58dfcc8d8d1ca8ab8
+DIST synapse-1.63.1.gh.tar.gz 7861575 BLAKE2B 7f69f2620289aa2c6b846514ce086e0ce20d559179cded20cda43b6c2ef2ad36d3b3f3fd6b139d2237a4c002c92a820a4150e5d8b25218b17bf22b9999638c67 SHA512 eb3bfb22081e932b2b7168a2b656b2ba7cc656bffbf60eb169b8d187d2a742809e2c0d6170afcea2bcf40ae5042a7b2ce7d7438294167bcc48def71e2488e338

diff --git a/net-im/synapse/files/synapse.service b/net-im/synapse/files/synapse.service
new file mode 100644
index 000000000000..19661e96257e
--- /dev/null
+++ b/net-im/synapse/files/synapse.service
@@ -0,0 +1,22 @@
+[Unit]
+Description=Synapse Matrix homeserver
+After=network.target
+After=postgresql-10.service
+After=postgresql-11.service
+After=postgresql-12.service
+After=postgresql-13.service
+After=postgresql-14.service
+After=postgresql-15.service
+
+[Service]
+ExecStart=/usr/bin/synctl --no-daemonize start /etc/synapse/homeserver.yaml
+ExecStop=/usr/bin/synctl stop /etc/synapse/homeserver.yaml
+ExecReload=/bin/kill -HUP $MAINPID
+Restart=on-failure
+PrivateTmp=true
+User=synapse
+Group=synapse
+WorkingDirectory=/var/lib/synapse
+
+[Install]
+WantedBy=multi-user.target

diff --git a/net-im/synapse/synapse-1.63.1.ebuild b/net-im/synapse/synapse-1.63.1.ebuild
new file mode 100644
index 000000000000..72a914a9792e
--- /dev/null
+++ b/net-im/synapse/synapse-1.63.1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..10} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=poetry
+
+inherit distutils-r1 optfeature systemd
+
+DESCRIPTION="Reference implementation of Matrix homeserver"
+HOMEPAGE="
+	https://matrix.org/
+	https://github.com/matrix-org/synapse/
+"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/matrix-org/${PN}.git"
+else
+	MY_PV="${PV/_rc/rc}"
+	SRC_URI="https://github.com/matrix-org/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+	KEYWORDS="~amd64 ~ppc64"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="postgres systemd test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-user/synapse
+	acct-group/synapse
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		dev-python/bleach[${PYTHON_USEDEP}]
+		dev-python/canonicaljson[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/frozendict[${PYTHON_USEDEP}]
+		dev-python/ijson[${PYTHON_USEDEP}]
+		>=dev-python/jinja-3.0[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		>=dev-python/matrix-common-1.2.1[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/netaddr[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/phonenumbers[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},webp]
+		dev-python/prometheus_client[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pymacaroons[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		dev-python/signedjson[${PYTHON_USEDEP}]
+		dev-python/sortedcontainers[${PYTHON_USEDEP}]
+		dev-python/treq[${PYTHON_USEDEP}]
+		dev-python/twisted[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/unpaddedbase64[${PYTHON_USEDEP}]
+		postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
+		systemd? ( dev-python/python-systemd[${PYTHON_USEDEP}] )
+	')
+"
+BDEPEND="
+	test? ( $(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	') )
+"
+
+python_test() {
+	"${EPYTHON}" -m twisted.trial tests || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+	keepdir /var/{lib,log}/synapse /etc/synapse
+	fowners synapse:synapse /var/{lib,log}/synapse /etc/synapse
+	fperms 0750 /var/{lib,log}/synapse /etc/synapse
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	systemd_dounit "${FILESDIR}/synapse.service"
+}
+
+pkg_postinst() {
+	optfeature "VoIP relaying on your homeserver with turn" net-im/coturn
+
+	einfo "In order to generate initial configuration run:"
+	einfo "sudo -u synapse synapse_homeserver \\"
+	einfo "    --server-name matrix.domain.tld \\"
+	einfo "    --config-path /etc/synapse/homeserver.yaml \\"
+	einfo "    --generate-config \\"
+	einfo "    --data-directory /var/lib/synapse \\"
+	einfo "    --report-stats=no"
+	einfo
+	einfo "See also upgrade notes:"
+	einfo "https://github.com/matrix-org/synapse/blob/develop/docs/upgrade.md"
+}