[gentoo-commits] repo/gentoo:master commit in: dev-util/gn/

["Sam James" <sam@gentoo.org>]

commit:     5ba24c6d5caf0c07869fa64c45bf4355b7cf4953
Author:     WANG Xuerui <xen0n <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  9 08:13:51 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 15 01:40:40 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ba24c6d

dev-util/gn: add 0.2049

Signed-off-by: WANG Xuerui <xen0n <AT> gentoo.org>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/gn/Manifest         |  1 +
 dev-util/gn/gn-0.2049.ebuild | 64 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/dev-util/gn/Manifest b/dev-util/gn/Manifest
index 431a180088e7..7db177c5ff28 100644
--- a/dev-util/gn/Manifest
+++ b/dev-util/gn/Manifest
@@ -1 +1,2 @@
 DIST gn-0.1943.tar.xz 706792 BLAKE2B 51889ad85e86e702c2690c5c23010d666ef0467be92d982e6dea2eec2e20774c04425900cad64672c7782bf36e62984e612c04ff0f1c7e9598f2877270cf8504 SHA512 4e3270e13e35fa0ede3c81b563b72a9e9baee18b6412d32603d3c7a327315ceea86dc28c9c3b01c9e9f4d520e222dfeabe152f946eb0947d9285359568934864
+DIST gn-0.2049.tar.xz 727960 BLAKE2B fe93d09c1fa5b6267a4d26f37ec42e629b36645ef58bf6ebcc07dd8cd2ee9509c1e997182251a3e2c3ef3c5b7d636c9a8228c1e49d1d7245b3ebdac36e7c5a1a SHA512 f3e6dc87d647702c5d22793e2eed3e9950f8c9a6d7178eae67bb7d6518b6533c74fa3f43245fb9e422994a27f1a0f1986709f91e7ce2ed78eb5f17838f75e1db

diff --git a/dev-util/gn/gn-0.2049.ebuild b/dev-util/gn/gn-0.2049.ebuild
new file mode 100644
index 000000000000..2a8ad1312b10
--- /dev/null
+++ b/dev-util/gn/gn-0.2049.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2018-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit ninja-utils python-any-r1 toolchain-funcs
+
+DESCRIPTION="GN is a meta-build system that generates build files for Ninja"
+HOMEPAGE="https://gn.googlesource.com/"
+SRC_URI="https://dev.gentoo.org/~xen0n/distfiles/dev-util/gn/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm64 ~ppc64 ~riscv ~x86"
+IUSE="vim-syntax"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/ninja
+"
+
+PATCHES=(
+	"${FILESDIR}"/gn-gen-r5.patch
+)
+
+pkg_setup() {
+	:
+}
+
+src_configure() {
+	python_setup
+	tc-export AR CC CXX
+	unset CFLAGS
+	set -- ${EPYTHON} build/gen.py --no-last-commit-position --no-strip --no-static-libstdc++
+	echo "$@" >&2
+	"$@" || die
+	cat >out/last_commit_position.h <<-EOF || die
+	#ifndef OUT_LAST_COMMIT_POSITION_H_
+	#define OUT_LAST_COMMIT_POSITION_H_
+	#define LAST_COMMIT_POSITION_NUM ${PV##0.}
+	#define LAST_COMMIT_POSITION "${PV}"
+	#endif  // OUT_LAST_COMMIT_POSITION_H_
+	EOF
+}
+
+src_compile() {
+	eninja -C out gn
+}
+
+src_test() {
+	eninja -C out gn_unittests
+	out/gn_unittests || die
+}
+
+src_install() {
+	dobin out/gn
+	einstalldocs
+
+	if use vim-syntax; then
+		insinto /usr/share/vim/vimfiles
+		doins -r misc/vim/{autoload,ftdetect,ftplugin,syntax}
+	fi
+}