* [gentoo-commits] repo/gentoo:master commit in: games-action/brutal-legend-hb/, games-action/brutal-legend-gog/, ...
@ 2022-07-11 18:53 James Le Cuirot
0 siblings, 0 replies; only message in thread
From: James Le Cuirot @ 2022-07-11 18:53 UTC (permalink / raw
To: gentoo-commits
commit: ff90b89cab0f5b9599ea6b246505f052de50e562
Author: James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 11 18:47:35 2022 +0000
Commit: James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Mon Jul 11 18:49:47 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ff90b89c
games-action/brutal-legend: Split into gog and hb packages
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>
games-action/brutal-legend-gog/Manifest | 1 +
.../brutal-legend-gog-2.0.0.3.ebuild | 69 +++++++++++++++++++++
.../metadata.xml | 0
.../{brutal-legend => brutal-legend-hb}/Manifest | 0
.../brutal-legend-hb-20130615-r3.ebuild | 69 +++++++++++++++++++++
.../metadata.xml | 0
.../brutal-legend/brutal-legend-20130615-r2.ebuild | 70 ----------------------
7 files changed, 139 insertions(+), 70 deletions(-)
diff --git a/games-action/brutal-legend-gog/Manifest b/games-action/brutal-legend-gog/Manifest
new file mode 100644
index 000000000000..74e3ef8d130f
--- /dev/null
+++ b/games-action/brutal-legend-gog/Manifest
@@ -0,0 +1 @@
+DIST gog_brutal_legend_2.0.0.3.sh 8519941388 BLAKE2B 1f7ccab8897275b019971307d2fc55c4783212ea8bdbb0944a6ea4f15433e90a955eb2908d84fa1c654650d12cee7f31cce4e926ddda70fa87ef18d6cb8b3aad SHA512 49dcfb3dea868392501da2c11a6d9c415406d017e8954d53131fe78bccf04ce773f0728da7e89e52feb21b8d246f28ae71eb8df5d8162fc132e4cd0864706209
diff --git a/games-action/brutal-legend-gog/brutal-legend-gog-2.0.0.3.ebuild b/games-action/brutal-legend-gog/brutal-legend-gog-2.0.0.3.ebuild
new file mode 100644
index 000000000000..1c9b0afd1d0a
--- /dev/null
+++ b/games-action/brutal-legend-gog/brutal-legend-gog-2.0.0.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHECKREQS_DISK_BUILD="8600M"
+inherit check-reqs desktop unpacker xdg
+
+MY_PN="${PN%-gog}"
+DESCRIPTION="Rock-themed action-adventure that marries visceral action combat with open-world freedom"
+HOMEPAGE="https://www.gog.com/game/brutal_legend"
+SRC_URI="gog_brutal_legend_${PV}.sh"
+
+LICENSE="GOG-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist fetch splitdebug"
+
+BDEPEND="
+ app-arch/unzip
+ media-libs/libpng
+"
+
+RDEPEND="
+ media-libs/glu[abi_x86_32]
+ media-libs/libsdl2[abi_x86_32,joystick,opengl,sound,video]
+ >=sys-devel/gcc-3.4[cxx]
+ >=sys-libs/glibc-2.7[stack-realign(-)]
+ sys-libs/zlib[abi_x86_32]
+ virtual/opengl[abi_x86_32]
+ !${CATEGORY}/${MY_PN}-hb
+"
+
+S="${WORKDIR}/data/noarch/game"
+DIR="/opt/${MY_PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+pkg_nofetch() {
+ einfo "Please buy and download ${SRC_URI} from:"
+ einfo " ${HOMEPAGE}"
+ einfo "and move it to your distfiles directory."
+}
+
+src_unpack() {
+ unpack_zip "${A}"
+}
+
+src_prepare() {
+ default
+
+ # The distributed icon is broken so fix it. pngfix exits unsuccessfully when
+ # it fixes an image, so run it again to check the fixed image.
+ pngfix --out="${T}"/Buddha.png Buddha.png ||
+ pngfix "${T}"/Buddha.png || die
+}
+
+src_install() {
+ exeinto "${DIR}"
+ doexe Buddha.bin.x86
+ dosym ../..${DIR}/Buddha.bin.x86 /usr/bin/${MY_PN}
+
+ insinto "${DIR}"
+ doins -r "${T}"/Buddha.png DFCONFIG Data/ Linux/ OGL/ Win/
+
+ exeinto "${DIR}"/lib
+ doexe lib/libfmod*.so lib/libsteam_api.so
+
+ make_desktop_entry ${MY_PN} "Brütal Legend" "${EPREFIX}${DIR}"/Buddha.png
+}
diff --git a/games-action/brutal-legend/metadata.xml b/games-action/brutal-legend-gog/metadata.xml
similarity index 100%
copy from games-action/brutal-legend/metadata.xml
copy to games-action/brutal-legend-gog/metadata.xml
diff --git a/games-action/brutal-legend/Manifest b/games-action/brutal-legend-hb/Manifest
similarity index 100%
rename from games-action/brutal-legend/Manifest
rename to games-action/brutal-legend-hb/Manifest
diff --git a/games-action/brutal-legend-hb/brutal-legend-hb-20130615-r3.ebuild b/games-action/brutal-legend-hb/brutal-legend-hb-20130615-r3.ebuild
new file mode 100644
index 000000000000..b751bca21841
--- /dev/null
+++ b/games-action/brutal-legend-hb/brutal-legend-hb-20130615-r3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHECKREQS_DISK_BUILD="8600M"
+inherit check-reqs desktop unpacker xdg
+
+MY_PN="${PN%-hb}"
+DESCRIPTION="Rock-themed action-adventure that marries visceral action combat with open-world freedom"
+HOMEPAGE="https://www.humblebundle.com/store/brutal-legend"
+SRC_URI="BrutalLegend-Linux-${PV:0:4}-${PV:4:2}-${PV:6:2}-setup.bin"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist fetch splitdebug"
+
+BDEPEND="
+ app-arch/unzip
+ media-libs/libpng
+"
+
+RDEPEND="
+ media-libs/glu[abi_x86_32]
+ media-libs/libsdl2[abi_x86_32,joystick,opengl,sound,video]
+ >=sys-devel/gcc-3.4[cxx]
+ >=sys-libs/glibc-2.7[stack-realign(-)]
+ sys-libs/zlib[abi_x86_32]
+ virtual/opengl[abi_x86_32]
+ !${CATEGORY}/${MY_PN}-gog
+"
+
+S="${WORKDIR}/data"
+DIR="/opt/${MY_PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+pkg_nofetch() {
+ einfo "Please buy and download ${SRC_URI} from:"
+ einfo " ${HOMEPAGE}"
+ einfo "and move it to your distfiles directory."
+}
+
+src_unpack() {
+ unpack_zip "${A}"
+}
+
+src_prepare() {
+ default
+
+ # The distributed icon is broken so fix it. pngfix exits unsuccessfully when
+ # it fixes an image, so run it again to check the fixed image.
+ pngfix --out="${T}"/Buddha.png Buddha.png ||
+ pngfix "${T}"/Buddha.png || die
+}
+
+src_install() {
+ exeinto "${DIR}"
+ doexe Buddha.bin.x86
+ dosym ../..${DIR}/Buddha.bin.x86 /usr/bin/${MY_PN}
+
+ insinto "${DIR}"
+ doins -r "${T}"/Buddha.png DFCONFIG Data/ Linux/ OGL/ Win/
+
+ exeinto "${DIR}"/lib
+ doexe lib/libfmod*.so lib/libsteam_api.so
+
+ make_desktop_entry ${MY_PN} "Brütal Legend" "${EPREFIX}${DIR}"/Buddha.png
+}
diff --git a/games-action/brutal-legend/metadata.xml b/games-action/brutal-legend-hb/metadata.xml
similarity index 100%
rename from games-action/brutal-legend/metadata.xml
rename to games-action/brutal-legend-hb/metadata.xml
diff --git a/games-action/brutal-legend/brutal-legend-20130615-r2.ebuild b/games-action/brutal-legend/brutal-legend-20130615-r2.ebuild
deleted file mode 100644
index bed1c73d4fc9..000000000000
--- a/games-action/brutal-legend/brutal-legend-20130615-r2.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# TODO: unbundle libsdl-2
-
-EAPI=7
-
-inherit desktop unpacker wrapper xdg
-
-TIMESTAMP=${PV:0:4}-${PV:4:2}-${PV:6:2}
-DESCRIPTION="Unleash the power of Heavy Metal to reign down fire from the sky"
-HOMEPAGE="https://www.doublefine.com/games/brutal-legend"
-SRC_URI="BrutalLegend-Linux-${TIMESTAMP}-setup.bin"
-
-LICENSE="all-rights-reserved"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-RESTRICT="bindist fetch splitdebug"
-
-MYGAMEDIR="/opt/${PN}"
-QA_PREBUILT="${MYGAMEDIR#/}/lib/*
- ${MYGAMEDIR#/}/Buddha.bin.x86"
-
-RDEPEND="
- amd64? (
- >=sys-libs/zlib-1.2.8-r1[abi_x86_32(-)]
- >=virtual/glu-9.0-r1[abi_x86_32(-)]
- >=virtual/opengl-7.0-r1[abi_x86_32(-)]
- >=x11-libs/libX11-1.6.2[abi_x86_32(-)]
- >=x11-libs/libXau-1.0.7-r1[abi_x86_32(-)]
- >=x11-libs/libXdmcp-1.1.1-r1[abi_x86_32(-)]
- >=x11-libs/libXext-1.3.2[abi_x86_32(-)]
- >=x11-libs/libxcb-1.9.1[abi_x86_32(-)]
- )
- x86? (
- sys-libs/zlib
- virtual/glu
- virtual/opengl
- x11-libs/libX11
- x11-libs/libXau
- x11-libs/libXdmcp
- x11-libs/libXext
- x11-libs/libxcb
-
- )"
-BDEPEND="app-arch/unzip"
-
-S="${WORKDIR}"/data
-
-pkg_nofetch() {
- einfo "Please buy & download ${SRC_URI} from:"
- einfo " https://www.humblebundle.com/store"
- einfo "and move it to your DISTDIR directory."
-}
-
-src_unpack() {
- unpack_zip ${A}
-}
-
-src_install() {
- newicon -s 256 Buddha.png ${PN}.png
- make_wrapper ${PN} "./Buddha.bin.x86" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
- make_desktop_entry ${PN}
-
- dodir "${MYGAMEDIR}"
- # this is over 9000!!!! ...eh, 8GB data
- mv * "${D}/${MYGAMEDIR}" || die
-
- fperms +x "${MYGAMEDIR}/Buddha.bin.x86"
-}
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2022-07-11 18:53 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2022-07-11 18:53 [gentoo-commits] repo/gentoo:master commit in: games-action/brutal-legend-hb/, games-action/brutal-legend-gog/, James Le Cuirot
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox