[gentoo-commits] repo/gentoo:master commit in: x11-libs/wxGTK/

["David Seifert" <soap@gentoo.org>]

commit:     6e285b43f43a24cb6507077b9dbbac9c3efe188f
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  9 22:57:46 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Jul  9 22:57:46 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6e285b43

x11-libs/wxGTK: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap <AT> gentoo.org>

 ...wxGTK-3.0.4-r2.ebuild => wxGTK-3.0.4-r3.ebuild} | 87 ++++++++++------------
 1 file changed, 41 insertions(+), 46 deletions(-)

diff --git a/x11-libs/wxGTK/wxGTK-3.0.4-r2.ebuild b/x11-libs/wxGTK/wxGTK-3.0.4-r3.ebuild
similarity index 69%
rename from x11-libs/wxGTK/wxGTK-3.0.4-r2.ebuild
rename to x11-libs/wxGTK/wxGTK-3.0.4-r3.ebuild
index ce1c918692a7..990923e26230 100644
--- a/x11-libs/wxGTK/wxGTK-3.0.4-r2.ebuild
+++ b/x11-libs/wxGTK/wxGTK-3.0.4-r3.ebuild
@@ -1,52 +1,51 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=8
 
 inherit multilib-minimal
 
 DESCRIPTION="GTK+ version of wxWidgets, a cross-platform C++ GUI toolkit"
 HOMEPAGE="https://wxwidgets.org/"
-SRC_URI="https://github.com/wxWidgets/wxWidgets/releases/download/v${PV}/wxWidgets-${PV}.tar.bz2
+SRC_URI="
+	https://github.com/wxWidgets/wxWidgets/releases/download/v${PV}/wxWidgets-${PV}.tar.bz2
 	https://dev.gentoo.org/~leio/distfiles/wxGTK-3.0.4_p20190713.tar.xz
 	doc? ( https://github.com/wxWidgets/wxWidgets/releases/download/v${PV}/wxWidgets-${PV}-docs-html.tar.bz2 )"
+S="${WORKDIR}/wxWidgets-${PV}"
 
+LICENSE="wxWinLL-3 GPL-2 doc? ( wxWinFDL-3 )"
+SLOT="3.0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
 IUSE="+X doc debug gstreamer libnotify opengl sdl tiff"
 
-SLOT="3.0"
-
 RDEPEND="
 	dev-libs/expat[${MULTILIB_USEDEP}]
 	sdl? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
 	X? (
-		>=dev-libs/glib-2.22:2[${MULTILIB_USEDEP}]
-		media-libs/libpng:0=[${MULTILIB_USEDEP}]
+		dev-libs/glib:2[${MULTILIB_USEDEP}]
+		media-libs/libjpeg-turbo:=[${MULTILIB_USEDEP}]
+		media-libs/libpng:=[${MULTILIB_USEDEP}]
 		sys-libs/zlib[${MULTILIB_USEDEP}]
-		virtual/jpeg:0=[${MULTILIB_USEDEP}]
-		>=x11-libs/gtk+-2.18:2[${MULTILIB_USEDEP}]
+		x11-libs/gtk+:2[${MULTILIB_USEDEP}]
 		x11-libs/gdk-pixbuf[${MULTILIB_USEDEP}]
 		x11-libs/libSM[${MULTILIB_USEDEP}]
 		x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
 		x11-libs/pango[${MULTILIB_USEDEP}]
 		gstreamer? (
 			media-libs/gstreamer:1.0[${MULTILIB_USEDEP}]
-			media-libs/gst-plugins-base:1.0[${MULTILIB_USEDEP}] )
+			media-libs/gst-plugins-base:1.0[${MULTILIB_USEDEP}]
+		)
 		libnotify? ( x11-libs/libnotify[${MULTILIB_USEDEP}] )
 		opengl? ( virtual/opengl[${MULTILIB_USEDEP}] )
 		tiff?   ( media-libs/tiff:0[${MULTILIB_USEDEP}] )
-		)"
-
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
+	)"
+DEPEND="
+	${RDEPEND}
 	opengl? ( virtual/glu[${MULTILIB_USEDEP}] )
 	X? ( x11-base/xorg-proto )"
