[gentoo-commits] repo/gentoo:master commit in: media-plugins/audacious-plugins/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     12796e41e736f1ae388dc7ed6603079bd95422fb
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 11 04:22:07 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Mon Jul 11 04:22:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=12796e41

media-plugins/audacious-plugins: bump to 4.2

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-plugins/audacious-plugins/Manifest           |   1 +
 .../audacious-plugins/audacious-plugins-4.2.ebuild | 162 +++++++++++++++++++++
 2 files changed, 163 insertions(+)

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index 5af822e4c403..0b49f6704c23 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1,2 +1,3 @@
 DIST audacious-plugins-4.0.5.tar.bz2 1759133 BLAKE2B b806ac110875f94f6e0f1db757d2ec0c7a0391f83efeb068f3e79c7e994fa33d0045095669b5e7ec771714419aaa98b0d0125a5dd18a00f4ee23fc899142858f SHA512 90ab2edbfc797fa835aae9937b5f478a0ca575f31c443d9e8ba7394e1615f605beb417372872874c94d4f804dba7bea9fbae2078e162178386683d8a3e36c108
 DIST audacious-plugins-4.1.tar.bz2 1802825 BLAKE2B 253fddf82408708d8094836088bec1b9b7c932e75c959443579e4bbdc3a4b850757328d90b1ab7a6a0bdd85120d4b0a901f9fa22638f90938f19fd0fa35012ba SHA512 4adad3b4e9c264d52c6523fe84db56b9a87476a4ad5a86f85456a7e0276758d61675022e9e3da07e061dac45f604e54f83f9db85a37f0aaf0b75b3356a63932f
+DIST audacious-plugins-4.2.tar.bz2 1947472 BLAKE2B 405fe7d30f190590955e66540595059869aed920b5cbaffa84439a336b20e6016c704dd3d3775521bde5c3bef0954aae96d72587d6c383966d63dd955b7a6b4a SHA512 632f1ac90c3a079bb92120e4bc6ef6b13f3f809f150809a64569fae49c908dafeb30e16a34d18bb081e099fe2a252a7ed8b76da129ffa0d51b16216f0b6d1282

diff --git a/media-plugins/audacious-plugins/audacious-plugins-4.2.ebuild b/media-plugins/audacious-plugins/audacious-plugins-4.2.ebuild
new file mode 100644
index 000000000000..23633544524d
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-4.2.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${P/_/-}"
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+
+KEYWORDS="~amd64 ~riscv ~x86"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="
+	aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth gme http jack
+	openmpt lame libnotify libsamplerate lirc mms modplug mp3 nls opengl
+	pulseaudio scrobbler sdl sid sndfile soxr speedpitch streamtuner vorbis
+	wavpack
+"
+
+REQUIRED_USE="ampache? ( http ) streamtuner? ( http )"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )
+"
+DEPEND="
+	app-arch/unzip
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtwidgets:5
+	~media-sound/audacious-${PV}
+	sys-libs/zlib
+	x11-libs/gdk-pixbuf:2
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	ampache? ( =media-libs/ampache_browser-1* )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia:=
+		>=media-libs/libcddb-1.2.1
+	)
+	cue? ( media-libs/libcue:= )
+	ffmpeg? ( >=media-video/ffmpeg-0.7.3 )
+	flac? (
+		>=media-libs/flac-1.2.1-r1
+		>=media-libs/libvorbis-1.0
+	)
+	fluidsynth? ( media-sound/fluidsynth:= )
+	http? ( >=net-libs/neon-0.26.4 )
+	jack? (
+		>=media-libs/bio2jack-0.4
+		virtual/jack
+	)
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	openmpt? ( media-libs/libopenmpt )
+	libsamplerate? ( media-libs/libsamplerate:= )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	opengl? ( dev-qt/qtopengl:5 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl2[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	soxr? ( media-libs/soxr )
+	speedpitch? ( media-libs/libsamplerate:= )
+	streamtuner? ( dev-qt/qtnetwork:5 )
+	vorbis? (
+		>=media-libs/libogg-1.1.3
+		>=media-libs/libvorbis-1.2.0
+	)
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+}
+
+src_prepare() {
+	default
+	if ! use nls; then
+		sed -e "/SUBDIRS/s/ po//" -i Makefile || die "Failed to sed" # bug #512698
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-mpris2
+		--enable-qt
+		--enable-qtaudio
+		--enable-songchange
+		--disable-adplug # not packaged
+		--disable-gtk
+		--disable-oss4
+		--disable-coreaudio
+		--disable-sndio
+		$(use_enable aac)
+		$(use_enable alsa)
+		$(use_enable ampache)
+		$(use_enable bs2b)
+		$(use_enable cdda cdaudio)
+		$(use_enable cue)
+		$(use_enable ffmpeg ffaudio)
+		$(use_enable flac)
+		$(use_enable flac filewriter)
+		$(use_enable fluidsynth amidiplug)
+		$(use_enable gme console)
+		$(use_enable http neon)
+		$(use_enable jack)
+		$(use_enable lame filewriter_mp3)
+		$(use_enable libnotify notify)
+		$(use_enable openmpt openmpt)
+		$(use_enable libsamplerate resample)
+		$(use_enable lirc)
+		$(use_enable mms)
+		$(use_enable modplug)
+		$(use_enable mp3 mpg123)
+		$(use_enable nls)
+		$(use_enable opengl qtglspectrum)
+		$(use_enable pulseaudio pulse)
+		$(use_enable scrobbler scrobbler2)
+		$(use_enable sdl sdlout)
+		$(use_enable sid)
+		$(use_enable sndfile)
+		$(use_enable soxr)
+		$(use_enable speedpitch)
+		$(use_enable streamtuner)
+		$(use_enable vorbis)
+		$(use_enable wavpack)
+	)
+	econf "${myeconfargs[@]}"
+}