[gentoo-commits] repo/gentoo:master commit in: app-crypt/gcr/

["Matt Turner" <mattst88@gentoo.org>]

commit:     a61268e24cb762caf9ab73a17d9ab0efa1b7ec68
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 26 21:59:43 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Jul 26 22:01:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a61268e2

app-crypt/gcr: Version bump to 3.41.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 app-crypt/gcr/Manifest          |  1 +
 app-crypt/gcr/gcr-3.41.1.ebuild | 84 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index a138c3c1ce25..2f2637cad476 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1 +1,2 @@
 DIST gcr-3.41.0.tar.xz 1039744 BLAKE2B c646a04168310051d5b582a9d2f7ab9da89eef095e856e56b8d730600debead051ad8bb40eddb7457b1be2be3e092227dd886f647258a9c6a81d4bab728245f7 SHA512 455acc40ed77feeb35f9845b00229f468b322b7eda0b1b5abb0153f0a6ba29f3d0364df22225143f4caf130254a1258b3c7f934370e5142f2f64e1c3084b6f6e
+DIST gcr-3.41.1.tar.xz 1030368 BLAKE2B 9d254b7f2ad864c45200e58b685db97c1ffbc83d29ba8cbda94d30ec565aa3dc5a2535305dc63b3264131b68ec9e48f37ac30d5ba08d0ce156f3b6091cd62dc1 SHA512 dd70d41636ede863d05824b26823a8f572902f7a9b6f09b0c70586ef0d4c046864e6956130b9231850a515a9fbfcd56faf20354c1cf8f697f005827c048a2325

diff --git a/app-crypt/gcr/gcr-3.41.1.ebuild b/app-crypt/gcr/gcr-3.41.1.ebuild
new file mode 100644
index 000000000000..53971669534e
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.41.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-base-3 and co
+
+IUSE="gtk gtk-doc +introspection systemd test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+DEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=app-crypt/p11-kit-0.19.0
+	>=app-crypt/libsecret-0.20
+	systemd? ( sys-apps/systemd:= )
+	gtk? ( >=x11-libs/gtk+-3.22:3[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}"/3.38.0-optional-vapi.patch
+)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		-Dssh_agent=true
+		$(meson_feature systemd)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}