[gentoo-commits] repo/gentoo:master commit in: media-gfx/img2pdf/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     328d1184cac7362bb0da22930f16cfbd7cb25ccc
Author:     Thamognya Kodi <contact <AT> thamognya <DOT> com>
AuthorDate: Fri Jul  1 13:02:41 2022 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Jul 15 08:38:12 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=328d1184

media-gfx/img2pdf: Bump to 0.4.4

Signed-off-by: Thamognya Kodi <contact <AT> thamognya.com>
Closes: https://github.com/gentoo/gentoo/pull/26188
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-gfx/img2pdf/Manifest             |  1 +
 media-gfx/img2pdf/img2pdf-0.4.4.ebuild | 60 ++++++++++++++++++++++++++++++++++
 media-gfx/img2pdf/metadata.xml         |  9 ++++-
 3 files changed, 69 insertions(+), 1 deletion(-)

diff --git a/media-gfx/img2pdf/Manifest b/media-gfx/img2pdf/Manifest
index 39a137e9bdb8..217dbc167e68 100644
--- a/media-gfx/img2pdf/Manifest
+++ b/media-gfx/img2pdf/Manifest
@@ -1 +1,2 @@
 DIST img2pdf-0.4.3.tar.gz 98656 BLAKE2B ec7be83fa7fc38f94c7770a2566a49a39e5fd0abb715de74fc3f65d59087cecdd009f4284e647facaf6ae019a118b4bedf7ce8d4a09b8479a299c8404a8940d5 SHA512 00755788c7380e44733c5a309428894b6689e93d4d7cca8f84681d12977848971a6b1a7c92c7203258a529894e7a0debb5beaeb6b375de769a0d600ea8d65423
+DIST img2pdf-0.4.4.tar.gz 97796 BLAKE2B d04eae8c02490e4e73339dade92b2521ad410ed741ccc2987961543790589b14a5c8939cb9bbadcc795f5edcbb59a1a43bd522c75948f42dde1acffafb6266e0 SHA512 56943cd965b3e6b0680b7696ca4b5a2ba779474f945dd0d2648fb6f18ab18aab6d74640f9bd8e9c8683e3e641b0657cb84c691054910d84f0c9e8ad733f179e9

diff --git a/media-gfx/img2pdf/img2pdf-0.4.4.ebuild b/media-gfx/img2pdf/img2pdf-0.4.4.ebuild
new file mode 100644
index 000000000000..7900354a9775
--- /dev/null
+++ b/media-gfx/img2pdf/img2pdf-0.4.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Losslessly convert raster images to PDF"
+HOMEPAGE="https://gitlab.mister-muffin.de/josch/img2pdf"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gui"
+
+# pytest-xdist isn't really required but it helps speed up tests
+BDEPEND="
+	test? (
+		app-text/ghostscript-gpl
+		app-text/mupdf
+		app-text/poppler[cairo,png,tiff]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pdfrw[${PYTHON_USEDEP}]
+		dev-python/pillow[tiff,${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		media-gfx/imagemagick[jpeg,jpeg2k,lcms,png,-q8,-q32,tiff]
+		media-libs/exiftool
+		media-libs/netpbm[jpeg]
+	)
+"
+RDEPEND="
+	dev-python/pikepdf[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	gui? ( $(python_gen_impl_dep tk) )
+"
+
+# gif animation test fails
+PATCHES=( "${FILESDIR}"/${P}-test-gif-animation.patch )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_python_prepare_all
+
+	# Remove gui executable if there's no demand/support for it.
+	if ! use gui; then
+		sed -i '/gui_scripts/d' setup.py || die
+	fi
+
+	# gif animation test fails
+	rm src/tests/input/animation.gif src/tests/output/animation.gif.pdf || die "rm animation gif failes"
+}
+
+python_test() {
+	epytest -n auto
+}

diff --git a/media-gfx/img2pdf/metadata.xml b/media-gfx/img2pdf/metadata.xml
index ab909682d5c4..f6852412a419 100644
--- a/media-gfx/img2pdf/metadata.xml
+++ b/media-gfx/img2pdf/metadata.xml
@@ -1,7 +1,14 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<!-- maintainer-needed -->
+	<maintainer type="person" proxied="yes">
+		<name>Thamognya Kodi</name>
+		<email>contact@thamognya.com</email>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
 	<stabilize-allarches/>
 	<longdescription lang="en">
 	Losslessly convert raster images to PDF. The file size will not