[gentoo-commits] repo/gentoo:master commit in: app-text/pelican/

["Sam James" <sam@gentoo.org>]

commit:     9156a09e8e51dbddf276e0f8a7e83fc9d6305454
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 12 10:38:19 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jul 12 10:38:56 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9156a09e

app-text/pelican: add 4.8.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-text/pelican/Manifest             |  1 +
 app-text/pelican/pelican-4.8.0.ebuild | 66 +++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/app-text/pelican/Manifest b/app-text/pelican/Manifest
index b87a7a69ebd8..2ea926632228 100644
--- a/app-text/pelican/Manifest
+++ b/app-text/pelican/Manifest
@@ -1 +1,2 @@
 DIST pelican-4.7.2.tar.gz 1401737 BLAKE2B c277844c0c153f71aae051dd8897e9abf8fd1ddc7c49251aaa7b85b7324a85da0ded74e8328a4b64ec79b8e6b4e143d5496b8535900c8a88bfa6198489c0a80c SHA512 9fbf2ecb3c193e976e01a4d095095ac55d56fe45aa24467d91635bbecb9df933ccabd6a456e14c6ee14ce0a845820be8d887917af314e13c7a3eb830cb0ce7e6
+DIST pelican-4.8.0.gh.tar.gz 1401791 BLAKE2B 889c9054659c9f98cca571fa0f3ea9ee7752aa65c3feb71278570bad74095f521d3838aa1a32dc3ae331ba86149cdd10be9c31c7ed5bc6e06348edf3eb3bb081 SHA512 2e94eb88a836bcb430026463c0e7e906b7f065507e0d873b6e0fc980e271e6a8f2e62b22af4b61c963d90ef61d57787de20656fe7497b0ae14e93eff2d364f3b

diff --git a/app-text/pelican/pelican-4.8.0.ebuild b/app-text/pelican/pelican-4.8.0.ebuild
new file mode 100644
index 000000000000..b27fc7ca7cae
--- /dev/null
+++ b/app-text/pelican/pelican-4.8.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A tool to generate a static blog, with restructured text or markdown input files"
+HOMEPAGE="https://blog.getpelican.com/ https://pypi.org/project/pelican/"
+SRC_URI="https://github.com/getpelican/pelican/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="AGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="doc examples markdown"
+
+RDEPEND=">=dev-python/docutils-0.16[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/feedgenerator-1.9[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.6[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+	>=dev-python/rich-10.1[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-1.1[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	markdown? ( >=dev-python/markdown-3.1[${PYTHON_USEDEP}] )"
+BDEPEND="
+	test? (
+		>=dev-python/markdown-3.1[${PYTHON_USEDEP}]
+		dev-python/typogrify[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( README.rst )
+
+EPYTEST_DESELECT=(
+	# Needs investigation, we weren't running tests at all before
+	pelican/tests/test_testsuite.py::TestSuiteTest::test_error_on_warning
+	pelican/tests/test_pelican.py::TestPelican::test_basic_generation_works
+	pelican/tests/test_pelican.py::TestPelican::test_custom_generation_works
+)
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		docompress -x /usr/share/doc/${PF}/samples
+		doins -r samples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Typographical enhancements (alternative to markdown)" dev-python/typogrify
+}