[gentoo-commits] repo/gentoo:master commit in: media-sound/amsynth/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     822b9857b756de1218a23a28493e5351811e4308
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 18 03:11:06 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Mon Jul 18 03:11:06 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=822b9857

media-sound/amsynth: bump to 1.13.0

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/amsynth/Manifest              |  1 +
 media-sound/amsynth/amsynth-1.13.0.ebuild | 64 +++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/media-sound/amsynth/Manifest b/media-sound/amsynth/Manifest
index 9cd27b408458..187f196a445a 100644
--- a/media-sound/amsynth/Manifest
+++ b/media-sound/amsynth/Manifest
@@ -1 +1,2 @@
 DIST amsynth-1.12.4.tar.gz 1624416 BLAKE2B 1dcd2454d94200b76097d4215ed419123a3b8427064c8f674a1e7cb27620fb5b2977470ea7feb8114c429ed904511ec73c73461b7f38e1388e4cfeabc4e68ec3 SHA512 502fdd1d6c4e54a57482d266977d78008efa26717c173be0bf98e907a111366fd80b65d667b9448e751085901dc5f2a61ac0bf5b1d02e35c695ecd99c9d1df00
+DIST amsynth-1.13.0.tar.gz 1626209 BLAKE2B 29b79f18ca0ddbba77aaf1bde738f235698f0debe2ddea3b9f2bce2eeaaa399ba125f72b97c83157b87bb28bdb4a259ae2e535c87def16a9e1af3d3093bf0270 SHA512 29698be7d690c76a46a0c8306d6c3b94630b25ed9a3524d7e27d22e244f5c144b74b8473f09eecdb1368443f503ba7024d1c71ead6794f11a2d1cb2114c84bd5

diff --git a/media-sound/amsynth/amsynth-1.13.0.ebuild b/media-sound/amsynth/amsynth-1.13.0.ebuild
new file mode 100644
index 000000000000..e42fb11b9d12
--- /dev/null
+++ b/media-sound/amsynth/amsynth-1.13.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg
+
+DESCRIPTION="Virtual analogue synthesizer"
+HOMEPAGE="https://github.com/amsynth/amsynth"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/release-${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="alsa dssi gtk jack lash lv2 nsm oss vst"
+
+REQUIRED_USE="dssi? ( gtk ) lv2? ( gtk )"
+
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+"
+RDEPEND="
+	alsa? (
+		media-libs/alsa-lib:=
+		media-sound/alsa-utils
+	)
+	dssi? (
+		media-libs/dssi:=
+		media-libs/liblo:=
+	)
+	gtk? (
+		x11-libs/gtk+:2
+		x11-libs/libX11
+	)
+	jack? ( virtual/jack )
+	lash? ( media-sound/lash )
+	lv2? ( media-libs/lv2 )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.12.2-metadata.patch"
+)
+
+src_prepare() {
+	default
+	! use gtk && eapply "${FILESDIR}/${PN}-1.12.2-x11.patch"
+}
+
+src_configure() {
+	econf \
+		$(use_with alsa) \
+		$(use_with dssi) \
+		$(use_with gtk gui) \
+		$(use_with jack) \
+		$(use_with lash) \
+		$(use_with lv2) \
+		$(use_with nsm) \
+		$(use_with oss) \
+		$(use_with vst)
+}