[gentoo-commits] repo/gentoo:master commit in: sci-biology/HTSeq/

["David Seifert" <soap@gentoo.org>]

commit:     45b11a00d7dd6f99521af35a08cc4c7214656751
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  2 13:16:00 2022 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sat Jul  2 13:16:00 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45b11a00

sci-biology/HTSeq: add 2.0.2

Bug: https://bugs.gentoo.org/809662
Bug: https://bugs.gentoo.org/846221
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-biology/HTSeq/HTSeq-2.0.2.ebuild | 68 ++++++++++++++++++++++++++++++++++++
 sci-biology/HTSeq/Manifest           |  1 +
 2 files changed, 69 insertions(+)

diff --git a/sci-biology/HTSeq/HTSeq-2.0.2.ebuild b/sci-biology/HTSeq/HTSeq-2.0.2.ebuild
new file mode 100644
index 000000000000..678968788ff7
--- /dev/null
+++ b/sci-biology/HTSeq/HTSeq-2.0.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_IN_SOURCE_BUILD=1
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Python support for SAM/BAM/Bowtie/FASTA/Q/GFF/GTF files"
+HOMEPAGE="https://htseq.readthedocs.io/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/htseq/htseq.git"
+else
+	SRC_URI="https://github.com/htseq/htseq/archive/release_${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+	S="${WORKDIR}"/htseq-release_${PV}
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-biology/pysam[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)"
+BDEPEND="
+	>=dev-lang/swig-3.0.8
+	dev-python/cython[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# mask broken asserts in src/step_vector.h:72
+	append-cppflags -DNDEBUG
+
+	distutils-r1_src_configure
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	# Due to the build directories creating a competing
+	# hierarchy, we move to the test/ dir to avoid implicitly
+	# injecting the root HTSeq/ dir into the PYTHONPATH,
+	# which leads the python module lookup astray:
+	#   ${PWD}
+	#   ├── build
+	#   │   ├── lib
+	#   │   │   └── HTSeq
+	#   │   [...]
+	#   ├── HTSeq
+	#   └── test
+	cd test/ || die
+	ln -s ../example_data || die
+	epytest
+}

diff --git a/sci-biology/HTSeq/Manifest b/sci-biology/HTSeq/Manifest
index 92258c60174f..fbb304f1410e 100644
--- a/sci-biology/HTSeq/Manifest
+++ b/sci-biology/HTSeq/Manifest
@@ -1 +1,2 @@
 DIST HTSeq-0.12.4.tar.gz 36187218 BLAKE2B 27be4e8783f9e32c10e23ae812069b489eb11dfa4058db43b5db4b8089792351901255103e4d4de1bcf866da3acd13e742adf8d35a9b70305aa156c70dde0837 SHA512 ec4a1a7e9177f103465840ffa9f936a5e887ffd17760b99d4cbdfd5a88e2ab44275fadfcbee153aadc6e828de7be205ed7a07f3a0548457b7c66826341c3ca64
+DIST HTSeq-2.0.2.gh.tar.gz 48468261 BLAKE2B c68ec67906f3cf78954e94214b82fd51bc19e0c505f994a3df4bfc682d804fa26f4883e9a8fa1e8ddf1e4f8ba8690d605705ebdd2d1695470984c2f04b6a19ce SHA512 96c0b4de6c9cfa9e405f02e366ecfed63bb0dba0ab76fe872f6f48b52a4956b08fa75efa4b1e4c6e4560e34b4e2921bf1ec9671831226ad415ed421a88ec3f6d