[gentoo-commits] repo/gentoo:master commit in: media-libs/sdl_audiolib/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     d37535b7dcbb3054701c04daf85cbff38ac6e039
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 30 00:41:29 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jun 30 01:50:39 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d37535b7

media-libs/sdl_audiolib: add 0_p20220622

Tidy, add doc/flac/wildmidi IUSE, fix LICENSE, and use system libfmt.

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-libs/sdl_audiolib/Manifest                   |  1 +
 media-libs/sdl_audiolib/metadata.xml               |  3 +-
 .../sdl_audiolib/sdl_audiolib-0_p20220622.ebuild   | 76 ++++++++++++++++++++++
 3 files changed, 79 insertions(+), 1 deletion(-)

diff --git a/media-libs/sdl_audiolib/Manifest b/media-libs/sdl_audiolib/Manifest
index 4dda6082d546..e5637c68f6b6 100644
--- a/media-libs/sdl_audiolib/Manifest
+++ b/media-libs/sdl_audiolib/Manifest
@@ -1 +1,2 @@
+DIST sdl_audiolib-0_p20220622.tar.gz 1138752 BLAKE2B 01e565506b29e922f3eb5ff2705a0614e53c6afd43526d781eb83d86f54dab6692689de51d618e07779fe8c97ee2cfbe3de744f29c1798e3f10205141dcb28ea SHA512 ec6267665fb1a98fcfb91a40ebbd86f7bb14e9fed36509a903ba5408d0f4b8672b19421943de6a4b3d2d0b187f9531dae4b7c9f766ee07f9c1aefa08ab6a51e3
 DIST sdl_audiolib-0_pre20220410.tar.xz 223932 BLAKE2B 09f35684b64b2b96fd0230612cc8458a8c7b0b94860c9d616c90141cd6d8088048e783170180191ed9998b2601676892686dc7d8373c8507d71db59b919c178b SHA512 01ef7f4d8987e1e27b4413d21eefbb8a83ab720f64ed76fd6314244d0d53bed5a061f4a22d4967e21cc9f6086532d33fea233f3e72e8a7abc5a80108f74710c1

diff --git a/media-libs/sdl_audiolib/metadata.xml b/media-libs/sdl_audiolib/metadata.xml
index 837e2e69d9c7..93b2751b25dc 100644
--- a/media-libs/sdl_audiolib/metadata.xml
+++ b/media-libs/sdl_audiolib/metadata.xml
@@ -6,10 +6,11 @@
     <name>Gentoo Games Project</name>
   </maintainer>
   <use>
-    <flag name="fluidsynth">use <pkg>media-sound/fluidsynth</pkg> for MIDI</flag>
+    <flag name="fluidsynth">Enable support for MIDI via <pkg>media-sound/fluidsynth</pkg></flag>
     <flag name="mpg123">Enable support for mp3 decoding via <pkg>media-sound/mpg123</pkg></flag>
     <flag name="openmpt">OpenMPT decoder via <pkg>media-libs/libopenmpt</pkg></flag>
     <flag name="soxr">Enable SoX Resampler support via <pkg>media-libs/soxr</pkg></flag>
+    <flag name="wildmidi">Enable support for MIDI via <pkg>media-sound/wildmidi</pkg></flag>
   </use>
   <upstream>
     <remote-id type="github">realnc/SDL_audiolib</remote-id>

diff --git a/media-libs/sdl_audiolib/sdl_audiolib-0_p20220622.ebuild b/media-libs/sdl_audiolib/sdl_audiolib-0_p20220622.ebuild
new file mode 100644
index 000000000000..2a3199706b09
--- /dev/null
+++ b/media-libs/sdl_audiolib/sdl_audiolib-0_p20220622.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/realnc/SDL_audiolib.git"
+else
+	SDLAUDIO_COMMIT="b66a66fedf8f65cacc5ce2ff8ed8d10649c6de31"
+	SRC_URI="https://github.com/realnc/SDL_audiolib/archive/${SDLAUDIO_COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN/sdl/SDL}-${SDLAUDIO_COMMIT}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Audio decoding, resampling and mixing library for SDL"
+HOMEPAGE="https://github.com/realnc/SDL_audiolib/"
+
+LICENSE="LGPL-3+ BSD-2 || ( MIT Unlicense )"
+SLOT="0"
+IUSE="doc flac fluidsynth libsamplerate modplug mpg123 musepack openmpt opus sndfile soxr vorbis wildmidi"
+
+RDEPEND="
+	dev-libs/libfmt:=
+	media-libs/libsdl2[sound]
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth:= )
+	libsamplerate? ( media-libs/libsamplerate )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	openmpt? ( media-libs/libopenmpt )
+	opus? ( media-libs/opusfile )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	vorbis? ( media-libs/libvorbis )
+	wildmidi? ( media-sound/wildmidi )"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_DEC_ADLMIDI=OFF
+		-DUSE_DEC_BASSMIDI=OFF
+		-DUSE_DEC_FLAC=$(usex flac)
+		-DUSE_DEC_FLUIDSYNTH=$(usex fluidsynth)
+		-DUSE_DEC_LIBOPUSFILE=$(usex opus)
+		-DUSE_DEC_LIBVORBIS=$(usex vorbis)
+		-DUSE_DEC_MODPLUG=$(usex modplug)
+		-DUSE_DEC_MPG123=$(usex mpg123)
+		-DUSE_DEC_MUSEPACK=$(usex musepack)
+		-DUSE_DEC_OPENMPT=$(usex openmpt)
+		-DUSE_DEC_SNDFILE=$(usex sndfile)
+		-DUSE_DEC_WILDMIDI=$(usex wildmidi)
+		-DUSE_DEC_XMP=OFF
+		-DUSE_RESAMP_SOXR=$(usex soxr)
+		-DUSE_RESAMP_SRC=$(usex libsamplerate)
+		-DWITH_SYSTEM_FMTLIB=ON
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	use !doc || doxygen "${BUILD_DIR}"/Doxyfile || die
+}
+
+src_install() {
+	cmake_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}