[gentoo-commits] repo/gentoo:master commit in: dev-libs/isl/

["Sam James" <sam@gentoo.org>]

commit:     663fce3e0904a6b30bb2fca6a773755dbf2f6a50
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Jul  5 03:48:20 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Jul  5 03:49:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=663fce3e

dev-libs/isl: add 0.25

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-libs/isl/Manifest        |  1 +
 dev-libs/isl/isl-0.25.ebuild | 78 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/dev-libs/isl/Manifest b/dev-libs/isl/Manifest
index efecf2e95178..8d951bfe898a 100644
--- a/dev-libs/isl/Manifest
+++ b/dev-libs/isl/Manifest
@@ -1 +1,2 @@
 DIST isl-0.24.tar.xz 1930956 BLAKE2B 39cbfd18ad05778e3a5a44429261b45e4abc3efe7730ee890674d968890fe5e52c73bc1f8d271c7c3bc72d5754e3f7fcb209bd139e823d19cb9ea4ce1440164d SHA512 ff6bdcff839e1cd473f2a0c1e4dd4a3612ec6fee4544ccbc62b530a7248db2cf93b4b99bf493a86ddf2aba00e768927265d5d411f92061ea85fd7929073428e8
+DIST isl-0.25.tar.xz 1977048 BLAKE2B 54a13ba8a5d7666f62f3fb20db278d15b803400cb8b69f119b18fd1f54f7d02f1e07cd1e189803fc416afaa81b35e2247ef6b3da3d8cddc463b05cc9b3921890 SHA512 81ac6b404a71e146bb705efe647ecf3bee19c3254f534cb44228cec13ffc7a33d7d58b980106dbb120ffdc557403d966619e219328edd0a4b3cbc4ac66acb255

diff --git a/dev-libs/isl/isl-0.25.ebuild b/dev-libs/isl/isl-0.25.ebuild
new file mode 100644
index 000000000000..cc920b7c0e49
--- /dev/null
+++ b/dev-libs/isl/isl-0.25.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib multilib-minimal preserve-libs toolchain-funcs
+
+DESCRIPTION="A library for manipulating integer points bounded by linear constraints"
+HOMEPAGE="https://libisl.sourceforge.io/"
+SRC_URI="https://libisl.sourceforge.io/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/23"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/gmp-5.1.3-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="app-arch/xz-utils
+	virtual/pkgconfig"
+
+DOCS=( ChangeLog AUTHORS doc/manual.pdf )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.24-gdb-autoload-dir.patch
+	"${FILESDIR}"/${PN}-0.24-respect-flags.patch
+)
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local econf_opts=(
+		$(use_enable static-libs static)
+
+		# AX_PROG_CC_FOR_BUILD deficiency:
+		# https://wiki.gentoo.org/wiki/Project:Toolchain/use_native_symlinks
+		CC_FOR_BUILD="$(tc-getBUILD_CC)"
+	)
+
+	if ! tc-is-cross-compiler; then
+		# Incorrect CFLAGS handling as CFLAGS_FOR_BUILD
+		# even for native builds. As a result -O3 is being used
+		# regardless of user's CFLAGS.
+		econf_opts+=(
+			CFLAGS_FOR_BUILD="${CFLAGS}"
+		)
+	fi
+
+	ECONF_SOURCE="${S}" econf "${econf_opts[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}
+
+pkg_preinst() {
+	preserve_old_lib \
+		/usr/$(get_libdir)/libisl$(get_libname 14) \
+		/usr/$(get_libdir)/libisl$(get_libname 15) \
+		/usr/$(get_libdir)/libisl$(get_libname 19) \
+		/usr/$(get_libdir)/libisl$(get_libname 21) \
+		/usr/$(get_libdir)/libisl$(get_libname 22)
+}
+
+pkg_postinst() {
+	preserve_old_lib_notify \
+		/usr/$(get_libdir)/libisl$(get_libname 14) \
+		/usr/$(get_libdir)/libisl$(get_libname 15) \
+		/usr/$(get_libdir)/libisl$(get_libname 19) \
+		/usr/$(get_libdir)/libisl$(get_libname 21) \
+		/usr/$(get_libdir)/libisl$(get_libname 22)
+}