[gentoo-commits] repo/gentoo:master commit in: app-admin/salt/

["Patrick McLean" <chutzpah@gentoo.org>]

commit:     72519a17ac56df946eaeb2728fad7de1f8f732c9
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 28 18:22:12 2022 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Tue Jun 28 18:24:30 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=72519a17

app-admin/salt: add 3003.5

Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 app-admin/salt/Manifest           |   1 +
 app-admin/salt/salt-3003.5.ebuild | 208 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 209 insertions(+)

diff --git a/app-admin/salt/Manifest b/app-admin/salt/Manifest
index 5ab3190d3f91..be95622da536 100644
--- a/app-admin/salt/Manifest
+++ b/app-admin/salt/Manifest
@@ -4,6 +4,7 @@ DIST salt-3002.8.tar.gz 15798643 BLAKE2B 12280dfd29f46f9bb8b2df6fcef474c2c2237d6
 DIST salt-3002.9.tar.gz 15817470 BLAKE2B 31fb6dbb61a9f0ab22ca761810a934792e9fa9c78628f925e63d3d54d00fa4ea0b4aa806ba3ea92f7397ba3291281bf8989d9a288fb3114c7911cdebfc9acd6a SHA512 f34fd05960a68cba51f34cf8b7c737bd84d00472cec80628f082d16e54cf70705e191ac4b6690bf406a8a11e26c8155e4bdbdec34ede5f0721fd9b5e637a0ed1
 DIST salt-3003.3.tar.gz 16017984 BLAKE2B 9cd1e33a7b6dff4d3c6c5a87e1204f7f113b6190da8301061e26fcec178aba597a9e17ab60a54a67b52a895a9a8aef58bec70e9fdd8d8edc5a42945f6de21a58 SHA512 4fe50922833fce48fcc679adb16a0e1fe893531b2feb08b235a1461c58b8d9a72af2acd89fc0f712207fb0cd215d6b446e31a40001b46c43d0cc4ac827ce29e3
 DIST salt-3003.4.tar.gz 16031515 BLAKE2B 34902aba7ab64f4ddbacbad1b776b9b2218caf22fb843879a80bd5c30b6c28f4c22a050bbaf0e9735507a78c887f52bcae7d1833ffeb51a543ec22fda79252e6 SHA512 35419fbb3f9a0f3e87579f740b717d6902cab0d85397b16d1e94d9516bf5f5d269b4f8bca370fd376abd9b7c8a6ad7ef4c8e8a8fdd31655fd17c810989e79693
+DIST salt-3003.5.tar.gz 16056545 BLAKE2B ede3f0c63175f093dca07bee1bfb659cc608336ae92f532fc45868bd7eca659498c42e5d44324492744b802ade088adac869277679989550e217c1a135d6566d SHA512 ebda2056b4d6d216a0689b919d00aa78f615c355d21703d1939dbb6b00e9ad9347be4ee5b861282521f2d337bf7bf2fdc85e6942016358088a094d854fb33be9
 DIST salt-3003.tar.gz 15830910 BLAKE2B ea4f02eece951c3fb4fcc480d00f7b531ac549b2e23ff9a210b73f749f9ba83e0402e02a59028f41f94958d17512e417b7c1b7015e8ee3aeac55be9b1374fe6f SHA512 7f631466372f303c03f2852a5cfba1ee5c6ba1636a6fe1e1622e90d0b1376ef9f670aa1b4754f3d9c8c7fe1b99fe1b4c49e140dc86d90d157a1ec1e73ba43c38
 DIST salt-3004.1.tar.gz 17685649 BLAKE2B 64950cdc8420228f935d4a21fc20872da9ecf7c51b866ec3c59b46486b84a739b002acc44fa909eed93ce3dc6bedc9804df05d3d9ee5a9a13cd9d041ba70f876 SHA512 9353a8dc2a1c6e272318c6f35059236c5d78b6c8930f715275b701c12fca3be1fe930eb533f3f0c22933ba60967b0980300b922fe486cee9a62e6cdb568bdf91
 DIST salt-3004.2.tar.gz 17685127 BLAKE2B a42e31d8a006488b3a6f341f817cde21ff86248d2b548d9914c429c62d7570cdf46cf2b41311cbb08ced7f9518e68156c6df3eb78e55cacfd4d40a4e7a54f52b SHA512 b2fa434f1d25eabac51d65d75bb020943eb71aff113d683e6f436a0f205bd3c7682b1b7acd4d9a62bf37a47eb0561293d263f3174d5e266f0998a1652fcae2ef

