[gentoo-commits] repo/gentoo:master commit in: media-sound/ncmpc/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     a304d726a3b9d26363673b868af7280fd2e171e5
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Sat Jul  2 04:05:54 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sat Jul  2 04:05:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a304d726

media-sound/ncmpc: bump to 0.47

Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/ncmpc/Manifest          |  1 +
 media-sound/ncmpc/ncmpc-0.47.ebuild | 67 +++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/media-sound/ncmpc/Manifest b/media-sound/ncmpc/Manifest
index c6ec01543602..597635aed66c 100644
--- a/media-sound/ncmpc/Manifest
+++ b/media-sound/ncmpc/Manifest
@@ -1 +1,2 @@
 DIST ncmpc-0.46.tar.xz 289332 BLAKE2B e57a931f5a512c543d48a9b6e532c7944e655d28d02fe9ec2b5b41563e2e6a5806924a668ae592f3fee58a2bb04a681fee0903b8046a61ce39a453092dfd8623 SHA512 34cbb9ff527bfa4d849069694b6d1a1e54c932b64538e799c9ef9b9ccc42ed24932b6bcbf3552af6ce846af6b7399916e1aabc6c79ac564f1c9fe56a33b6332f
+DIST ncmpc-0.47.tar.xz 291400 BLAKE2B 4b9e5bcc435b6064c054ad84000986942a699993e78decb26b73b4f3ec8d261e4e752e11d40ed5bdcbaab260b37f1a59b99708be05ade44973fee3f2b1e6d9d1 SHA512 6c9990ca9a0781eef67fae8b20ceec5fc00177b1db2b08cfdf122dd1f61f87a92030baadcaac154d73ddee622c963481d4e37d46f76a4ef21e51d4f18a6f3e6a

diff --git a/media-sound/ncmpc/ncmpc-0.47.ebuild b/media-sound/ncmpc/ncmpc-0.47.ebuild
new file mode 100644
index 000000000000..007bfb703b0a
--- /dev/null
+++ b/media-sound/ncmpc/ncmpc-0.47.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Ncurses client for the Music Player Daemon (MPD)"
+HOMEPAGE="https://www.musicpd.org/clients/ncmpc/ https://github.com/MusicPlayerDaemon/ncmpc"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="async-connect chat-screen doc +help-screen key-screen +library-screen lirc lyrics-screen +mouse nls outputs-screen pcre search-screen +song-screen"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )
+"
+RDEPEND="
+	media-libs/libmpdclient
+	sys-libs/ncurses:=[unicode(+)]
+	lirc? ( app-misc/lirc )
+	pcre? ( dev-libs/libpcre2 )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# use correct docdir and don't install license file
+	sed -e "/^docdir =/s/meson.project_name()/'${PF}'/" \
+		-e "s/'COPYING', //" \
+		-i meson.build || die
+
+	# use correct (html) docdir
+	sed -e "/install_dir:.*doc/s/meson.project_name()/'${PF}'/" \
+		-i doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcurses=ncursesw
+		-Dcolors=true
+		-Dmini=false
+		-Dlyrics_plugin_dir="${EPREFIX}/usr/$(get_libdir)/ncmpc/lyrics"
+		-Dasync_connect=$(usex async-connect true false)
+		-Dchat_screen=$(usex chat-screen true false)
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Dhelp_screen=$(usex help-screen true false)
+		-Dkey_screen=$(usex key-screen true false)
+		-Dlibrary_screen=$(usex library-screen true false)
+		-Dlirc=$(usex lirc enabled disabled)
+		-Dlocale=$(usex nls enabled disabled)
+		-Dlyrics_screen=$(usex lyrics-screen true false)
+		-Dmouse=$(usex mouse enabled disabled)
+		-Dmultibyte=$(usex nls true false)
+		-Dnls=$(usex nls enabled disabled)
+		-Doutputs_screen=$(usex outputs-screen true false)
+		-Dregex=$(usex pcre enabled disabled)
+		-Dsearch_screen=$(usex search-screen true false)
+		-Dsong_screen=$(usex song-screen true false)
+	)
+
+	meson_src_configure
+}