[gentoo-commits] repo/gentoo:master commit in: sci-physics/fastjet/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     b2d04b525de8e18083fd96d02b3ca700b1e64e76
Author:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 22 20:36:21 2022 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Fri Jul 22 20:37:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b2d04b52

sci-physics/fastjet: fix USE="cgal" with versions 5.4 and up

Closes: https://bugs.gentoo.org/851912
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 sci-physics/fastjet/fastjet-3.4.0-r1.ebuild | 77 +++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

diff --git a/sci-physics/fastjet/fastjet-3.4.0-r1.ebuild b/sci-physics/fastjet/fastjet-3.4.0-r1.ebuild
new file mode 100644
index 000000000000..d35057476e08
--- /dev/null
+++ b/sci-physics/fastjet/fastjet-3.4.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+FORTRAN_NEEDED=plugins
+PYTHON_COMPAT=( python3_{8..11} )
+DOCS_BUILDER="doxygen"
+DOCS_DEPEND="
+	media-gfx/graphviz
+	media-libs/freetype
+"
+
+inherit autotools docs flag-o-matic fortran-2 python-single-r1
+
+DESCRIPTION="A software package for jet finding in pp and e+e- collisions"
+HOMEPAGE="https://fastjet.fr/"
+SRC_URI="https://fastjet.fr/repo/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cgal examples python +plugins"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# cgal is header-only in version 5.4 and up. We need to use the
+# special --enable-cgal-header-only argument to use these versions.
+DEPEND="
+	cgal? ( >=sci-mathematics/cgal-5.4:=[shared(+)] )
+	plugins? ( sci-physics/siscone:= )
+	python? ( ${PYTHON_DEPS} )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/fortran"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-system-siscone.patch
+	"${FILESDIR}"/${P}-gfortran.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use cgal && \
+		has_version 'sci-mathematics/cgal[gmp]' && append-libs -lgmp
+
+	econf \
+		$(use_enable cgal cgal-header-only) \
+		$(use_enable plugins allplugins) \
+		$(use_enable plugins allcxxplugins) \
+		--enable-shared \
+		--enable-static=no \
+		--disable-static \
+		--disable-auto-ptr  \
+		$(use_enable python pyext)
+}
+
+src_compile() {
+	default
+	docs_compile
+}
+
+src_install() {
+	default
+	if use examples; then
+		emake -C example maintainer-clean
+		find example -iname 'makefile*' -delete || die
+
+		docinto examples
+		dodoc -r example/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	find "${ED}" -name '*.la' -delete || die
+}