diff --git a/app-admin/salt/salt-3003.5.ebuild b/app-admin/salt/salt-3003.5.ebuild
new file mode 100644
index 000000000000..c3ba4ac9a49e
--- /dev/null
+++ b/app-admin/salt/salt-3003.5.ebuild
@@ -0,0 +1,208 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit systemd distutils-r1
+
+DESCRIPTION="Salt is a remote execution and configuration manager"
+HOMEPAGE="https://www.saltstack.com/resources/community/
+	https://github.com/saltstack"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}stack/${PN}.git"
+	EGIT_BRANCH="develop"
+	SRC_URI=""
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cheetah cherrypy ldap libcloud libvirt genshi gnupg keyring mako
+	mongodb neutron	nova openssl portage profile redis selinux test raet
+	+zeromq vim-syntax"
+
+RDEPEND="
+	sys-apps/pciutils
+	>=dev-python/distro-1.5[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/libnacl[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pycryptodome-3.9.8[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/markupsafe[${PYTHON_USEDEP}]
+	>=dev-python/requests-1.0.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/toml-0.10.2[${PYTHON_USEDEP}]
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	libcloud? ( >=dev-python/libcloud-2.5.0[${PYTHON_USEDEP}] )
+	mako? ( dev-python/mako[${PYTHON_USEDEP}] )
+	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+	libvirt? (
+		$(python_gen_cond_dep 'dev-python/libvirt-python[${PYTHON_USEDEP}]' python3_8)
+	)
+	openssl? (
+		dev-libs/openssl:0=[-bindist(-)]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+	raet? (
+		>=dev-python/libnacl-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/ioflo-1.1.7[${PYTHON_USEDEP}]
+		>=dev-python/raet-0.6.0[${PYTHON_USEDEP}]
+	)
+	cherrypy? ( >=dev-python/cherrypy-3.2.2[${PYTHON_USEDEP}] )
+	cheetah? ( dev-python/cheetah3[${PYTHON_USEDEP}] )
+	genshi? ( dev-python/genshi[${PYTHON_USEDEP}] )
+	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
+	portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
+	redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
+	selinux? ( sec-policy/selinux-salt )
+	nova? (
+		$(python_gen_cond_dep '>=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}]' python3_8)
+	)
+	neutron? (
+		$(python_gen_cond_dep '>=dev-python/python-neutronclient-2.3.6[${PYTHON_USEDEP}]' python3_8)
+	)
+	gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )
+	profile? ( dev-python/yappi[${PYTHON_USEDEP}] )
+	vim-syntax? ( app-vim/salt-vim )
+	zeromq? ( >=dev-python/pyzmq-19.1.0[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		>=dev-python/boto-2.32.1[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+		dev-python/mako[${PYTHON_USEDEP}]
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/moto-1.3.14[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		=dev-python/pytest-salt-factories-0.121*[${PYTHON_USEDEP}]
+		dev-python/pytest-tempdir[${PYTHON_USEDEP}]
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/libcloud[${PYTHON_USEDEP}]
+		net-dns/bind-tools
+		>=dev-python/virtualenv-20.0.20[${PYTHON_USEDEP}]
+		!x86? ( >=dev-python/boto3-1.19.63[${PYTHON_USEDEP}] )
+	)"
+
+DOCS=( README.rst AUTHORS )
+
+REQUIRED_USE="|| ( raet zeromq )
+	test? ( cheetah genshi )"
+RESTRICT="!test? ( test ) x86? ( test )"
+
+# tests currently broken
+RESTRICT+=" test"
+
+PATCHES=(
+	"${FILESDIR}/salt-3003-skip-tests-that-oom-machine.patch"
+	"${FILESDIR}/salt-3003-gentoolkit-revdep.patch"
+	"${FILESDIR}/salt-3002-tests.patch"
+	"${FILESDIR}/salt-3003.3-tests.patch"
+	"${FILESDIR}/salt-3003.1-tests.patch"
+	"${FILESDIR}/salt-3004.2-jinja-3.patch"
+	"${FILESDIR}/salt-3003.4-tests.patch"
+	"${FILESDIR}/salt-3003.4-relax-pyzmq-dep.patch"
+)
+
+python_prepare_all() {
+	# remove tests with external dependencies that may not be available, and
+	# tests that don't work in sandbox
+	rm tests/unit/{test_{zypp_plugins,module_names},utils/test_extend}.py || die
+	rm tests/unit/modules/test_{file,boto_{vpc,secgroup,elb}}.py || die
+	rm tests/unit/states/test_boto_vpc.py || die
+	rm tests/support/gitfs.py tests/unit/runners/test_git_pillar.py || die
+	rm tests/pytests/functional/transport/server/test_req_channel.py || die
+
+	# tests that require network access
+	rm tests/unit/{states,modules}/test_zcbuildout.py || die
+	rm -r tests/integration/cloud || die
+	rm -r tests/kitchen/tests/wordpress/tests || die
+	rm tests/kitchen/test_kitchen.py || die
+	rm tests/unit/modules/test_network.py || die
+
+	# tests require root access
+	rm tests/integration/pillar/test_git_pillar.py || die
+	rm tests/integration/states/test_supervisord.py || die
+	rm tests/pytests/unit/client/test_ssh.py || die
+
+	# make sure pkg_resources doesn't bomb because pycrypto isn't installed
+	find "${S}" -name '*.txt' -print0 | xargs -0 sed -e '/pycrypto>/ d ; /pycryptodomex/ d' -i || die
+	# pycryptodome rather than pycryptodomex
+	find "${S}" -name '*.py' -print0 | xargs -0 -- sed -i -e 's:Cryptodome:Crypto:g' -- || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_prepare() {
+	einfo "Fixing collections.abc warnings for ${EPYTHON}"
+	local abc
+	abc="$("${EPYTHON}" -c 'import collections.abc; print("|".join((c for c in dir(collections.abc) if not c.startswith("_"))))')" || die
+	find -name '*.py' -type f -print0 | xargs -0 sed -r -e "s:collections\\.(${abc}):collections.abc.\\1:g" -i || die
+
+	# removes contextvars, see bug: https://bugs.gentoo.org/799431
+	sed -i '/^contextvars/d' requirements/base.txt || die
+}
+
+python_install_all() {
+	local svc
+	USE_SETUPTOOLS=1 distutils-r1_python_install_all
+
+	for svc in minion master syndic api; do
+		newinitd "${FILESDIR}"/${svc}-initd-5 salt-${svc}
+		newconfd "${FILESDIR}"/${svc}-confd-1 salt-${svc}
+		systemd_dounit "${FILESDIR}"/salt-${svc}.service
+	done
+
+	insinto /etc/${PN}
+	doins -r conf/*
+}
+
+python_test() {
+	# testsuite likes lots of files
+	ulimit -n 4096 || die
+
+	# ${T} is too long a path for the tests to work
+	local TMPDIR
+	TMPDIR="$(mktemp --directory --tmpdir=/tmp ${PN}-XXXX)"
+	(
+		export TMPDIR
+		cleanup() { rm -rf "${TMPDIR}" || die; }
+
+		trap cleanup EXIT
+
+		addwrite "${TMPDIR}"
+
+		USE_SETUPTOOLS=1 NO_INTERNET=1 SHELL="/bin/bash" \
+			"${EPYTHON}" -m pytest -vv \
+			|| die "testing failed with ${EPYTHON}"
+	)
+}
+
+pkg_postinst() {
+	if use python_targets_python3_8; then
+		if use nova; then
+			ewarn "Salt's nova functionality will not work with python3.8 since"
+			ewarn "dev-python/python-novaclient does not support it yet"
+		fi
+		if use neutron; then
+			ewarn "Salt's neutron functionality will not work with python3.8 since"
+			ewarn "dev-python/python-neutronclient does not support it yet"
+		fi
+		if use libvirt; then
+			ewarn "Salt's libvirt functionality will not work with python3.8 since"
+			ewarn "dev-python/libvirt-python does not support it yet"
+		fi
+	fi
+}