-
+BDEPEND="virtual/pkgconfig"
 PDEPEND=">=app-eselect/eselect-wxwidgets-20131230"
 
-LICENSE="wxWinLL-3 GPL-2 doc? ( wxWinFDL-3 )"
-
-S="${WORKDIR}/wxWidgets-${PV}"
 PATCHES=(
 	"${WORKDIR}"/wxGTK-3.0.4_p20190713/
 	"${FILESDIR}"/${PN}-3.0.5-collision.patch
@@ -54,14 +53,13 @@ PATCHES=(
 )
 
 multilib_src_configure() {
-	local myconf
-
-	# X independent options
-	myconf="
-			--with-zlib=sys
-			--with-expat=sys
-			--enable-compat28
-			$(use_with sdl)"
+	local myconf=(
+		# X independent options
+		--with-zlib=sys
+		--with-expat=sys
+		--enable-compat28
+		$(use_with sdl)
+	)
 
 	# debug in >=2.9
 	# there is no longer separate debug libraries (gtk2ud)
@@ -70,17 +68,16 @@ multilib_src_configure() {
 	# apps can disable these features by building w/ -NDEBUG or wxDEBUG_LEVEL_0.
 	# http://docs.wxwidgets.org/3.0/overview_debugging.html
 	# https://groups.google.com/group/wx-dev/browse_thread/thread/c3c7e78d63d7777f/05dee25410052d9c
-	use debug \
-		&& myconf="${myconf} --enable-debug=max"
+	use debug && myconf+=( --enable-debug=max )
 
 	# wxGTK options
 	#   --enable-graphics_ctx - needed for webkit, editra
 	#   --without-gnomevfs - bug #203389
-	use X && \
-		myconf="${myconf}
+	if use X; then
+		myconf+=(
+			--enable-gui
 			--enable-graphics_ctx
 			--with-gtkprint
-			--enable-gui
 			--with-libpng=sys
 			--with-libxpm=sys
 			--with-libjpeg=sys
@@ -89,37 +86,35 @@ multilib_src_configure() {
 			$(use_enable gstreamer mediactrl)
 			$(use_with libnotify)
 			$(use_with opengl)
-			$(use_with tiff libtiff sys)"
-
-	# wxBase options
-	if use !X ; then
-		myconf="${myconf}
-			--disable-gui"
+			$(use_with tiff libtiff sys)
+		)
+	else
+		# wxBase options
+		myconf+=( --disable-gui )
 	fi
 
-	ECONF_SOURCE="${S}" econf ${myconf}
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
 }
 
 multilib_src_install_all() {
-	cd "${S}"/docs || die
+	cd docs || die
 	dodoc changes.txt readme.txt
 	newdoc base/readme.txt base_readme.txt
 	newdoc gtk/readme.txt gtk_readme.txt
 
-	use doc && HTML_DOCS="${WORKDIR}"/wxWidgets-${PV}-docs-html/.
+	use doc && HTML_DOCS=( "${WORKDIR}"/wxWidgets-${PV}-docs-html/. )
 	einstalldocs
 
 	# Stray windows locale file, causes collisions
-	local wxmsw="${ED}usr/share/locale/it/LC_MESSAGES/wxmsw.mo"
-	[[ -e ${wxmsw} ]] && rm "${wxmsw}"
+	rm -f "${ED}"/usr/share/locale/it/LC_MESSAGES/wxmsw.mo || die
 }
 
 pkg_postinst() {
-	has_version app-eselect/eselect-wxwidgets \
-		&& eselect wxwidgets update
+	has_version app-eselect/eselect-wxwidgets &&
+		eselect wxwidgets update
 }
 
 pkg_postrm() {
-	has_version app-eselect/eselect-wxwidgets \
-		&& eselect wxwidgets update
+	has_version app-eselect/eselect-wxwidgets &&
+		eselect wxwidgets update
 }